[REQ] Disable sleep/hibernation one time to drain battery

[vevola]

rather than having to manually change the settings, is there a little app that will temporarily disable sleep/hibernation so as to drain all the battery?

[4wd]

Attached is a small program called PowerMaxTemp, (or PMT for short), that will change the current power scheme to either Always On on XP, (and possibly 2003), or High performance for Vista/7.

Normally both these schemes don't allow Standby/Hibernation, however if you've modified them then you'll just have to change them back now
(HINT: If you have changed them, make a copy and call them something else.)

Before changing the power scheme it will determine the current power scheme and then write a command into the RunOnce registry keys, [HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce], to change it back to the current scheme on the next (re)boot.

If you go into the registry editor after running it and look at the entry above you'll see a key similar to the following:

XP:          PMT           powercfg.exe /setactive "Minimal Power Management"
Vista/7:   PMT           powercfg.exe /setactive 381b4222-f694-41f0-9685-ff5bb260df2e

You can delete this key if you don't want it to execute on next boot.

The program will run from CLI or Desktop, there's a bit of error checking to see if powercfg.exe ran OK, it doesn't have any output, (unless there's an error), which I might add later.

It has been tested on my Win7HPx64 Desktop and XP Pro netbook and amazingly it worked.

Have fun.

Source code in AutoIt

Code: AutoIt [Select]

1. #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
2. #AutoIt3Wrapper_Icon=klaptopdaemon.ico
3. #AutoIt3Wrapper_UseUpx=n
4. #AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
5. #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
6. ;PowerMaxTemp
7.  
8. #include <Array.au3>
9. #include <Constants.au3>
10. #include <GUIConstantsEx.au3>
11. #include <WindowsConstants.au3>
12. #include <StaticConstants.au3>
13. #include "_Startup.au3"
14. #include "_OsVersionInfo.au3"
15.  
16. Global $schemes, $MaxPowSch, $CurrPowSch, $Progress
17.  
18. If _OsVersionTest($VER_GREATER_EQUAL, 6, 0) Then
19.         $Progress = 'Vista/7 ' & StringLower(@CPUArch) & ' or higher'
20. Else
21.         $Progress = 'XP/2003 ' & StringLower(@CPUArch)
22. EndIf
23. $Progress = $Progress & @CRLF
24.  
25. _RevertOldSch()
26. _GetAllScheme()
27. _GetMaxPower()
28. _GetCurrentScheme()
29. _ResetPowerScheme()
30. _SetPowerScheme()
31. _Exit()
32.  
33.  
34. ; Get me outta here!
35. Func _Exit()
36.         MsgBox(64, 'PowerMaxTemp', $Progress)
37.         Exit
38. EndFunc
39.  
40.  
41. ; Get all power schemes using powercfg.exe /list
42. Func _GetAllScheme()
43.         Local $error
44.         Local $foo = Run(@comspec & ' /c powercfg.exe /list"', '.', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
45.         If @error Then
46.                 MsgBox(48, 'PowerMaxTemp error', 'Failed to run powercfg.exe /list')
47.         EndIf
48.         $PowSchList = ''
49.         While 1
50.                 $PowSchList &= StdoutRead($foo)
51.             If @error <> 0 Then ExitLoop
52.         WEnd
53.         $error = ''
54.         While 1
55.                 $error &= StderrRead($foo)
56.             If @error <> 0 Then ExitLoop
57.                 If @extended > 0 Then
58.                         $Progress = $Progress & 'Power schemes not read' & ' - Code: ' & @error & @CRLF & 'Exiting...'
59.                         _Exit()
60.                 EndIf
61.         WEnd
62.         StdioClose($foo)
63.         $schemes = StringSplit(StringStripWS($PowSchList, 4), @CR)
64. EndFunc
65.  
66.  
67. ; Get the Maximum power scheme:
68. ; XP: Always On
69. ; Vista/7: High performance
70. Func _GetMaxPower()
71.         Local $i
72.         For $i = 1 To $schemes[0]
73.                 If _OsVersionTest($VER_GREATER_EQUAL, 6, 0) Then
74.                         If StringInStr($schemes[$i], 'High performance') > 0 Then $MaxPowSch = StringMid($schemes[$i], 20, (StringInStr($schemes[$i], ' ', 0, 1, 20) - 20))
75.                 Else
76.                         If StringInStr($schemes[$i], 'Always On') > 0 Then $MaxPowSch = "Always On"
77.                 EndIf
78.         Next
79.         $Progress = $Progress & 'New scheme:            ' & $MaxPowSch & @CRLF
80. EndFunc
81.  
82.  
83. ; Get the current power scheme, in Vista/7 it's marked in the list with '*'.
84. ; In XP we have to issue a powercfg /query command
85. ; Vista/7 uses the GUID, XP uses the plain text name  -  Standards, who needs them?
86. Func _GetCurrentScheme()
87.         Local $i, $output, $error
88.         $Progress = $Progress & 'Current scheme:                '
89.         If _OsVersionTest($VER_GREATER_EQUAL, 6, 0) Then
90.                 For $i = 1 To $schemes[0]
91.                         If StringInStr($schemes[$i], '*') > 0 Then $CurrPowSch = StringMid($schemes[$i], 20, (StringInStr($schemes[$i], ' ', 0, 1, 20) - 20))
92.                 Next
93.         Else
94.                 Local $foo = Run(@comspec & ' /c powercfg.exe /query"', '.', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
95.                 If @error Then
96.                         MsgBox(48, 'PowerMaxTemp error', 'Failed to run powercfg.exe /query')
97.                 EndIf
98.                 $output = ''
99.                 While 1
100.                         $output &= StdoutRead($foo)
101.                         If @error <> 0 Then ExitLoop
102.                 WEnd
103.                 $error = ''
104.                 While 1
105.                         $error &= StderrRead($foo)
106.                         If @error <> 0 Then ExitLoop
107.                         If @extended > 0 Then
108.                                 $Progress = $Progress & 'Not read' & ' - Code: ' & @error & @CRLF
109.                         EndIf
110.                 WEnd
111.                 StdioClose($foo)
112.                 Local $XP = StringSplit(StringStripWS($output, 4), @CR)
113.                 For $i = 0 To $XP[0]
114.                         If StringLeft($XP[$i], 4) = 'Name' Then $CurrPowSch = StringStripWS(StringMid($XP[$i], 6), 4)
115.                 Next
116.         EndIf
117.         If @extended <= 0 Then $Progress = $Progress & $CurrPowSch & @CRLF
118. EndFunc
119.  
120.  
121. ; Set RunOnce to restore the current power scheme on reboot
122. Func _ResetPowerScheme()
123.         If _OsVersionTest($VER_GREATER_EQUAL, 6, 0) Then
124.                 If _StartupRegistry_Install("PMT", "powercfg.exe /setactive " & $CurrPowSch, 1, 1) = 0 Then
125.                         $Progress = $Progress & 'Install RunOnce:               Fail' & @CRLF
126.                 Else
127.                         $Progress = $Progress & 'Install RunOnce:               Done' & @CRLF
128.                 EndIf
129.         Else
130.                 If _StartupRegistry_Install("PMT", 'powercfg.exe /setactive "' & $CurrPowSch & '"', 1, 1) = 0 Then
131.                         $Progress = $Progress & 'Install RunOnce:               Fail' & @CRLF
132.                 Else
133.                         $Progress = $Progress & 'Install RunOnce:               Done' & @CRLF
134.                 EndIf
135.         EndIf
136. EndFunc
137.  
138.  
139. ; Change the system to use the maximum power scheme, for XP we put quotes around it
140. Func _SetPowerScheme()
141.         Local $error
142.         If _OsVersionTest($VER_GREATER_EQUAL, 6, 0) Then
143.                 Local $foo = Run(@comspec & ' /c powercfg.exe /setactive ' & $MaxPowSch, '.', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
144.         Else
145.                 Local $foo = Run(@comspec & ' /c powercfg.exe /setactive "' & $MaxPowSch & '"', '.', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
146.         EndIf
147.         If @error Then
148.                 MsgBox(48, 'PowerMaxTemp error', 'Failed to run powercfg.exe /setactive')
149.         EndIf
150.         $cps = ''
151.         While 1
152.                 $cps &= StdoutRead($foo)
153.             If @error <> 0 Then ExitLoop
154.         WEnd
155.         $error = ''
156.         While 1
157.                 $error &= StderrRead($foo)
158.             If @error <> 0 Then ExitLoop
159.                 If @extended > 0 Then
160.                         $Progress = $Progress & 'Set scheme:            Fail' & ' - Code: ' & @error & @CRLF
161.                 EndIf
162.         WEnd
163.         StdioClose($foo)
164.         If @extended <= 0 Then $Progress = $Progress & 'Set scheme:             Done' & @CRLF
165. EndFunc
166.  
167.  
168. ; When PMT is run, RunOnce is checked for key 'pmt'.
169. ; If it exists: the old scheme is read, the command executed, and the 'pmt' key removed.
170. ; If it doesn't exist the program carries on with setting High performance/Always On scheme.
171. Func _RevertOldSch()
172.         If @CPUArch = 'X64' Then
173.                 Local $OldPowSch = RegRead("HKEY_LOCAL_MACHINE64\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", "pmt")
174.         Else
175.                 Local $OldPowSch = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", "pmt")
176.         EndIf
177.         If $OldPowSch = '' Then
178.                 $Progress = $Progress & 'Revert:                        No' & @CRLF
179.                 Return
180.         EndIf
181.         $Progress = $Progress & 'Revert:                        Yes' & @CRLF
182.         Local $foo = Run(@comspec & ' /c ' & $OldPowSch, '.', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
183.         If @error Then
184.                 MsgBox(48, 'PowerMaxTemp error', 'Failed to run ' & $OldPowSch)
185.         EndIf
186.         $cps = ''
187.         While 1
188.                 $cps &= StdoutRead($foo)
189.             If @error <> 0 Then ExitLoop
190.         WEnd
191.         $error = ''
192.         While 1
193.                 $error &= StderrRead($foo)
194.             If @error <> 0 Then ExitLoop
195.                 If @extended > 0 Then
196.                         $Progress = $Progress & 'Scheme reset:          Fail' & ' - Code: ' & @error & @CRLF
197.                 EndIf
198.         WEnd
199.         StdioClose($foo)
200.         If @extended <= 0 Then $Progress = $Progress & 'Scheme reset:           Done' & @CRLF
201.         If _StartupRegistry_Uninstall("PMT", $OldPowSch, 1, 1) = 0 Then
202.                 $Progress = $Progress & 'Remove RunOnce:                Fail' & @CRLF
203.         Else
204.                 $Progress = $Progress & 'Remove RunOnce:                Done' & @CRLF
205.         EndIf
206.         _Exit()
207. EndFunc

Updated:
20120112 - Running it a second time reverts to the original power scheme and clears the RunOnce\pmt key.
20120120 - Outputs results into a window.

[4wd]

Updated, see above - now reverts system on second run.

[vevola]

Just curious as to whether I should be "seeing" something (some type of visual feedback), because I don't... 

[Ath]

Just curious as to whether I should be "seeing" something (some type of visual feedback), because I don't... 

-vevola (January 12, 2012, 05:02 AM)

it doesn't have any output, (unless there's an error)

-4wd (January 05, 2012, 10:02 PM)

Sounds like all is good

[vevola]

cool! thanks!!

[4wd]

No visual output.....I'm a bit of a lazy coder

However, you should get aural feedback.  When my machines are switched to High performance/Always On the CPU fan goes into high gear

I'll look at providing some kind of output window at the end.

[4wd]

Updated - now outputs to a window.

Run it once:


Run it again:


It will say Fail instead of Done if the powercfg.exe command failed, (and give the error), or the RunOnce registry entry couldn't be (re)set.

Unfortunately, it's not easy to determine how an AutoIt executable was launched, (CLI or Windows), so the output will always be to a window even if launched from the CLI.

I think that about covers it unless there's a problem - I might look at enabling/disabling Hibernate/Sleep from within the script, (to reduce reliance on powercfg.exe), but don't count on it.

[skwire]

Nice work, 4wd.  vevola, please confirm this works for you and I'll mark and move this thread to Finished Programs. 

[vevola]

Well, it seems to first hibernate, and then on wake up it works...

Also... should I be running it *twice*? I'm not sure I understand your earlier post with the two screenshots...

[4wd]

Well, it seems to first hibernate, and then on wake up it works...

-vevola (February 18, 2012, 09:13 AM)

What OS are you using?
What is the Power Scheme before you run it, (Control Panel->Power Options) ?
What is the Power Scheme after you run it ?

Always On or High Performance does not normally allow Sleep, Standby or Hibernate unless the Power Scheme has been changed by the user, (you should make a copy and change that instead).

Also... should I be running it *twice*? I'm not sure I understand your earlier post with the two screenshots...

-vevola (February 18, 2012, 09:13 AM)

Updated:
20120112 - Running it a second time reverts to the original power scheme and clears the RunOnce\pmt key.
20120120 - Outputs results into a window.

-4wd (January 05, 2012, 10:02 PM)

That's what the Revert in the output window signifies, Revert=Yes means it's being run for the second time and is setting the Power Scheme to it's original setting prior to the first time PMT was run, it also clears the RunOnce registry entry.

[vevola]

I'm running Win7 64x with "Balanced" power scheme.

To be honest, I tried using the revert, but now hibernation doesn't work at all. When it goes to sleep, I can't wake it up anymore. I see "resuming", and then a black screen and I have to force shut it down. I then see "delete restoration data" or "resume", and I have to "delete" for windows to boot. Which also means that if I forget to save whatever I have open and go away for a while... well... I loose everything.

Any tips?

[4wd]

OK, I'm going to need some more information:

Is your operating system on an SSD or HDD?

The output of the powercfg list command, (see below):

C:\>powercfg list

Existing Power Schemes (* Active)
-----------------------------------
Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced) *
Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c  (High performance)
Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a  (Power saver)
Power Scheme GUID: e12bd28e-68a8-4f90-b0a5-f76b2b523ca3  (AMD Fusion Utility Recovery Profile)

Can you do a screengrab of PMTs output window when you run it both the first and second time, (like I did here), and either PM them to me or attach to a post.

Can you do a screengrab of both the Balanced and High Performance Advanced settings of your Power Options, the default for both of them should look like this:



Also, after running it once what is the value of the PMT key stored under HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce (use regedit.exe) ?

What is it after running PMT a second time, (it shouldn't be there) ?

[vevola]

Is your operating system on an SSD or HDD?

SSD

The output of the powercfg list command

Microsoft Windows [Version 6.1.7601]
Existing Power Schemes (* Active)
-----------------------------------
Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced)
Power Scheme GUID: 49ef8fc0-bb7f-488e-b6a0-f1fc77ec649b  (Dell)
Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c  (High performance)
Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a  (Power saver) *

Can you do a screengrab of PMTs output window when you run it both the first and second time

Can you do a screengrab of both the Balanced and High Performance Advanced settings of your Power Options

Here's an archive with those screengrabs: http://dl.dropbox.co.../pmt_screenshots.rar

Also, after running it once what is the value of the PMT key stored under HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce (use regedit.exe) ?

powercfg.exe /setactive a1841308-3541-4fab-bc81-f71556f20b4a

What is it after running PMT a second time, (it shouldn't be there) ?

And it's not.

Thanks for your help!

[4wd]

Thanks, it shows that PMT is, (or trying to), switch from Power Saver to High Performance.

You didn't include the High Performance Advanced settings screengrab, could you please?

I'm running Win7 64x with "Balanced" power scheme.

-vevola (March 14, 2012, 03:41 PM)

The powercfg output shows you're running in the Power Saver scheme which is a bit more frugal than the Balanced scheme.

It also seems to indicate that there might be some form of power software installed by Dell, (only because I see a Dell power scheme there - AMD do the same thing if you run their Fusion software IIRC).

Thanks for your help!

No problem, it's just got me beat how it can be messing up your hibernation when all it does is swap power schemes, it doesn't change anything in those schemes.  It shouldn't even be going into Sleep/Hibernation when in High Performance, as you can see from my grab above, they're both set to Never by default.

You can also reset the power schemes to their default values by pressing the Restore Plan Defaults button under each schemes Advanced settings.

I've attached a small video of what happens when it runs - you can watch it change the power scheme each time it's run, (.7z because you can't attach .mp4 for some reason).

It's the equivalent of you typing in the following commands in a CLI, just as a matter of interest can you effect the same change from the CLI and does it do the same thing Hibernate-wise ?

powercfg /setactive 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c   (should set to High Performance)
powercfg /setactive a1841308-3541-4fab-bc81-f71556f20b4a    (should set back to Power Saver)

Anyone else care to try it with a Win7 laptop and see what happens?