AutoHotkey template to act on selected files in active Explorer window

[Nod5]

AutoHotkey script template to take action on selected files in active File Explorer window in Windows 10.

Background
FARR can find and launch files, but also do much more. This AutoHotkey script template helps you use FARR to quickly take action on selected files in the active Explorer window. Similar to a context menu action in Explorer, but started from a FARR alias.

AutoHotkey script template

Code: Autohotkey [Select]

1. #NoEnv
2. SendMode Input
3. SetWorkingDir %A_ScriptDir%
4. #SingleInstance force
5. SetBatchLines, -1
6. SetWinDelay, -1
7. SetControlDelay, -1
8.  
9. ; Template: take action on selected files in active Explorer window
10. ; - AutoHotkey helper script template for FindAndRunRobot (FARR)
11. ; - by Nod5 2020-04-25
12.  
13. ; Get active the window's handle (Hwnd) from parameter passed by FARR
14. vHwnd := A_Args[1]
15.  
16. ; verify that the window is Explorer
17. WinActivate, ahk_id %vHwnd%
18. If !WinActive("ahk_class CabinetWClass ahk_id " vHwnd)
19.   ExitApp
20.  
21. ; get filepaths for selected files
22. aFiles := ExplorerHwndSelectedFilepaths(vHwnd)
23.  
24. ; ----------------------------------------------------
25. ; add code to take action on the files here
26.  
27. ; example: show each filename in a messagebox popup
28. For Key, vFile in aFiles
29. {
30.   SplitPath, vFile, vFilename
31.   MsgBox % vFilename
32. }
33.  
34. ; ----------------------------------------------------
35.  
36. ; exit script when finished
37. ExitApp
38.  
39.  
40. ; required function
41. ; function: ExplorerHwndSelectedFilepaths()
42. ; return array of filepaths for selected files in Explorer window identified via HWND
43. ExplorerHwndSelectedFilepaths(vHwnd)
44. {
45.   if !vHwnd or !WinExist("ahk_class CabinetWClass ahk_exe Explorer.exe ahk_id " vHwnd)
46.     return
47.   for window in ComObjCreate("Shell.Application").Windows
48.   {
49.     if (window.HWND != vHwnd)
50.       continue
51.     aFiles := []
52.     sfv   := window.Document
53.     ; note: gets items in alphanum ascending sort order
54.     ; https://docs.microsoft.com/en-us/windows/desktop/shell/shellfolderview-selecteditems
55.     items := sfv.SelectedItems
56.     for item in items
57.       aFiles.push(item.Path)
58.     break
59.   }
60.   window := item := items := sfv := ""
61.   return aFiles
62. }

Preparation
Install AutoHotkey, https://www.autohotkey.com/

Create a new action
- Download the template to a file, for example "C:\some folder\timestamp action.ahk"
- Edit the template to add code for the action you want to perform on the selected files
- Create a FARR user alias to launch the script and pass the parameter %LASTHWND%

Example FARR alias
- alias keyword: timestamp now
- regular expression pattern: ^(stamp)$
- result: C:\some folder\timestamp action.ahk %LASTHWND%

Use the action
- Open Explorer and select some files
- Open FARR, type to show the alias action (for example "stamp") and press Enter.

Note
The regular expression pattern is optional in FARR aliases, but useful to more quickly get to a single result.
For max speed use short patterns like ^(sta|stam|stamp)$ to show only the alias result when you type "sta", "stam" or "stamp" but still let FARR show regular file search results if you continue typing for example "stamp collection".

Action example

Code: Autohotkey [Select]

1. ; set "time modified" for the file to the current time
2. For Key, vFile in aFiles
3. {
4.   FileSetTime, % A_Now, % vFile, M
5. }

List of action ideas
- add to music/video app playlist
- copy to some other folder
- create file shortcuts in some other folder
- create a companion note file ("filename.jpg -- notes.txt")
- compare selected files in WinMerge
- scale image files 50%
- rotate image files 90 degrees
- change file date modified/created timestamp to current time
- create backup file copy with a timestamp suffix ("filename_20200423103546.txt")
(Useful for basic versioning when Git is overkill but you want some order to avoid a mess like "text.doc", "text2 final.doc", "text 2 final FIXED.doc")
- calculate and save file hashes (sha1, sha256, ...)

Ideas for more advanced actions
Asymmetric action on two selected files: copy/clone some feature (image size, timestamp, filename pattern, ...) from first file onto second file. For example clone a date modified timestamp.

Why use this rather than regular Explorer context menu actions?
- easy to create and use if you're already using FARR and AutoHotkey
- very quick if you set up short regex alias patterns
- quick to toggle aliases on/off
- you can add and show context/instructions to alias text to remind you what the action does
- avoid browsing a cluttered context menu



Example with screenshots
Use case: We want a quick way to to create .txt files to write notes about some files, for example some images.



Edit the template and add an action to create .txt note files. Save, for example to "C:\test\create txt note.ahk"

Code: Autohotkey [Select]

1. ; create companion text file for notes
2. For Key, vFile in aFiles
3. {
4.   FileAppend, , % vFile " -- notes.txt"
5. }

Create a user alias in FARR



Select files in Explorer, Open FARR and use the alias



Text files are created.



Take important notes.

[mouser]

awesome 

[anandcoral]

Great for learning features of Farr and Autohotkey too.
Thanks a lot  Nod5,

Regards,

Anand