Extract text PDF using AHK

[weedseed85]

Dear Developer's,

Might i please ask for your help.

(My English writing skills are very... disappointing, bud i think i can make myself clear. If not please ask. Thank you)

I really would like to create a script, with the help of AHK Hotkey. perhaps i will be in need of some external software, so be it.
My primary objective is to create a, "closed" kind, A script that does not need anny more input than i already gave it.

I would like to write or create a script that retries the text from a searchable PDF file and return me the output from the "search".

I was thinking about, the script / program, extracting all the available text from the PDF, putting it in a txt file and with the help of AHK I could
search or retrieve the text i need.

I have limited knowledge of AHK, But I've created some before so I'm not a complete noob. Besides I know where to find the AHK help documentary

Any suggestion is fine, and will help me getting closer to my goal.

Thanks is advance.

Greets,
Michel
 

[4wd]

This might get you started, it's an AutoIt thread with source code provided so shouldn't be too hard to convert to AutoHK or just leave and modify to do what you want:

Search PDF files for specific word and delete them

It uses pdftotext.exe, (part of Xpdf distribution), to convert the PDF before searching, naturally you don't need the delete part of it - you could just change that to output a list of found files.

Code reproduced below, not tested by me, (although I'm thinking this might be something useful....hhmm...off to the Bat Cave   ).

Code: AutoIt [Select]

1. ; Written by DavidFromLafayette & wakillon
2. ; http://www.autoitscript.com/forum/topic/127980-search-pdf-files-for-specific-word-and-delete-them/
3. #include <File.au3>
4. $current = "r:\updatecd\gcr_document"
5. $ext = "*.pdf"
6. $_pdftotextPath = 'c:\gnuwin32\bin\pdftotext.exe'
7. $_OutPutFilepath = 'C:\temp\file.txt'
8. _FileCreate($_OutPutFilepath)
9.  
10. Search($current, $ext)
11.  
12. Func Search($current, $ext)
13.  
14.         Local $search = FileFindFirstFile($current & "\*.*")
15.         While 1
16.                 Dim $file = FileFindNextFile($search)
17.                 If @error Or StringLen($file) < 1 Then ExitLoop
18.                 ;ConsoleWrite('-->-- $file : ' & $file & @CRLF)
19.                 If Not StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
20.                         $_RunWait = '"' & $_pdftotextPath & '" "' & $current & '\' & $file & '" ' & $_OutPutFilepath
21.                         RunWait($_RunWait, '', @SW_HIDE)
22.                         $filecontents = FileRead($_OutPutFilepath)
23.                         $ObsoleteinFile = StringInStr($filecontents, "Obsolete")
24.                         If $ObsoleteinFile > 0 And $ObsoleteinFile < 100 Then ; check to ensure Obsolete is on title page
25.                                 ConsoleWrite("Obsolete in File" & $file & $ObsoleteinFile & @CRLF)
26.                                 FileDelete($current & '\' & $file)
27.                         EndIf
28.                         FileDelete($_OutPutFilepath)
29.                 EndIf
30.                 If StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
31.                         Search($current & "\" & $file, $ext)
32.                 EndIf
33.                 Sleep(1000)
34.         WEnd
35.         FileClose($search)
36.  
37. EndFunc   ;==>Search

[weedseed85]

Dear Four Wheel Drive (4wd),

Thank you!

I'll try to cook something up with the code you provided. I'll even might take a look at the
AutoIt software, Looks very interesting.

Thank You

 

[4wd]

Here's a simple AutoIt program that will let you search a directory of pdf files, (including recursive), for specific text at the end it will output a list of files that had matches - started off based on the code above.

Nothing fancy but it might get you started.

Code: AutoIt [Select]

1. #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
2. #AutoIt3Wrapper_UseUpx=n
3. #AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
4. #AutoIt3Wrapper_Res_File_Add=pdftotext.exe
5. #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
6.  
7. ; Include lots of constants for GUI creation
8. #include <Constants.au3>
9. #include <ButtonConstants.au3>
10. #include <EditConstants.au3>
11. #include <GUIConstantsEx.au3>
12. #include <StaticConstants.au3>
13. #include <WindowsConstants.au3>
14. #include <RFLTA.au3>    ; Recursive filelist function
15.  
16. ; If pdftotext.exe doesn't exist then extract it from within the SearchPDF executable
17. If Not FileExists('pdftotext.exe') Then
18.         FileInstall('pdftotext.exe', '.\pdftotext.exe')
19. EndIf
20.  
21. ; Global variables: inifile
22. Global $inifile = StringLeft(@ScriptName, StringLen(@ScriptName) - 4) & '.ini'
23.  
24. ; Initial search directory = users Documents
25. $current = @MyDocumentsDir
26. $_text = ''
27.  
28. _GetIni() ; Get previous directory & search from inifile
29.  
30. ; Simple GUI interface
31. #Region ### START Koda GUI section ###
32. $Form1_1 = GUICreate("SearchPDF", 354, 376)             ; GUI window name/size
33. $Input1 = GUICtrlCreateInput("", 7, 65, 250, 21)        ; Search text input field
34. GUICtrlSetData($Input1, $_text)                         ; Set with previous data if it exists
35. $Input2 = GUICtrlCreateInput("", 8, 10, 250, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_READONLY))     ; Search dir display field
36. GUICtrlSetData($Input2, $current)                               ; Set with previous data if it exists
37. $Button1 = GUICtrlCreateButton("Path", 270, 7, 75, 25)          ; Path select button
38. $Button2 = GUICtrlCreateButton("Exit", 136, 339, 75, 25)        ; Exit button
39. $Button3 = GUICtrlCreateButton("Search", 272, 65, 75, 25)       ; Search button
40. $Checkbox1 = GUICtrlCreateCheckbox("Recurse", 272, 40, 65, 17)  ; Recurse checkbox
41. $Edit1 = GUICtrlCreateEdit("", 8, 100, 337, 229)                                ; Edit control for output, will let you copy text, (and edit it)
42. GUISetState(@SW_SHOW)                                   ; Show the GUI
43. #EndRegion ### END Koda GUI section ###
44.  
45.  
46. While 1                                         ; Wait for something to happen
47.         $nMsg = GUIGetMsg()                     ; Get any messages from the interface
48.         Switch $nMsg
49.                 Case $Button1                   ; Path button pressed
50.                         $temp = FileSelectFolder('Folder to monitor:', '', 4)
51.                         If @error <> 1 Then $current = $temp
52.                         GUICtrlSetData($Input2, $current)               ; Change input field to reflect chosen path
53.                 Case $GUI_EVENT_CLOSE, $Button2         ; GUI closed/Exit pressed: Write out current path/search text
54.                         IniWrite($inifile, 'General', 'Path', $current)
55.                         IniWrite($inifile, 'General', 'Search', $_text)
56.                         Exit
57.                 Case $Button3           ; Search pressed
58.                         If (GUICtrlRead($Checkbox1) = $GUI_CHECKED) Then        ; Read state of Recurse checkbox and set flag
59.                                 $_recurse = 1
60.                         Else
61.                                 $_recurse = 0
62.                         EndIf
63.                         $_text = GUICtrlRead($Input1)   ; Read search text, if empty pop up a message
64.                         If $_text = '' Then
65.                                 MsgBox(48, 'SearchPDF', 'No search text entered')
66.                                 ContinueCase
67.                         EndIf
68.                         $_pdfFiles = _RecFileListToArray($current, '*.pdf', 1, $_recurse, 0, 2) ; Call RFLTA to list all .pdf files
69.                         If Not IsArray($_pdfFiles) Or $_pdfFiles[0] = 0 Then    ; If none found, pop up a message
70.                                 MsgBox(48, 'SearchPDF', 'No PDF files found')
71.                                 ContinueCase
72.                         EndIf
73.                         Search($_pdfFiles, $_text)      ; Call Search function with array of pdf files and search text
74.                 Case Else
75.         EndSwitch
76. WEnd
77.  
78.  
79. Func Search($files, $text) ; Arguments passed: Array containing PDF path\filenames and text to search for
80.         Local $_tempFile = @TempDir & '\tempPDF.txt', $output = ''      ; Local variables: temporary txt file and output
81.         For $i = 1 To $files[0] ; First array element [0] contains number of files
82.                 $_RunWait = '"' & $files[$i] & '" ' & $_tempFile        ; Compose command for conversion
83.                 RunWait(@comspec & ' /c pdftotext.exe ' & $_RunWait, '.', @SW_HIDE)     ; Execute command for conversion with hidden CLI
84.                 $filecontents = FileRead($_tempFile)    ; Read converted PDF file into variable
85.                 $textInFile = StringInStr($filecontents, $text) ; Look for search text
86.                 If $textInFile > 0 Then ; If it exists add filename to output list
87.                         $output &= $files[$i] & @CRLF
88.                 EndIf
89.                 FileDelete($_tempFile)  ; Delete temporary txt file ready for next conversion
90.         Next
91.         If $output = '' Then $output = 'No files matched'
92.         GUICtrlSetData($Edit1, $output) ; Write the results into the edit control
93. EndFunc   ;==>Search
94.  
95. Func _GetIni() ; Reads data from ini file if it exists
96.         If FileExists($inifile) Then
97.                 $current = IniRead($inifile, 'General', 'Path', @MyDocumentsDir)
98.                 $_text = IniRead($inifile, 'General', 'Search', '')
99.         EndIf
100. EndFunc

pdftotext.exe is contained within SearchPDF.exe as a resource, it'll be extracted out if necessary.  Previous path and search are written to an ini file on exit to be used next time it's run.

Seems to work OK but no great bug finding was performed, no error trapping either.

EDIT: Cleaned it up a bit, (laugh if you like), now outputs to edit control so you can copy results, added lots of comments because mouser likes that kind of thing.
EDIT2: Tells you if no matches are found.

Anyway, I'm stopping there - you could add a progressbar, some way to cancel, better output (eg. line numbers within the file, no text within file, etc), etc.

[phitsc]

I have used pdftotext for my NANY 2013 entry pdfautomv. The code / script is in Ruby and can be found here: https://bitbucket.or...automv.rb?at=default

[kyrathaba]

added lots of comments because mouser likes that kind of thing...

LOL