DONE: Batch adjust shortcut targets

[nkormanik]

Let's suppose we have thousands of shortcuts pointing to images (contour plots), with the images all grouped together in the particular folder:

C:\4\images\50501\

Partial list of the image files:

50501_20104_21901.png
50501_20104_21902.png
50501_20104_21903.png
50501_20104_22001.png
50501_20104_22002.png
50501_20104_22003.png
etc.

All the shortcuts -- one per image above -- are burried in carefully named and organized subfolders within the particular root folder:

C:\4\shortcuts\50501\...

Now suppose we decide for whatever reason that we want to move all the images to another folder:

C:\work\images\50501\

Notice that the "4" has changed to "work".

Now all the shortcut files pointing to the first folder need to be changed accordingly.

The shortcut-altering program should be 'recursive', as the shortcuts are buried in subdirectories within the main shortcut folder.  But the task is identical for each shortcut.... 

change

"C:\4\shortcuts\50501\(image file)"

to

"C:\work\shortcuts\50501\(image file)"


Anyone here interested in writing a program that can accomplish the task?  Seems this would be a useful program.  If one already exists, I haven't found it.

The solution we presently have is to recreate all the shortcuts from scratch.  Skwire's "File Punter" can do that nicely.  Perhaps, however, it might be appropriate to have a "Batch adjust shortcut targets" program.

Comments appreciated.

Thanks.

Nicholas Kormanik
[email protected]

[skwire]

You might as well simply use File Punter to regenerate the shortcuts.  It would actually cost more to read the current shortcut and generate a new one than to simply generate a new one.  Make sense?

[kunkel321]

