FARR mini weather report from wttr.in

[Nod5]

Wttr is a fun and fast URL based command line weather report tool.
Background and syntax here https://github.com/chubin/wttr.in

This post describes how to show wttr weather as text directly in the FARR searchbox.



Step 1. create a FARR alias
name: weather
regex: ^(weath|weat|wea)$
result: weather | appcap "C:\folder\FARR_weather_helper.exe"

Step 2. prepare helper AutoHotkey script
- Save code to C:\folder\FARR_weather_helper.ahk
- Modify the wttr URL in the code: which location? what data to show? language? extra text?
- Compile the script to an .exe file (necessary since FARR's appcap doesn't work if we run .ahk scripts uncompiled, it seems)

Code: Autohotkey [Select]

1. #NoEnv
2. #SingleInstance force
3. SetBatchLines, -1
4.  
5. ; FARR_weather_helper.ahk
6. ; 2020-11-19 by Nod5
7. ; helper script to show weather from wttr.in in FARR searchbox
8. ; wttr details and syntax at https://github.com/chubin/wttr.in
9.  
10. ; prepare wttr URL (must escape each % character with `)
11. vUrl := "https://wttr.in/london?format=`%c+`%t+`%C"
12. ; example output: ☀️ +9°C Sunny
13.  
14. ; download weather page to variable
15. vString := urlDownloadToVar(vUrl)
16.  
17. ; replace FARR searchbox string with weather string via clipboard paste
18. ; clipboard pastes all at once so won't trigger other aliases
19. vBackup := ClipboardAll
20. Clipboard := vString
21. Send ^a^v
22. sleep 500
23. Clipboard := vBackup
24. vBackup := ""
25. ExitApp
26.  
27.  
28. ; function: dowload URL and return it as variable
29. UrlDownloadToVar(url, raw :=0)
30. {
31.   ; prefix https:// if not found
32.   if( !regExMatch(url,"i)https?://") )
33.     url := "https://" url
34.   try
35.   {
36.     hObject:=ComObjCreate("WinHttp.WinHttpRequest.5.1")
37.     hObject.Open("GET",url)
38.     hObject.Send()
39.     return raw ? hObject.ResponseBody : hObject.ResponseText
40.   }catch err{
41.       MsgBox % err.message
42.   }
43.   return 0
44. }

Alternatives
Here are some alternative ways to use wttr in FARR

• Load the wttr URL as embedded webpage in FARR
• Run a script to get the URL weather text and show as a FARR results line via appcapresults
• Run a script to get the URL weather text and show it in FARR searchbox via FARR's command line parameter -search

But in all these three cases FARR does not show the unicode weather emoji correctly.
However wttr also has options for richer output formats such as multiline or even mapped weather reports as .png images, and that could probably look quite nice in FARR's HTML view.

[skajfes]

Cool idea, but wouldn't it be easier to have the weather be shown in the results?
something like an alias with htmlviewurl https://wttr.in/london?format=%c+%t+%C in the results?

[Nod5]

Cool idea, but wouldn't it be easier to have the weather be shown in the results?
something like an alias with htmlviewurl https://wttr.in/london?format=%c+%t+%C in the results?

-skajfes (November 24, 2020, 05:45 AM)

Then the emoji did not show correctly when I tested it - see note at the end of my post. But works for only text/numbers.