Taskbar Activate... Hide your toolbar without it accidently popping up on you

[philosopherdog]

I'm using xp and I never liked having a fixed toolbar, but when you set the toolbar to autohide it always pops up when you don't want it to. I hate that. There's no way to control the timing in XP natively. The other day I decided to see if I could solve the problem. I came across a little utility called Taskbar Activate http://home.nordnet....vate.html#Historique . It works! It hasn't been updated since 99 though! I was wondering a couple of things: 1) is there anything else like this around? 2) is anyone interested in building on this amazing little program? For instance, I'd love to see a feature that shuts off the ability of a tray icon to cause the bar to come to the top. If you have an icon that's active the whole toolbar comes to the top. I have my toolbar wide on the left side using this program and it rocks.

[tomos]

I like the sound of that..
wonder would it work on my second "taskbar" too - a Directory Opus one. Prob not..

[jgpaiva]

Solution: HideTaskbar!

code inside

[Select]

; Author: jgpaiva
;
; Script Function:
; mimmics windows taskbar autohide without the annoying popup on window
; flash
;

#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
#persistent
#singleinstance,force

EdgeTime := 200
Edge = Bottom

inborder := false
WinHide,ahk_class Shell_TrayWnd

CoordMode,mouse,screen
Settimer,FollowMouse%Edge%,100
return

ShowTaskbar:
  if (!inborder)
    return

  WinHide,ahk_class Shell_TrayWnd
  WinShow,ahk_class Shell_TrayWnd
  settimer,FollowMouse%Edge%,off
  loop
  {
    sleep,100
    MouseGetPos,,,WindowId
    WinGetclass,TrayClass,ahk_id %WindowId%
    if (TrayClass <> "Shell_TrayWnd")
      break
  }
  settimer,FollowMouse%Edge%,on
  WinHide,ahk_class Shell_TrayWnd
  return

FollowMouseLeft:
  MouseGetPos,MouseX,MouseY
  If(MouseX = 0 AND !inborder)
  {
    inborder := true
    settimer,ShowTaskbar,-%EdgeTime%
    return
  }
  If(MouseX <> 0 AND inborder)
  {
    inborder := false
    settimer,ShowTaskbar,off
    return
  }
  return

FollowMouseBottom:
  MouseGetPos,MouseX,MouseY
  If(MouseY = A_screenheight -1 AND !inborder)
  {
    inborder := true
    settimer,ShowTaskbar,-%EdgeTime%
    return
  }
  If(MouseY <> A_screenHeight -1 AND inborder)
  {
    inborder := false
    settimer,ShowTaskbar,off
    return
  }
  return

FollowMouseTop:
  MouseGetPos,MouseX,MouseY
  If(MouseY = 0 AND !inborder)
  {
    inborder := true
    settimer,ShowTaskbar,-%EdgeTime%
    return
  }
  If(MouseY <> 0 AND inborder)
  {
    inborder := false
    settimer,ShowTaskbar,off
    return
  }
  return

FollowMouseRight:
  MouseGetPos,MouseX,MouseY
  If(MouseX = A_screenWidth -1 AND !inborder)
  {
    inborder := true
    settimer,ShowTaskbar,-%EdgeTime%
    return
  }
  If(MouseX <> A_screenWidth -1 AND inborder)
  {
    inborder := false
    settimer,ShowTaskbar,off
    return
  }
  return

Just install autohotkey, copy the code and save it as "hidetaskbar.ahk" and then double-click it

To change the time it takes the taskbar to popup, edit the script and change the "edgetime" parameter.

Notice that this only works for taskbars on the left of the screen!

PS: don't forget to disable windows taskbar auto-hide! Sorry, it's the other way around. Please enable windows taskbar auto-hide, it'll work better.

V 1.1 updated 14-02
added option to choose the edge where the taskbar is positioned. Just change to "edge = top", "edge = left", "edge = bottom" or "edge = left"!

[PhilB66]

Have you tried TaskBar Hider utility yet?

[tomos]

Notice that this only works for taskbars on the left of the screen!

-jgpaiva (February 13, 2008, 07:53 AM)

sounds great,
can that be modified as well?

[jgpaiva]

sounds great,
can that be modified as well?

-tomos (February 13, 2008, 08:43 AM)

Sure can!
I'll do it asap.

[tomos]

sounds great,
can that be modified as well?

-tomos (February 13, 2008, 08:43 AM)

Sure can!
I'll do it asap.

-jgpaiva (February 13, 2008, 09:09 AM)

mines at the bottom, but hey! no rush!

EDIT/ had a look myself but couldnt see anything obvious

[jgpaiva]

tomos: it'd take me a while to make the options and such, thus please make the following change:

Change the first 2 'If's to the following 2: (each in its respective line, of course )

[Select]

  If (MouseY = A_screenHeight -1 AND !inborder)
  If (mouseY <> A_screenHeight -1 AND inborder)

I'll add that option later

[edit] corrected the lines[/edit]

[tomos]

tomos: it'd take me a while to make the options and such, thus please make the following change:

Change the first 2 'If's to the following 2: (each in its respective line, of course )

[Select]

  If (MouseY = A_screenHeight -1 AND !inborder)
  If (mouseY <> A_screenHeight -1 AND inborder)

I'll add that option later

-jgpaiva (February 13, 2008, 09:56 AM)

thanks jg 

[tomos]

hmm
unfortunately I have problem with my taskbar -
when I disable autohide, it continues to autohide but just acts a bit funny about it -
sometimes reducing full window sizes, sometimes not...

so when I run this it wont work.
Maybe if I rebooted autohide might take effect, will see but not now (just restarted after winupdates a short while ago..)

[PhilB66]

@tomos

Taskbar Repair Tool from Kelly Theriot might be of help (Also mentioned here).

[tomos]

@tomos

Taskbar Repair Tool from Kelly Theriot might be of help (Also mentioned here).

-PhilB66 (February 13, 2008, 07:29 PM)

thanks Phil !
it's in my software folder will have a look later

[jgpaiva]

Updated Hide taskbar, see above post

[app103]

Skrommel's FadingTaskbar can be used for this, too.

[philosopherdog]

jppaviava,
Thanx for the code to delay the popup. That's an elegant solution. Is it also possible to reduce the size of the little line, or even hide the line indicating the toolbar is there? Thanx.

[jgpaiva]

I'm glad you like it, philosopherdog!

I don't really understand your question, HideTaskbar was supposed to completelly hide the taskbar, not even showing the line it shows when it's in autohide!