Could bulk re-create the LNKs via Ctrl+A (select all the images), then hold Alt and click-n-drag to bulk create shortcuts for each image file....   Unfortunately this would put them all into where ever you dropped them (you'd then have to re-create your directory tree).

[nkormanik]

Yep, does make sense.

I actually need to replicate (but with tiny path-tweak) all the shortcuts 12 times.  12 huge folders of images in total.

The conundrum is..., File Punter has already created one great workable set of shortcuts.  All are perfect.  16110 of 'em.  Buried and organized nicely within the relevant shortcuts folder for the first set of images.

So I was hoping to simply copy the entire set of shortcuts 11 more times, and merely adjust the shortcuts (recursively) to point to the next image folder.

It's not really that I'm "moving" the first set of images.  I just used that as an understandable illustration.  What I'm actually doing is creating 11 more image sets, in addition to the first.  So will need sets of shortcuts for each set of images.  Since I have a perfect set of shortcuts for the first set of images, it does seem reasonable to use it again and again, if the path-tweak can be made for each of the additional 11 sets.

Set #1 Shortcuts --> Set #1 Images
Set #2 Shortcuts --> Set #2 Images
.
.
.
Set #12 Shortcuts --> Set #12 Images

But, too, does seem like a useful program to have available for the world.  No one seems to have come up with it yet.

[nkormanik]

By the way, in addition to the path changing, the filename target changes as well.

What changes in the filename is the "50501" part, becoming "50502", for the second set of images.  And on and on.

[skwire]

Since I have a perfect set of shortcuts for the first set of images, it does seem reasonable to use it again and again, if the path-tweak can be made for each of the additional 11 sets.

-nkormanik (June 22, 2012, 06:02 PM)

But that's what I'm saying -- just use File Punter again and create the additional rules you need.  Why create an entirely new program when File Punter can already do what you want?

Based off of your other thread, I gave you two example RegEx rules necessary to create your folders.  So, with 11 image sets total, you'd only have to create 22 rules total to generate all your needed shortcuts.  Really, what could be easier?

[nkormanik]

What about the world lacking and needing "Batch adjust shortcut targets"???

[4wd]

What about the world lacking and needing "Batch adjust shortcut targets"???

-nkormanik (June 22, 2012, 06:50 PM)

But what you are doing is copying the files with a new name to a new destination.

It would be easier to create a new shortcut.

Is the folder structure for the images and the shortcuts the same?

If so then try this: BSC (nothing to do with cows)



Instructions:

Honestly, do you really want some?

Oh OK, it creates shortcuts in the Destination directory of whatever files are in the Source directory complete with directory structure - Bulk Shortcut Creator.

And yes, that is a cow icon

Also BSM in the other archive



BSC source:

Code: AutoIt [Select]

1. #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
2. #AutoIt3Wrapper_Icon=cow.ico
3. #AutoIt3Wrapper_Outfile=BSC.exe
4. #AutoIt3Wrapper_UseUpx=n
5. #AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
6. #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
7. #Include <GUIConstantsEx.au3>
8. #include <EditConstants.au3>
9. #include <ProgressConstants.au3>
10. #Include <WindowsConstants.au3>
11. #include <StaticConstants.au3>
12. #include 'RecFileListToArray.au3'
13.  
14. #Region ### START Koda GUI section ### Form=
15. $Form1 = GUICreate("BSC v0.1", 349, 180, 192, 124)
16. $Go = GUICtrlCreateButton("Go", 255, 137, 75, 25)
17. GUICtrlSetTip(-1, 'Starts shortcut creation')
18. $Button1 = GUICtrlCreateButton("Source", 280, 13, 50, 25)
19. GUICtrlSetTip(-1, 'Select a source folder to create' & @CRLF & 'shortcuts for files')
20. $Button2 = GUICtrlCreateButton("Dest", 280, 56, 50, 25)
21. GUICtrlSetTip(-1, 'Select a destination folder to put' & @CRLF & 'the shortcuts in')
22. $progress = GUICtrlCreateProgress(15, 96, 314, 17)
23. $Input1 = GUICtrlCreateInput("", 16, 14, 258, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_READONLY))
24. $Input2 = GUICtrlCreateInput("", 17, 57, 256, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_READONLY))
25. $cRecurse = GUICtrlCreateCheckbox("Recurse", 152, 127, 66, 17)
26. GUICtrlSetTip(-1, 'Recurse down through folder structure')
27. $Input3 = GUICtrlCreateInput("*.*", 16, 139, 121, 21)
28. GUICtrlSetTip(-1, 'Wildcard filter for files to' & @CRLF & 'create shortcuts for')
29. $oDir = GUICtrlCreateCheckbox("One folder", 152, 151, 79, 17)
30. GUICtrlSetTip(-1, 'Outputs shortcuts to destination folder,' & @CRLF & 'does not duplicate folder tree')
31. GUICtrlSetState(-1, $GUI_DISABLE)
32. GUISetState(@SW_SHOW)
33. #EndRegion ### END Koda GUI section ###
34.  
35.  
36. While 1
37.         $nMsg = GUIGetMsg()
38.         Switch $nMsg
39.                 Case $cRecurse
40.                         If (GUICtrlRead($cRecurse) = 1) Then
41.                                 GUICtrlSetState($oDir, $GUI_ENABLE)
42.                         Else
43.                                 GUICtrlSetState($oDir, $GUI_UNCHECKED)
44.                                 GUICtrlSetState($oDir, $GUI_DISABLE)
45.                         EndIf
46.                 Case $Button1
47.                         $sPath = FileSelectFolder('Source folder:', '', 4)
48.                         If @error = 1 Then $sPath = ''
49.                         GUICtrlSetData($Input1, $sPath)
50.                 Case $Button2
51.                         $dPath = FileSelectFolder('Destination folder:', '', 4)
52.                         If @error = 1 Then $dPath = ''
53.                         GUICtrlSetData($Input2, $dPath)
54.                 Case $Go
55.                         If $sPath <> '' And $dPath <> '' Then
56.                                 $filter = GUICtrlRead($Input3)
57.                                 If (GUICtrlRead($cRecurse) = 1) Then
58.                                         If Not (GUICtrlRead($oDir) = 1) Then
59.                                                 $output = _RecFileListToArray($sPath, '*', 2, 1, 0, 1, '*.lnk')
60.                                                 _DupeTree($sPath, $dPath)
61.                                         EndIf
62.                                         $output = _RecFileListToArray($sPath, $filter, 1, 1, 0, 1, '*.lnk')
63.                                 Else
64.                                         $output = _RecFileListToArray($sPath, $filter, 1, 0, 0, 1, '*.lnk')
65.                                 EndIf
66.                                 _BSC($sPath, $dPath, (GUICtrlRead($oDir) = 1))
67.                         EndIf
68.                 Case $GUI_EVENT_CLOSE
69.                         Exit
70.         EndSwitch
71. WEnd
72.  
73.  
74. Func _BSC($src, $dest, $oneDir = 0)
75.         $prg = 0
76.         $diff = 100 / $output[0]
77.         GUICtrlSetData($progress, $prg)
78.         For $i = 1 To $output[0]
79.                 If $oneDir = 0 Then
80.                         $temp = $dest & '\' & $output[$i]
81.                 Else
82.                         $temp = $dest & StringMid($output[$i], StringInStr($output[$i], '\', 0, -1))
83.                 EndIf
84.                 FileCreateShortcut($src & '/' & $output[$i], $temp)
85.                 $prg += $diff
86.                 GUICtrlSetData($progress, $prg)
87.         Next
88. EndFunc
89.  
90.  
91. Func _DupeTree($src, $dest)
92.         Local $i
93.         For $i = 1 To $output[0]
94.                 If Not FileExists($dest & '\' & $output[$i]) Then DirCreate($dest & '\' & $output[$i])
95.         Next
96. EndFunc

BSM source:

Code: AutoIt [Select]

1. #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
2. #AutoIt3Wrapper_Outfile=BSM.exe
3. #AutoIt3Wrapper_UseUpx=n
4. #AutoIt3Wrapper_Res_Fileversion=0.7.0.4
5. #AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
6. #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
7.  
8. #include <GUIConstantsEx.au3>
9. #include <EditConstants.au3>
10. #include <ProgressConstants.au3>
11. #include <WindowsConstants.au3>
12. #include <StaticConstants.au3>
13. #include <GuiStatusBar.au3>
14. #include <GuiListView.au3>
15. #include <ListViewConstants.au3>
16. #include <Array.au3>
17. #include <Date.au3>
18. #include <File.au3>
19.  
20. Global $inifile = StringLeft(@ScriptName, StringLen(@ScriptName) - 4) & '.ini'
21. Global $iSRC = 'C:\', $iPRS = '(.*)', $iPRR = '\1', $iNRS = '(.*)', $iNRR = '\1', $iREC = False, $iTST = False
22.  
23. _GetIni()
24.  
25. #Region ### START Koda GUI section ### Form=
26. $guiBSM = GUICreate("BSM v0.7", 354, 251)
27. $Go = GUICtrlCreateButton("Go", 256, 193, 75, 25)
28. GUICtrlSetTip(-1, "Starts shortcut modification")
29. $Button1 = GUICtrlCreateButton("Folder", 280, 13, 50, 25)
30. GUICtrlSetTip(-1, "Folder with shortcuts")
31. $progress = GUICtrlCreateProgress(16, 152, 314, 17)
32. $Input1 = GUICtrlCreateInput($iSRC, 16, 14, 258, 21, $GUI_SS_DEFAULT_INPUT)
33.  
34. $cRecurse = GUICtrlCreateCheckbox("Recurse", 170, 194, 66, 17)
35. If $iREC Then GUICtrlSetState($cRecurse, $GUI_CHECKED)
36. GUICtrlSetTip(-1, "Recurse down through folder structure")
37. $cTest = GUICtrlCreateCheckbox("Test", 90, 190, 56, 25)
38. If $iTST Then GUICtrlSetState($cTest, $GUI_CHECKED)
39. GUICtrlSetTip(-1, "Display test output")
40.  
41. $labelRx = GUICtrlCreateLabel("RegEx", 19, 196, 36, 17)
42. GUICtrlSetTip(-1, "Click to open browser at RegEx page")
43. GUICtrlSetColor(-1, '0x000099')
44.  
45. $Input2 = GUICtrlCreateInput($iPRS, 16, 80, 140, 21)
46. GUICtrlSetTip(-1, "Path RegEx to search for")
47. $Input4 = GUICtrlCreateInput($iPRR, 16, 110, 140, 21)
48. GUICtrlSetTip(-1, "Path RegEx replacement text")
49. $Input5 = GUICtrlCreateInput($iNRS, 190, 80, 140, 21)
50. GUICtrlSetTip(-1, "Name RegEx to search for")
51. $Input6 = GUICtrlCreateInput($iNRR, 190, 110, 140, 21)
52. GUICtrlSetTip(-1, "Name RegEx replacement text")
53. GUICtrlCreateLabel("Path of target", 52, 48, 70, 17)
54. GUICtrlCreateLabel("Name of target", 215, 49, 75, 17)
55. GUICtrlCreateLabel("Old", 160, 85, 25, 21, $SS_CENTER)
56. GUICtrlCreateLabel("New", 160, 115, 25, 21, $SS_CENTER)
57. $StatusBar1 = _GUICtrlStatusBar_Create($guiBSM)
58. WinMove("BSM v0.7", '', IniRead($inifile, 'Main', 'XPos', 20), IniRead($inifile, 'Main', 'YPos', 20))
59. GUISetState(@SW_SHOW)
60. #EndRegion ### END Koda GUI section ###
61.  
62. While 1
63.         $nMsg = GUIGetMsg()
64.         Switch $nMsg
65.                 Case $labelRx
66.                         ShellExecute('http://www.autoitscript.com/autoit3/docs/functions/StringRegExp.htm')
67.                 Case $Button1
68.                         $iSRC = FileSelectFolder('Select folder:', '', 4)
69.                         If @error = 1 Then $iSRC = ''
70.                         GUICtrlSetData($Input1, $iSRC)
71.                 Case $Go
72.                         $iSRC = GUICtrlRead($Input1)
73.                         If Not FileExists($iSRC) Then
74.                                 MsgBox(48, 'BSM Error', 'Not a valid path')
75.                         Else
76.                                 $output = ''
77.                                 GUICtrlSetData($progress, 0)
78.                                 $iPRS = GUICtrlRead($Input2)
79.                                 $iPRR = GUICtrlRead($Input4)
80.                                 $iNRS = GUICtrlRead($Input5)
81.                                 $iNRR = GUICtrlRead($Input6)
82.  
83.                                 If $iPRS = '' Then $iPRS = '(.*)'
84.                                 If $iPRR = '' Then $iPRR = '\1'
85.                                 If $iNRS = '' Then $iNRS = '(.*)'
86.                                 If $iNRR = '' Then $iNRR = '\1'
87.  
88.                                 If $iSRC <> '' Then
89.                                         _GUICtrlStatusBar_SetText($StatusBar1, 'Finding shortcuts')
90.                                         Global $start = TimerInit()
91.                                         If (GUICtrlRead($cRecurse) = 1) Then
92.                                                 $output = _FileListToArrayPlus($iSRC, "*.lnk", 1, 0, "", 2, True)
93.                                         Else
94.                                                 $output = _FileListToArrayPlus($iSRC, "*.lnk", 1, 0, "", 2, False)
95.                                         EndIf
96.                                         If @error = 0 Or IsArray($output) Then
97.                                                 _BSM($output, (GUICtrlRead($cTest) = 1))
98.                                         Else
99.                                                 MsgBox(48, 'BSM Error', 'No shortcuts found')
100.                                         EndIf
101.                                 EndIf
102.                         EndIf
103.                 Case $GUI_EVENT_CLOSE
104.                         $wPos = WinGetPos("BSM v0.7")
105.                         IniWrite($inifile, 'Main', 'Folder', $iSRC)
106.                         IniWrite($inifile, 'Main', 'PathSearch', $iPRS)
107.                         IniWrite($inifile, 'Main', 'PathReplace', $iPRR)
108.                         IniWrite($inifile, 'Main', 'NameSearch', $iNRS)
109.                         IniWrite($inifile, 'Main', 'NameReplace', $iNRR)
110.                         IniWrite($inifile, 'Main', 'Recurse', (GUICtrlRead($cRecurse) = 1))
111.                         IniWrite($inifile, 'Main', 'Test', (GUICtrlRead($cTest) = 1))
112.                         IniWrite($inifile, 'Main', 'XPos', $wPos[0])
113.                         IniWrite($inifile, 'Main', 'YPos', $wPos[1])
114.                         Exit
115.         EndSwitch
116. WEnd
117.  
118.  
119. Func _BSM($files, $test = False)
120.         Local $j = 1, $target, $targetPath, $newTarget, $newWorking, $prg = 1, $fDScut = 0, $fDLog = '', $fCScut = 0, $fCLog = '', $max, $nMsg2
121.         Local $Percent, $Percent_prev, $interrupt = False
122.         Dim $temp[101][2]
123.  
124.         $max = $files[0]
125.         Switch $test
126.                 Case True
127.                         _GUICtrlStatusBar_SetText($StatusBar1, 'Creating test output')
128.                         If $files[0] > 100 Then $max = 100
129.                 Case Else
130.                         _GUICtrlStatusBar_SetText($StatusBar1, 'Processing ' & $max & ' shortcuts')
131.         EndSwitch
132.  
133.         GUICtrlSetData($Go, 'Stop')
134.  
135.         For $i = 1 To $max
136.                 $nMsg2 = GUIGetMsg()
137.                 Switch $nMsg2
138.                         Case $Go
139.                                 $interrupt = True
140.                                 ExitLoop
141.                         Case Else
142.                                 $details = FileGetShortcut($files[$i])
143.                                 If $details[0] = "" Then
144.                                         _ArrayDelete($files, $i)
145.                                         $max -= 1
146.                                         $i -= 1
147.                                 Else
148.                                         $targetPath = StringLeft($details[0], StringInStr($details[0], '\', 0, -1) - 1)
149.                                         $target = StringMid($details[0], StringInStr($details[0], '\', 0, -1) + 1)
150.  
151.                                         $newTarget = StringRegExpReplace($targetPath, $iPRS, $iPRR) & '\' & StringRegExpReplace($target, $iNRS, $iNRR)
152.                                         $newWorking = StringRegExpReplace($details[1], $iPRS, $iPRR)
153.                                         Select
154.                                                 Case $test
155.                                                         $temp[$i][0] = $details[0]
156.                                                         $temp[$i][1] = $newTarget
157.                                                         $temp[0][0] = $i
158.                                                 Case Else
159.                                                         If FileDelete($files[$i]) Then
160.                                                                 If Not FileCreateShortcut($newTarget, $files[$i], $newWorking, $details[2], $details[3], $details[4], '', $details[5], $details[6]) Then
161.                                                                         $fCScut += 1
162.                                                                         $fCLog &= $files[$i] & @CRLF
163.                                                                 EndIf
164.                                                         Else
165.                                                                 $fDScut += 1
166.                                                                 $fDLog &= $files[$i] & @CRLF
167.                                                         EndIf
168.                                         EndSelect
169.                                         $Percent = Round(($i / $max) * 100, 0)
170.                                         If $Percent <> $Percent_prev Then
171.                                                 GUICtrlSetData($progress, $Percent)
172.                                                 $Percent_prev = $Percent
173.                                         EndIf
174.                                 EndIf
175.                 EndSwitch
176.         Next
177.  
178.         GUICtrlSetData($Go, 'Go')
179.         If $interrupt Then
180.                 _GUICtrlStatusBar_SetText($StatusBar1, 'Interrupted')
181.         Else
182.                 _GUICtrlStatusBar_SetText($StatusBar1, 'Finished: ' & Round(TimerDiff($start) / 1000, 1) & ' seconds')
183.         EndIf
184.  
185.         If $test Then
186.                 _ArrayBox($temp, 1, 'BSM Test Output', '|Old Shortcut Target|New Shortcut Target', True)
187.         Else
188.                 If $fDScut > 0 Or $fCScut > 0 Or $interrupt Then
189.                         _Log($fCLog, $fCScut, $fDLog, $fDScut, $files[0], $interrupt)
190.                 Else
191.                         MsgBox(64, 'BSM Results', 'Total shortcuts: ' & $files[0] & @CRLF & 'No failures during Delete/Create')
192.                 EndIf
193.         EndIf
194.  
195.         GUICtrlSetData($progress, 0)
196. EndFunc   ;==>_BSM
197.  
198.  
199. Func _Log($cl, $cc, $dl, $dc, $tot, $int)
200.         Local $fLog = FileOpen(@TempDir & '\BSM.log', 138)
201.         If $fLog = -1 Then
202.                 MsgBox(64, 'BSM Error', 'Unable to open log file:' & @CRLF & @TempDir & '\BSM.log' & @CRLF & 'for output')
203.         Else
204.                 FileWrite($fLog, 'BSM results ' & _Now() & @CRLF & 'Total shortcuts: ' & $tot & @CRLF & @CRLF)
205.                 If $int Then FileWrite($fLog, '**** INTERRUPTED ****' & @CRLF & @CRLF)
206.                 FileWrite($fLog, 'Shortcuts that failed to be deleted: ' & $dc & @CRLF)
207.                 If $dc > 0 Then FileWrite($fLog, $dl & @CRLF & @CRLF)
208.                 FileWrite($fLog, 'Shortcuts that failed to be created: ' & $cc & @CRLF)
209.                 If $cc > 0 Then FileWrite($fLog, $cl & @CRLF & @CRLF)
210.                 FileClose($fLog)
211.                 ShellExecuteWait(@TempDir & '\BSM.log')
212.         EndIf
213. EndFunc   ;==>_Log
214.  
215.  
216. Func _GetIni()
217.         If FileExists($inifile) Then
218.                 $iSRC = IniRead($inifile, 'Main', 'Folder', 'C:\')
219.                 $iPRS = IniRead($inifile, 'Main', 'PathSearch', '(.*)')
220.                 $iPRR = IniRead($inifile, 'Main', 'PathReplace', '\1')
221.                 $iNRS = IniRead($inifile, 'Main', 'NameSearch', '(.*)')
222.                 $iNRR = IniRead($inifile, 'Main', 'NameReplace', '\1')
223.                 $iREC = IniRead($inifile, 'Main', 'Recurse', 'False')
224.                 $iTST = IniRead($inifile, 'Main', 'Test', 'False')
225.         EndIf
226. EndFunc   ;==>_GetIni
227.  
228.  
229. ;===============================================================================
230. ;
231. ; Function Name:    _ArrayBox()
232. ; Description:      Shows an array in a GUI window.  Improved version of _ArrayDisplay
233. ; Parameter(s):     $Array - An array, 1d or 2d, 0-based or 1-based
234. ; $ArrayBase - 1 or 0 - tells what base the array is
235. ; $sTitle - the title to put on the output window
236. ; $Width, $Height, $Left, $Top - Set the size and position of the output window
237. ; Requirement(s):   $Array must be 1d or 2d.  If 1-based, then arraysize is assumed to be $Array[0] or $Array[0][0]
238. ; Return Value(s):  -1 = $Array is not an array, error=1
239. ; Author(s):        Mike Ratzlaff <[email protected]>
240. ; Revision: 20050620A
241. ;
242. ;===============================================================================
243. ;
244. Func _ArrayBox(ByRef $Array, $ArrayBase = 1, $sTitle = 'Array Box', $sTemp = '', $sIni = False, $Width = 400, $Height = 200, $Left = -1, $Top = -1)
245.         Dim $AllDone = 0, $msg, $i, $j, $ArrayDimensions = UBound($Array, 0)
246.         Dim $hndForm_Main, $hndListView_Display
247.  
248.         If $ArrayDimensions = 0 Then
249.                 SetError(1)
250.                 Return -1
251.         EndIf
252.  
253.         ;Setup
254.         If $ArrayBase <> 0 Then $ArrayBase = 1
255.         If $ArrayBase Then
256.                 Select
257.                         Case $ArrayDimensions = 1
258.                                 $ArrayMax = $Array[0]
259.                         Case $ArrayDimensions = 2
260.                                 $ArrayMax = $Array[0][0]
261.                 EndSelect
262.         Else
263.                 $ArrayMax = UBound($Array, 1) - 1
264.         EndIf
265.  
266.         ;Create GUI
267.         If $Height < 100 Then $Height = 100
268.         If $Width < 100 Then $Width = 100
269.         $hndForm_Main = GUICreate($sTitle, $Width, $Height, $Left, $Top, BitOR($WS_POPUP, $WS_CAPTION, $WS_SIZEBOX, $WS_MAXIMIZEBOX, $WS_EX_DLGMODALFRAME))
270.  
271.         ;Create List Box
272.         If $ArrayDimensions = 1 Then
273.                 If $sTemp = '' Then $sTemp = 'Index|Value'
274.         ElseIf $ArrayDimensions = 2 Then
275.                 If $sTemp = '' Then
276.                         $sTemp = 'Index'
277.                         For $i = 0 To UBound($Array, 2) - 1
278.                                 $sTemp = $sTemp & '|' & $i
279.                         Next
280.                 EndIf
281.         EndIf
282.         $hndListView_Display = GUICtrlCreateListView($sTemp, 0, 0, $Width, $Height - 24, BitOR($LVS_SHOWSELALWAYS, $LVS_SINGLESEL, $LVS_NOSORTHEADER))
283.         GUICtrlSetResizing($hndListView_Display, BitOR($GUI_DockLeft, $GUI_DockTop, $GUI_DockRight, $GUI_DockBottom))
284.         _GUICtrlListView_SetColumnWidth($hndListView_Display, 0, 36)
285.  
286.         ;Create Controls, Show GUI
287.         $hndButton_Close = GUICtrlCreateButton('&Close', $Width - 80, $Height - 24, 80, 24)
288.         GUICtrlSetResizing($hndButton_Close, BitOR($GUI_DockRight, $GUI_DockBottom, $GUI_DockSize))
289.         GUICtrlSetState($hndButton_Close, $GUI_DefButton)
290.         If $sIni Then WinMove($sTitle, '', IniRead($inifile, 'Test', 'XPos', 20), IniRead($inifile, 'Test', 'YPos', 20), IniRead($inifile, 'Test', 'Width', 400), IniRead($inifile, 'Test', 'Height', 200))
291.         GUISetState(@SW_SHOW, $hndForm_Main)
292.  
293.         ;Display Array
294.         Select
295.                 Case $ArrayDimensions = 1 ;1-Dimensional Array
296.                         For $i = $ArrayBase To $ArrayMax
297.                                 GUICtrlCreateListViewItem($i & '|' & $Array[$i], $hndListView_Display)
298.                         Next ;$i
299.                 Case $ArrayDimensions = 2 ;2-Dimensional Array
300.                         For $i = $ArrayBase To $ArrayMax
301.                                 $sTemp = $Array[$i][0]
302.                                 For $j = 1 To UBound($Array, 2) - 1
303.                                         $sTemp = $sTemp & '|' & $Array[$i][$j]
304.                                 Next ;$j
305.                                 GUICtrlCreateListViewItem('[' & $i & ']|' & $sTemp, $hndListView_Display)
306.                         Next ;$i
307.                 Case Else ;Unhandled Type
308.  
309.         EndSelect
310.         _GUICtrlListView_SetColumnWidth($hndListView_Display, 1, $LVSCW_AUTOSIZE)
311.         _GUICtrlListView_SetColumnWidth($hndListView_Display, 2, $LVSCW_AUTOSIZE)
312.  
313.         ;Wait for user to close box
314.         Do
315.                 $msg = GUIGetMsg()
316.                 Select
317.                         Case $msg = $GUI_EVENT_CLOSE
318.                                 $AllDone = 1
319.                         Case $msg = $hndButton_Close
320.                                 $AllDone = 1
321.                 EndSelect
322.         Until $AllDone
323.         Local $wPos = WinGetPos($sTitle)
324.         If @error = 0 And $sIni Then
325.                 IniWrite($inifile, 'Test', 'XPos', $wPos[0])
326.                 IniWrite($inifile, 'Test', 'YPos', $wPos[1])
327.                 IniWrite($inifile, 'Test', 'Width', $wPos[2])
328.                 IniWrite($inifile, 'Test', 'Height', $wPos[3])
329.         EndIf
330.         GUIDelete($hndForm_Main)
331.         Return 0
332. EndFunc   ;==>_ArrayBox
333.  
334.  
335. ; #FUNCTION# =====================================================================================================================
336. ; _FileListToArrayPlus($sPath, $sInclude = "*", $iFlag = 0, $sExcludeFolder = "", $sExclude = "", $iPathType = 0, $bRecursive = False)
337. ; Name...........:  _FileListToArray_Rec
338. ; Parameters ....:  $sPath: Folder to search
339. ;     $sInclude: String to match on (wildcards allowed, multiples delimited by ;)
340. ;     $iFlag: Returned data type. 0 = Files and folders (default), 1 = Files only, 2 = Folders only
341. ;     $sExcludeFolder: List of folders to exclude from search (wildcards allowed, multiples delimited by ;)
342. ;     $sExclude: List of filenames to exclude from search (wildcards allowed, multiples delimited by ;)
343. ;     $iPathType: Returned data format. 0 = Filename only (default), 1 = Path relative to $sPath, 2 = Full path/filename
344. ;     $bRecursive: False = Search $sPath folder only (default), True = Search $sPath and all subfolders
345. ; Author ........:  Half the Autoit Community (Forum thread #96952)
346. ;===================================================================================================================================
347.  
348. Func _FileListToArrayPlus($sPath, $sInclude = "", $iFlag = 0, $sExcludeFolder = "", $sExclude = "", $iPathType = 0, $bRecursive = False)
349.         Local $sRet = "", $sReturnFormat = "", $interrupt = False
350.         $sPath = StringRegExpReplace($sPath, "[\\/]+\z", "") & "\" ; ensure single trailing slash
351.         If Not FileExists($sPath) Then Return SetError(1, 1, "")
352.         ; Edit include files list
353.         If $sInclude = "*" Then $sInclude = ""
354.         If $sInclude Then
355.                 If StringRegExp($sInclude, "[\\/ :><\|]|(?s)\A\s*\z") Then Return SetError(2, 2, "") ; invalid characters test
356.                 $sInclude = StringRegExpReplace(StringRegExpReplace($sInclude, "(\s*;\s*)+", ";"), "\A;|;\z", "") ; Strip unwanted whitespace
357.                 $sInclude = StringRegExpReplace($sInclude, "[][$.+^{}()]", "\\$0"); Ignore special characters
358.                 $sInclude = StringReplace(StringReplace(StringReplace($sInclude, "?", "."), "*", ".*?"), ";", "$|") ; Convert ? to ., * to .*?, and ; to |
359.                 $sInclude = "(?i)\A(" & $sInclude & "$)"; case-insensitive, match from first char, terminate strings
360.         EndIf
361.         ; Edit exclude folders list
362.         If $sExcludeFolder Then
363.                 $sExcludeFolder = StringRegExpReplace(StringRegExpReplace($sExcludeFolder, "(\s*;\s*)+", ";"), "\A;|;\z", "") ; Strip unwanted whitespace
364.                 $sExcludeFolder = StringRegExpReplace($sExcludeFolder, "[][$.+^{}()]", "\\$0"); Ignore special characters
365.                 $sExcludeFolder = StringReplace(StringReplace(StringReplace($sExcludeFolder, "?", "."), "*", ".*?"), ";", "$|") ; Convert ?=.  *=.*?  ;=|
366.                 $sExcludeFolder = "(?i)\A(?!" & $sExcludeFolder & "$)"; case-insensitive, match from first char, terminate strings
367.         EndIf
368.         ; Edit exclude files list
369.         If $sExclude Then
370.                 $sExclude = StringRegExpReplace(StringRegExpReplace($sExclude, "(\s*;\s*)+", ";"), "\A;|;\z", "") ; Strip unwanted whitespace
371.                 $sExclude = StringRegExpReplace($sExclude, "[][$.+^{}()]", "\\$0"); Ignore special characters
372.                 $sExclude = StringReplace(StringReplace(StringReplace($sExclude, "?", "."), "*", ".*?"), ";", "$|") ; Convert ?=.  *=.*?  ;=|
373.                 $sExclude = "(?i)\A(?!" & $sExclude & "$)"; case-insensitive, match from first char, terminate strings
374.         EndIf
375.         ;   MsgBox(1,"Masks","File include: " & $sInclude & @CRLF & "File exclude: " & $sExclude & @CRLF & "Dir exclude : " & $sExcludeFolder)
376.  
377.         If Not ($iFlag = 0 Or $iFlag = 1 Or $iFlag = 2) Then Return SetError(3, 3, "")
378.  
379.         Local $sOrigPathLen = StringLen($sPath), $aQueue[64] = [1, $sPath], $iQMax = 63
380.         While $aQueue[0]
381.                 $WorkFolder = $aQueue[$aQueue[0]]
382.                 $aQueue[0] -= 1
383.                 $search = FileFindFirstFile($WorkFolder & "*")
384.                 If @error Then ContinueLoop
385.                 Switch $iPathType
386.                         Case 1 ; relative path
387.                                 $sReturnFormat = StringTrimLeft($WorkFolder, $sOrigPathLen)
388.                         Case 2 ; full path
389.                                 $sReturnFormat = $WorkFolder
390.                 EndSwitch
391.                 While 1
392.                         $nMsg2 = GUIGetMsg()
393.                         Switch $nMsg2
394.                                 Case $Go
395.                                         $interrupt = True
396.                                         ExitLoop
397.                                 Case Else
398.                                         $file = FileFindNextFile($search)
399.                                         If @error Then ExitLoop
400.                                         If @extended Then ; Folder
401.                                                 If $sExcludeFolder And Not StringRegExp($file, $sExcludeFolder) Then ContinueLoop
402.                                                 If $bRecursive Then
403.                                                         If $aQueue[0] = $iQMax Then
404.                                                                 $iQMax += 128
405.                                                                 ReDim $aQueue[$iQMax + 1]
406.                                                         EndIf
407.                                                         $aQueue[0] += 1
408.                                                         $aQueue[$aQueue[0]] = $WorkFolder & $file & "\"
409.                                                 EndIf
410.                                                 If $iFlag = 1 Then ContinueLoop
411.                                                 $sRet &= $sReturnFormat & $file & "|"
412.                                         Else ; File
413.                                                 If $iFlag = 2 Then ContinueLoop
414.                                                 If $sInclude And Not StringRegExp($file, $sInclude) Then ContinueLoop
415.                                                 If $sExclude And Not StringRegExp($file, $sExclude) Then ContinueLoop
416.                                                 $sRet &= $sReturnFormat & $file & "|"
417.                                         EndIf
418.                         EndSwitch
419.                 WEnd
420.                 FileClose($search)
421.                 If $interrupt Then ExitLoop
422.         WEnd
423.         If Not $sRet Then Return SetError(4, 4, "")
424.         Return StringSplit(StringTrimRight($sRet, 1), "|")
425. EndFunc   ;==>_FileListToArrayPlus

[nkormanik]

BSC looks like a nice little copying program good to keep on hand.  Thanks.

The structure of the shortcuts within subdirectories is different from the "Image Pool."

The motivation behind focusing on shortcuts was to avoid having to copy the image files themselves, over and over and over again, to all sorts of locations.  Better to have a zillion shortcuts, paired up in various ways, all pointing to the repository of images.  Easier to mix and match shortcuts.

Let's assume I'll create just one single "Image Pool" folder.  All images bunched together.  Over 100,000 images.

There will be 12 major groups of images within that "Image Pool" folder: 50501, 50502, 50503, etc.

Using "File Punter" I was able to create 1 of 12 sets of shortcuts to certain of those images (50501s).  So I still have 11 more sets of shortcuts to create.

If only one "Image Pool"...  Then the only part of the shortcuts which will change would be the first part of the target file name.  The path would be identical:

...path\50501_20104_21901.png.lnk  (belongs to the first set of shortcuts)
...path\50502_20104_21901.png.lnk  (belongs to the second set of shortcuts)
...path\50503_20104_21901.png.lnk  (belongs to the third set of shortcuts)
...path\etc.

I wish I could simply use the perfect set of shortcuts already created (for the 50501 set), make the ONE CHARACTER TWEAK in each filenme, and use these for the second shortcut set.  And on and on.  Through all 12 sets.

Appears not so easy to "Batch adjust shortcut targets", unfortunately.

=====

By the way, another approach different from shortcuts might be to put the filenames into a database, and have the database do the pairing, mixing, matching of files.  But, alas, I have even less experience in that area.  At least pairing up shortcuts makes sense to me.

[4wd]

OK, maybe this slightly modified version will get there:

Added:

• Basic wildcard filter for file matching.
• Option to output shortcuts to one directory.

So you should be able to put all your images in one directory, enter 50503*.* in the filter field and have a load of shortcuts for matching files created in another directory sans directory structure.

...so goes the theory.

Absolutely no error trapping or any of that kind of malarkey  - you put something stupid in the filter field it's your fault.



See above for archive.

Added mouseover tooltips.

[nkormanik]

I'll try it out, 4wd.  I appreciate your efforts.  Still have FolMon running on two computers, one to each side of me, chugging out images, so I'm monitoring the progress easily, thanks to you.

And Skwire, still creating shortcuts with File Punter on my main computer here.  One full set of 32,220 lines of commands has been running in File Punter for nearly two days.  But getting the job done.  At least I think so.

=====

Possible solution to the task at hand found:

http://networkadmink...ortcuts-utility.aspx

Place copy of all the perfect 50501 shortcuts into "shortcuts to be changed" folder.

Run from command line (or batchfile?):

>ChangeLNKs    /d=c:\shortcuts to be changed    /n=names.txt    /p=paths.txt

names.txt
50501;50502

paths.txt
50501;50502


This will create a set of shortcuts pointing to 50502 set of images.

Repeat process for rest of sets....  50503, 50504, etc.  12 sets.

I'll experiment with it more tomorrow.

[skwire]

One full set of 32,220 lines of commands has been running in File Punter for nearly two days.

-nkormanik (June 23, 2012, 03:15 AM)

Are you saying that you have 32,220 rules/entries in File Punter?  If so, why?

[4wd]

OK, I was bored so I thought I'd have a play around and came up with BSM, (guess what that stands for).



It'll modify shortcuts according to the regex entered - for modify read: it will delete and then create a new shortcut according to the modified information.

You can test what will happen by checking the Test box, only the first 20 shortcut manglings will be displayed.  If you enter nothing in the regex fields and hit the Go button then it will delete and then create the existing shortcuts with no changes - think of it as 'refreshing' your stale shortcuts.

****NOTE**** All the pictures changed with v0.2+ - that's why they're not here anymore.

For a roundup of the regex you can use, see here, for more than you ever wanted know, see here.

You can also click on the RegEx to have it open the first page in your browser, (images were grabbed before I added the RegEx link - I'm not going crazy, it only looks like it).

DISCLAIMER: Because I code for my enjoyment and not others: No error checking, trapping, safety nets, etc.  

By design the program should only ever effect shortcuts, (*.lnk), but if you get it to launch a pre-emptive nuclear strike against Melbourne, Australia, just remember......I won't be around to fix the bug.

It's all in the archive up here.

Are you saying that you have 32,220 rules/entries in File Punter?  If so, why?

-skwire (June 23, 2012, 08:16 AM)

I think he means running over two lots of 16110 files, (number of image files quoted in another post).

[nkormanik]

Are you saying that you have 32,220 rules/entries in File Punter?  If so, why?

-skwire (June 23, 2012, 08:16 AM)

Well, at least we know that File Punter works successfully with such a large task.  Plus I still don't understand how to do those RegEx expressions.  As a side note on File Punter, by the way, seems I can leave it running and doing its thing in the background with no problem, while I search the web and work on other stuff.  File Punter doesn't hog the computer resources, and doesn't trip over itself just because I bring up some website in Chrome.  That's an enormous plus.

The RegEx you and jgpaiva provided (using ReNamer), though, did work great "getting rid of that extra junk" in file names.  That saved me a lot of work and frustration.

[nkormanik]

4wd, boy am I glad you were bored.  Appears you've created the world's ONLY Windows GUI program to alter shortcuts.  Definitely beats that other 'command line' version I found.  I haven't tested BSM (Batch Shortcut Modifier) yet, but it looks fantastic.  Thanks a million.

[nkormanik]

Good to go on this thread as well.  Two great solutions for modifying shortcuts.

DONE!

[lujomu]

Albeit hard to find, there already is a GUI tool that can alter shortcuts: Shortcuts Search And Replace

It has served me well on numerous occasions!

[nkormanik]

Goodness!  Then three to choose from.  Hope this thread comes up in Google searches for those desiring this functionality.

[4wd]

Albeit hard to find, there already is a GUI tool that can alter shortcuts: Shortcuts Search And Replace

-lujomu (June 25, 2012, 04:46 PM)

I don't think that can change the actual target, just the target path, (and other bits).

[nkormanik]

4wd, as usual, I'm a bit confused....

From the Properties window for a particular shortcut, below is the present target:

C:\4\QQQ\images\50501\_50501_20101_20102_.png

I want to change the above target to:

C:\5\QQQ\images\50501\_50501_20101_20102_.png

The name of the shortcut is:

20101 20102[.lnk]

The present location of the shortcut is:

C:\5\QQQ\shortcuts 1_x_178\50501\20101\

What would the RegEx entries in BSM be to accomplish this?

(There will be thousands of such changes....)

Thanks much.

[4wd]

It won't work due to a slight oversight on my part  

I stupidly changed the name of the shortcut instead of the target within the shortcut.

I'll fix it and get back to you.

OK, fixed, (I think)...well, it worked here with your example above.

UPDATE:

• Fix: Changes the target name and not the shortcut
• Fix: Modifies the working directory, (which I forgot).
• Added: A version number.
• Added: Old and New label in case the tooltips weren't enough.

It's up there.

For your case above:


And this is what you'll get:


Search for:    C:\\4(.+)
Replace with: C:\\5\1

C:\\4(.+) - Match C:\4 and put the remaining characters into a group, (one (1) in this case since it's the first group)
C:\\5\1 - Replace with C:\5 and the characters from group one, (\1).

Because \ is a special character in RegEx you need to escape it by putting \ in front, hence the \\.

[nkormanik]

Fwd, something's still amiss.  Probably the RegEx...

To clarify the objective, let's pretend I'm having a conversation with your Batch Shortcut Modifier.  I say to BSM:

"Here is a big shortcuts folder full of sub-folders, and sub-sub-folders (all neatly sliced-and-diced in a tree structure, appropriately grouped and re-grouped by purpose).  Burried herein are, again, 'shortcuts' that all point to images in a huge main image folder, divided into sub-folders which hold the images.  Please recursively search through everything in the big shortcuts folder.  If you come upon a shortcut containing any target reference to 'C:\4\...,' please change it to 'C:\5\...'"

I pasted in the BSM commands as you suggested, and ran two tests:

Test #1

Folder:
C:\5\QQQ\shortcuts 1_x_178\50501\20101  (a sub-sub-folder actually containing shortcuts)

Path of target:  C:\\4(.+)  changed to  C:\\5\1

Test box checked.  Recurse box un-checked.

Results....

New shortcut:

C:\5\QQQ\shortcuts 1_x_178\50501\20101\20101 20102  (correct, same as old, unchanged)

New target:

C:\5\QQQ\images\50501\20101 20102  (does NOT appear to be correct)

Test #2

Folder:
C:\5\QQQ\shortcuts 1_x_178\  (a base folder, holding sub-folders, and sub-sub-folders)

Path of target:  C:\\4(.+)  changed to  C:\\5\1

Test box checked.  Recurse box checked.

Results....

Identical to previous test, Test #1.

=====

Following the BSM testing mode, I ran BSM in actual mode.  BSM seemed very fast and efficient.

Afterward, examining (Windows) Properties window for shortcut "20101 20102[.lnk]":

Target = "C:\5\QQQ\images\50501\20101 20102"

which is not correct; should be:

Target = "C:\5\QQQ\images\50501\_50501_20101_20102_.png"

Remember, early part of path in shortcut was originally:

Target = "C:\4\QQQ\images\50501\_50501_20101_20102_.png"

so BSM did indeed successfully change the beginning of the path, as requested.

However, the end part, targeting the .png file, is not correct.

My naive hunch is the RegEx needs to be adjusted in some way.

[nkormanik]

BSM enhancement request 1:

Upon successful completion of the job, small window pops up with something similar to the following, with C being the most preferred:

A)  DONE!

B)  DONE!  xxxx shortcuts processed.

C)  DONE!  xxxx shortcuts changed; yyyy shortcuts left alone.


BSM enhancement request 2:

Set up an .ini file containing the last used parameters, and re-use next time program is run.

[4wd]

Test #1

Folder:
C:\5\QQQ\shortcuts 1_x_178\50501\20101  (a sub-sub-folder actually containing shortcuts)

Path of target:  C:\\4(.+)  changed to  C:\\5\1

Test box checked.  Recurse box un-checked.

Results....

New shortcut:

C:\5\QQQ\shortcuts 1_x_178\50501\20101\20101 20102  (correct, same as old, unchanged)

New target:

C:\5\QQQ\images\50501\20101 20102  (does NOT appear to be correct)

-nkormanik (July 08, 2012, 11:38 PM)

OK, I'm confused here - prior to v0.2 it reported New shortcut/New target in Test mode.

With v0.2, it reports Old Target/New Target, (as you can see in my post above), because the actual shortcut doesn't get renamed, (as it was doing in the prior version - I naively thought the shortcut would have the same name as the target).

Are you sure you're using v0.2 ?

Here's a directory setup as you've described above showing that the properties for the shortcut point to the old C:\4\QQQ.... path, (this is using the parameters from your Test #2 but Test #1 also worked):

DONE: Batch adjust shortcut targets

Here's the Test output with arrows associating between things:

DONE: Batch adjust shortcut targets

This is the result of execution, the shortcut properties now point to the image in the other directory:

DONE: Batch adjust shortcut targets

BSM enhancement request 1:
C)  DONE!  xxxx shortcuts changed; yyyy shortcuts left alone.

-nkormanik (July 08, 2012, 11:46 PM)

See what I can do.

Set up an .ini file containing the last used parameters, and re-use next time program is run.

Easy enough, I'll have it save on close.

UPDATE BSM v0.3 (here):

• Added: Saves path/regex in an ini file on exit.
• Added: Generates a report when it's finished.

Regarding the report: If nothing went wrong then all it will say is the total number of shortcuts and there was no problem.  If something went wrong it will open a log file, (%TEMP%\BSM.log), in your default text editor.

NOTE: BSM works by replacing the existing shortcut by first deleting it, then creating a new one with the new data.  The log will show any shortcuts that failed to be deleted or failed to be created, (mark a couple of your shortcuts as Read-Only if you want to see what happens).

[nkormanik]

My apologies, 4wd.  I was testing with the previous version.

Current version works perfectly.

BSM is the best Batch Shortcut Modifier on the planet.

By the way, for those following, above in this thread was mentioned the program "Shortcuts Search And Replace."  That, too, is a fine program.  HOWEVER, for large jobs in my tests 4wd's BSM is about 100X faster.

Thanks very, very much, 4wd!