Idea: Pop out from directory

[pongosnodgrass]

For people like myself who unrar/unzip a lot it can become a pain when the item we unzip (into the current directory) unzips but also creates a sub directory so this means going into that subdirectory , highlighting everything , cut and then navigating back to the parent directory and pasting.

It would be cool if we could highlight files, right click and select a 'pop out' option where all selected files were moved the directory above.

Thanks for reading :-)

Pongo

[jgpaiva]

Hi!
And welcome to DC

I know someone complained about this earlier.
There's a better solution than what you're thinking. Here on DC, someone made a program that unzips stuff always to the top directory, thus, it never creates the subdirectory you mentioned (even if it exists in the rar) .
Unfortunatelly, after a quick search, I wasn't able to find this program. But I'm sure someone knows what I'm talking about and will get you a nice link

[PhilB66]

Filenanny maybe?

[AndyM]

all selected files were moved the directory above.

-pongosnodgrass (September 18, 2008, 05:48 AM)

just drag the selected files to the parent folder, or any other folder, in the folder pane.  instant copy.

[skrommel]

  I've started using ExtractNow from www.extractnow.com and plan to never extract a single archive manually again! Download and donate!

Skrommel

Features
- Supports ZIP, RAR, ISO, BIN, IMG, IMA, IMZ, 7Z, ACE, JAR, GZ, LZH, LHA, TAR, SIT archive formats
- Drag and drop files or folders from Windows Explorer to extract them
- Simple user interface and sleek design in a small package
- Recursively search through folders for archives (Just drag and drop them)
- Delete files or close program after extraction options
- Windows explorer file associations for all supported archive types
- Extract files into current directory, named folder, or favorite folder of choice
- System tray icon on Minimize and Always on top features
- Integrates with Windows Explorer via special context menu items

[skywalka]

I know someone complained about this earlier.
There's a better solution than what you're thinking. Here on DC, someone made a program that unzips stuff always to the top directory, thus, it never creates the subdirectory you mentioned (even if it exists in the rar) .
Unfortunatelly, after a quick search, I wasn't able to find this program. But I'm sure someone knows what I'm talking about and will get you a nice link

-jgpaiva (September 18, 2008, 09:31 AM)

https://www.donation...dex.php?topic=5491.0
I can't live without it.

[skrommel]

  Try MoveUp!

Not heavily tested... Just download, compile to an exe using AutoHotkey, run it and choose Install MoveUp into SendTo.

To use it, select the files to move to the parent folder, rightclick one of them and choose SendTo - MoveUp.

Skrommel

[Select]

;MoveUp.ahk
; Rightclick one or more files and select the contextmenu SendTo - MoveUp
;  to move the files to the parent folder
;Skrommel @ 2009

#NoEnv
#SingleInstance,Off
#NoTrayIcon

applicationname=MoveUp

If 0=0
{
  Gosub,ABOUT
  Return
}

Loop,%0%
{
  filename:=%A_Index%
  Loop,%filename%,1,0
  {
    SplitPath,A_LoopFileLongPath,,dir
    Break
  }
  SplitPath,dir,,parentdir
  Break
}

