I don't remember either, but here's
KeySwitch - Use hotkeys to switch windows!
1: Press Ctrl-T to start assigning a hotkey.
2: Press Ctrl and 0 through 9 to assign that hotkey to the active window.
3: To swith to a window, press the assigned hotkey.
To change modifiers and hotkeys, edit the modifier= and addkey= lines below.
Skrommel
;KeySwitch.ahk
; Use hotkeys to switch windows.
; 1: Press Ctrl-T to start assigning a hotkey.
; 2: Press Ctrl and 0 through 9 to assign that hotkey to the active window.
; 3: To swith to a window, press the assigned hotkey.
; To change modifiers and hotkeys, edit the modifier= and addkey= lines below.
;Skrommel @ 2008
modifier=^ ;^=Ctrl !=Alt +=Shift #=Win
addkey=^T
#SingleInstance,Force
#NoEnv
StringReplace,modifiertext,modifier,^,Ctrl-
StringReplace,modifiertext,modifiertext,!,Alt-
StringReplace,modifiertext,modifiertext,+,Shift-
StringReplace,modifiertext,modifiertext,#,Win-
StringReplace,addkeytext,addkey,^,Ctrl-
StringReplace,addkeytext,addkeytext,!,Alt-
StringReplace,addkeytext,addkeytext,+,Shift-
StringReplace,addkeytext,addkeytext,#,Win-
Loop,10
{
key:=A_Index-1
Hotkey,%modifier%%key%,USE
}
Hotkey,%addkey%,ADD
TOOLTIP("Press " addkeytext "`n to assign a hotkey to the active window`n`nwww.1HourSoftware.com",10)
add=0
Return
ADD:
If add=0
{
add=1
TOOLTIP("Press " modifiertext " and 0 through 9`n to assign the hotkey to the active window",0)
}
Else
{
add=0
ToolTip,
}
Return
USE:
StringRight,key,A_ThisHotkey,1
If add=1
{
WinGet,winid%key%,Id,A
add=0
WinGetTitle,title,A
TOOLTIP(modifiertext . key " = " title)
}
Else
{
winid:=winid%key%
WinActivate,Ahk_Id %winid%
}
Return
TOOLTIP(message,timeout=4)
{
ToolTip,%message%
If timeout<>0
SetTimer,TOOLTIPOFF,% timeout*1000
Return
}
TOOLTIPOFF:
SetTimer,TOOLTIPOFF,Off
ToolTip
Return
