Adding silence to audio track?

[Attronarch]

I have several hour-long audio tracks to which I have to add silence. It should go 30 seconds of music, 30 seconds of silence, and so on, until the end of track.

My first try was Audacity, which can add silence, but I couldn't figure it out how to add it to the whole track in same interval.

Any recommendations?

[MilesAhead]

Someone who uses Audacity or another program may have specific instructions.  In the meantime I would suggest checking the Sourceforge forum for Audacity as someone may have asked the same question.  Also I found a write-up of 25 free audio editors.  One of them may have an automation feature as well as batch processing.

http://www.hongkiat....gital-audio-editors/

[Nod5]

I made a script, try it. It requires Autohotkey and ffmpeg (and ffprobe that is included with ffmpeg).
https://autohotkey.com/
http://ffmpeg.zeranoe.com/builds/

update: fixed bugs with ffmpeg path (previously only worked when ffmpeg was in same folder as script)

update2: get the newer version here https://www.donation...ex.php?topic=42184.0

Code: Autohotkey [Select]

1. #NoEnv
2. SetWorkingDir %A_ScriptDir%
3. #SingleInstance force
4.  
5. ;30SecondSilencer
6. ;adds 30 seconds silence every 30 seconds to an mp3 file
7.  
8. ;-------------------------
9. ;CHANGE THESE PARAMETERS
10. source = C:\folder\some music file.mp3
11. workdir = C:\dir\
12. chunksize = 30     ;length of each silence/music segment
13. ffmpeg = C:\ffmpeg\ffmpeg.exe
14. ;-------------------------
15.  
16. ;check paths
17. SplitPath, source,,, ext, noext
18. SplitPath, ffmpeg,,fdir
19. if !FileExist(source) or !FileExist(workdir) or !FileExist(ffmpeg) or !FileExist(fdir "\ffprobe.exe")
20.  exitapp
21.  
22. ;Clear old files
23. Filedelete %workdir%\30ss-silent.mp3
24. Filedelete %workdir%\30ss_*.mp3
25. Filedelete %workdir%\%noext%_30ss.mp3
26. Filedelete %workdir%\30ss_*.txt
27.  
28. ;Get source duration in seconds
29. ;http://superuser.com/a/945604
30. RunWait %comspec% /c ""%fdir%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%source%" >> "%workdir%\30ss_duration.txt""
31. FileRead, dur, %workdir%\30ss_duration.txt
32. length := Ceil(dur)
33. if !length
34.  exitapp
35.  
36. ;split source into 30 second mp3 chunks
37. ;http://stackoverflow.com/a/7945753
38. steps := Ceil(length / chunksize) ; number of steps
39. start = 0
40. ToolTip, Split chunks...
41. sleep 1000
42. Loop, %steps%
43. {
44. c := StrLen(a_index)==1 ? "00" a_index : StrLen(a_index)==2 ? "0" a_index : a_index
45. Run "%ffmpeg%" -ss %start% -i "%source%" -t %chunksize% "%workdir%\30ss_%c%.mp3" ,,Min
46. start := start + chunksize
47. ToolTip, %A_index% / %steps%
48. }
49.  
50. ToolTip, Processing...  ;wait for ffmpeg to make all chunks
51. Loop
52. {
53.         pcount = 0
54.         for process in ComObjGet("winmgmts:").ExecQuery("Select * from Win32_Process")
55.                 if InStr(process.Name,"ffmpeg.exe")
56.                  pcount++
57.         if pcount < 1
58.          break
59.         ToolTip Processing %pcount% left
60.         sleep 400
61. }
62.  
63. ;make 30 sec silent audio mp3 file
64. ;http://stackoverflow.com/a/32027123
65. ToolTip, make silent.mp3
66. sleep 1000
67. RunWait "%ffmpeg%" -f lavfi -i anullsrc -t 30 "%workdir%\30ss-silent.mp3",,Min
68.  
69.  
70. ;Concatenate chunks and silence
71. ;https://trac.ffmpeg.org/wiki/Concatenate
72. ToolTip, Concatenate...
73. Loop, Files, %workdir%\30ss_*.mp3
74.  FileAppend, file '%workdir%\%A_LoopFileName%'`nfile '%workdir%\30ss-silent.mp3'`n, %workdir%\30ss_list.txt
75. RunWait "%ffmpeg%" -nostats -loglevel 0 -f concat -i "%workdir%\30ss_list.txt" -c copy "%workdir%\%noext%_30ss.mp3" ,,Min
76.  
77. ;clear chunks
78. Filedelete %workdir%\30ss_*.mp3
79.  
80. ToolTip, Finished!
81. sleep 1000

Out of curiousity what will you use the audio files for? crossfit/interval training perhaps?

[Attronarch]

Wow, thank you very much!

I've changed lines 10,11 and 13, but run into some trouble:

[REMOVED]

It is for my mother, she is Physical Education teacher, and among other things holds aerobic classes.

[Curt]

shouldn't the cuts fade in/out, instead of abrupt cutting? 

[Attronarch]

shouldn't the cuts fade in/out, instead of abrupt cutting? 

-Curt (January 09, 2016, 12:38 PM)

No, she didn't have such requirement.

[Nod5]

I see the problem, my bad. I fixed it in the post above. It should work now.

[Attronarch]

I see the problem, my bad. I fixed it in the post above. It should work now.

-Nod5 (January 09, 2016, 02:07 PM)

No errors pop out, but I also cannot find final mp3. I see work folder being filled with chunks, but after it is finished everything is deleted except:

• 30ss-silent.mp3
• 30ss_duration.txt

[Nod5]

shouldn't the cuts fade in/out, instead of abrupt cutting? 

-Curt (January 09, 2016, 12:38 PM)

Should be doable with this https://ffmpeg.org/f...filters.html#afade-1 , if anyone gets the hang of the correct commands line for fade in / out then post a snippet here and I'll integrate it in the script.

[Nod5]

No errors pop out, but I also cannot find final mp3. I see work folder being filled with chunks, but after it is finished everything is deleted except:

• 30ss-silent.mp3
• 30ss_duration.txt

-Attronarch (January 09, 2016, 02:22 PM)

There should be a new file named <workdir>\<source file name>_30ss.mp3

edit: I've tested it multiple times again and it works here.

the script also should create the file 30ss_list.txt , is that file present after you run the script? If so open it and check that the contents look like this

[Select]

file '<workdir path>\30ss_001.mp3'
file '<workdir path>\30ss-silent.mp3'
file '<workdir path>\30ss_002.mp3'
file '<workdir path>\30ss-silent.mp3'
...

[Attronarch]

Works perfect, thank you.

[Nod5]

newer version of 30SecondSilencer posted in the Coding Snacks section
https://www.donation...ex.php?topic=42184.0