error=0
Loop,%0%
{
  filename:=%A_Index%
  Loop,%filename%,1,0
  {
    SplitPath,A_LoopFileLongPath,name
    Break
  }
  filename=%dir%\%name%
;  MsgBox,%0%:Moving`n %filename%`nto`n %parentdir%\%name%
  FileGetAttrib,attrib,%filename%
  IfInString,filename,D
  {
    FileMoveDir,%filename%,%parentdir%\%name%
    If errorlevel=1
      error+=1
  }
  Else
  {
    FileMove,%filename%,%parentdir%\%name%
    If errorlevel=1
      error+=1
  }
}
If error>0
  ToolTip,Error! %error% files were not moved!
Else
  ToolTip,Success! %0% files were moved!
Sleep,3000
ExitApp


INSTALL:
RegRead,sendto,HKEY_CURRENT_USER,Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders,SendTo
IfNotExist,%sendto%\%applicationname%.lnk
  FileCreateShortcut,%A_WorkingDir%\%applicationname%,%sendto%\%applicationname%.lnk,,,,%A_WorkingDir%\%applicationname%.exe,,1,
IfNotExist,%sendto%\%applicationname%.lnk
  MsgBox,0,%applicationname%,Unable to install MoveUp!
Else
  MsgBox,0,%applicationname%,MoveUp installed in SendTo!
Gosub,ABOUT
Return


UNINSTALL:
RegRead,sendto,HKEY_CURRENT_USER,Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders,SendTo
IfExist,%sendto%\%applicationname%.lnk
  FileDelete,%sendto%\%applicationname%.lnk
IfExist,%sendto%\%applicationname%.lnk
  MsgBox,0,%applicationname%,Unable to remove MoveUp!
Else
  MsgBox,0,%applicationname%,MoveUp removed from SendTo!
Gosub,ABOUT
Return


ABOUT:
Gui,Destroy
Gui,Margin,20,20
Gui,Add,Picture,xm Icon1,%applicationname%.exe
Gui,Font,Bold
Gui,Add,Text,x+10 yp+10,%applicationname% v1.0
Gui,Font
Gui,Add,Text,y+10,Rightclick one or more files and select the contextmenu SendTo - MoveUp
Gui,Add,Text,xp y+5,to move the files to the parent folder

RegRead,sendto,HKEY_CURRENT_USER,Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders,SendTo
IfNotExist,%sendto%\%applicationname%.lnk
  Gui,Add,Button,GINSTALL,&Install MoveUp into SendTo
Else
  Gui,Add,Button,GUNINSTALL,&Remove MoveUp from SendTo

Gui,Add,Picture,xm y+20 Icon2,%applicationname%.exe
Gui,Font,Bold
Gui,Add,Text,x+10 yp+10,1 Hour Software by Skrommel
Gui,Font
Gui,Add,Text,y+10,For more tools, information and donations, please visit
Gui,Font,CBlue Underline
Gui,Add,Text,y+5 G1HOURSOFTWARE,www.1HourSoftware.com
Gui,Font

Gui,Add,Picture,xm y+20 Icon7,%applicationname%.exe
Gui,Font,Bold
Gui,Add,Text,x+10 yp+10,DonationCoder
Gui,Font
Gui,Add,Text,y+10,Please support the contributors at
Gui,Font,CBlue Underline
Gui,Add,Text,y+5 GDONATIONCODER,www.DonationCoder.com
Gui,Font

Gui,Add,Picture,xm y+20 Icon6,%applicationname%.exe
Gui,Font,Bold
Gui,Add,Text,x+10 yp+10,AutoHotkey
Gui,Font
Gui,Add,Text,y+10,This tool was made using the powerful
Gui,Font,CBlue Underline
Gui,Add,Text,y+5 GAUTOHOTKEY,www.AutoHotkey.com
Gui,Font

Gui,Show,,%applicationname% About
hCurs:=DllCall("LoadCursor","UInt",NULL,"Int",32649,"UInt") ;IDC_HAND
OnMessage(0x200,"WM_MOUSEMOVE")
Return

1HOURSOFTWARE:
  Run,http://www.1hoursoftware.com,,UseErrorLevel
Return

DONATIONCODER:
  Run,https://www.donationcoder.com,,UseErrorLevel
Return

AUTOHOTKEY:
  Run,http://www.autohotkey.com,,UseErrorLevel
Return

GuiClose:
  Gui,Destroy
  OnMessage(0x200,"")
  DllCall("DestroyCursor","Uint",hCur)
  ExitApp
Return

WM_MOUSEMOVE(wParam,lParam)
{
  Global hCurs
  MouseGetPos,,,,ctrl
  If ctrl in Static8,Static12,Static16
    DllCall("SetCursor","UInt",hCurs)
  Return
}
Return

EXIT:
ExitApp