Simple Counter Utility Wanted

[AndyM]

Would someone please make me a simple Counter Program in AHK?

Two reasons:  I could use the utility and it would also serve well as an example of some of the AHK code I'd like to be more familiar with.  The GUI creation and counting subroutines would save me a lot of trial and error working the code out for myself.

There would be a simple small (~100 pixel tall x ~200 pixels wide) dialog box with:

   - Two buttons: Increment counter by 1, Decrement counter by 1.
   - Counter display (this could even be on one of the buttons)
  
The other feature would be that the counter would automatically increment by 1 each hour on the hour.  I could manually adjust the counter with the buttons for a start value, which would be incremented by 1 on the next hour (at the top of the hour, not an hour after I start).

That's all I'd need, but if you wanted to teach me one other thing, it would be to make the dialog box, buttons, counter, etc in different colors if this can be done in AHK.  You can pick the colors.

Thanks in advance to any takers!

Andy

[skwire]

Here's a basic example (no colours):

Code: Autohotkey [Select]

1. ; -------------------
2. ; Set up environment.
3. ; -------------------
4. #NoEnv
5. #SingleInstance, Force
6. #Persistent
7. SetBatchLines, -1
8. SetControlDelay, -1
9. DetectHiddenWindows, On
10. SetWorkingDir, %A_ScriptDir%
11.  
12. ; -------------------------
13. ; Set any needed variables.
14. ; -------------------------
15. myCounter := 0
16. Allow_Counter_Update := True
17.  
18. ; -------------
19. ; Build out GUI
20. ; -------------
21. Gui, Margin, 3, 5
22. Gui, Font, s30
23. Gui, Add, Text  , xm     ym     w200 h100 0x1200 Center vCounter_txt          , % myCounter
24. Gui, Font
25. Gui, Add, Button, xm     ym+105 w95  h25                vPlus_btn    gOnButton, +1
26. Gui, Add, Button, xm+105 ym+105 w95  h25                vMinus_btn   gOnButton, -1
27. Gui, Show
28.  
29. SetTimer, OnHour, 1000 ; Fire every second.
30.  
31. Return ; End of auto-execute section.
32.  
33.  
34. GuiClose:
35. GuiEscape:
36. {
37.     ExitApp
38. }
39. Return
40.  
41.  
42. OnButton:
43. {
44.     If ( A_GuiControl = "Plus_btn" )
45.     {
46.         DoCounter( "Up" )
47.     }
48.     Else If ( A_GuiControl = "Minus_btn" )
49.     {
50.         DoCounter( "Down" )
51.     }
52. }
53. Return
54.  
55.  
56. OnHour:
57. {
58.     FormatTime, myNow, A_Now, HHmm
59.     If ( Mod( myNow, 100 ) = 0 ) ; We're at the top of an hour.
60.     {
61.         If ( Allow_Counter_Update = True )
62.         {
63.             ; Increase counter by one and then don't allow any more
64.             ; increases until the minute is up.  Otherwise, the
65.             ; counter would increase by one every second.
66.             DoCounter( "Up" )
67.             Allow_Counter_Update := False
68.         }
69.     }
70.    
71.     ; We are no longer in a top-of-the-hour minute so allow
72.     ; updates again for the next top-of-the-hour minute.
73.     If ( Mod( myNow, 100 ) != 0 )
74.     {
75.         Allow_Counter_Update := True
76.     }
77. }
78. Return
79.  
80.  
81. DoCounter( sWay )
82. {
83.     Global
84.    
85.     If ( sWay = "Up" )
86.     {
87.         myCounter++
88.     }
89.     Else If ( sWay = "Down" )
90.     {
91.         myCounter--
92.     }
93.     GuiControl, Text, Counter_txt, % myCounter
94. }

[AndyM]

Ah skwire, that's just perfect, exactly what I was looking for.  And the comments are quite helpful.

Thank you!!!   

Andy

[skwire]

You're most welcome.  Glad I could help.   

[skwire]

BTW, I just made a change to the code that I meant to make before I posted it.  Please refresh and re-grab the code.  Sorry about that.

[Winkie]

Of cource I can't beat skwire , but this is how I like it:

Code: Autohotkey [Select]

1. #NoEnv
2. #SingleInstance, Force
3. SetBatchLines, -1
4. SetControlDelay, -1
5.  
6. iMyCount := 0
7. bAllowUpdate := True
8.  
9. Gui, 1:+LabelMainGui
10. Gui, 1:Margin, 5, 5
11. Gui, 1:Font, s30
12. Gui, 1:Add, Text, xm w200 h100 0x1200 Center Section vCounterCtrl, % iMyCount
13. Gui, 1:Font
14. Gui, 1:Add, Button, ys w75 h25 Section vInput_btn gInputValue, Set
15. Gui, 1:Font, w700
16. Gui, 1:Add, Button, xs ys+45 w75 h25 gCountUp, +1
17. Gui, 1:Add, Button, xs w75 h25 gCountDown, -1
18. Gui, 1:Font
19. Gui, 1:Add, Checkbox, xm w138 h25 Checked vbDoHourCount gToggleHourCount, Count up on the hour
20. Gui, 1:Add, Checkbox, x+5 w138 h25 vbAllowNegatives, Allow negative values
21. Gui, 1:Show, Center, CountAM
22.  
23. SetTimer, HourCount, 1000
24. Return
25.  
26. MainGuiClose:
27. MainGuiEscape:
28. {
29.         ExitApp
30. }
31. Return
32.  
33. CountUp:
34. {
35.         iMyCount++
36.         FormatAndUpdate( iMyCount )
37. }
38. Return
39.  
40. CountDown:
41. {
42.         Gui, 1:Submit, NoHide
43.         If Not bAllowNegatives
44.         {
45.                 If iMyCount
46.                         iMyCount--
47.         }
48.         Else
49.                 iMyCount--
50.         FormatAndUpdate( iMyCount )
51. }
52. Return
53.  
54. HourCount:
55. {
56.         FormatTime, iMyNow, A_Now, HHmm
57.         If ( Mod( iMyNow, 100 ) = 0 ) ; We're at the top of an hour.
58.         {
59.                 If ( bAllowUpdate = True )
60.                 {
61.                         ; Increase counter by one and then don't allow any more increases until this minute is up.
62.                         Gosub, CountUp
63.                         bAllowUpdate := False
64.                 }
65.         }
66.         Else
67.         {
68.                 bAllowUpdate := True
69.         }
70. }
71. Return
72.  
73. ToggleHourCount:
74. {
75.         Gui, 1:Submit, NoHide
76.         If bDoHourCount
77.                 SetTimer, HourCount, 1000
78.         Else
79.                 SetTimer, HourCount, Off
80. }
81. Return
82.  
83. InputValue:
84. {
85.         Gui, 1:+Disabled
86.         Gui, 2:+LabelInputGui +Owner1
87.         Gui, 2:Margin, 12, 12
88.         Gui, 2:Add, Edit, xm w80 r1 Number
89.         Gui, 2:Add, UpDown, Range-32767-32767 viMyInput
90.         Gui, 2:Add, Button, x+15 w80 Default gNewInput, OK
91.         Gui, 2:Show, Center, Enter a value
92. }
93. Return
94.  
95. InputGuiClose:
96. InputGuiEscape:
97. {
98.         Gui, 1:-Disabled
99.         Gui, 2:Destroy
100. }
101. Return
102.  
103. NewInput:
104. {
105.         Gui, 2:Submit, NoHide
106.         Gui, 2:+OwnDialogs
107.         If Not iMyInput
108.         {
109.                 MsgBox, 36, Please confirm, Do you really want the value to be blank?
110.                 IfMsgBox No
111.                         Return
112.         }
113.         Gui, 1:-Disabled
114.         Gui, 2:Destroy
115.         Gui, 1:Default
116.         FormatAndUpdate( iMyInput )
117.         iMyCount := iMyInput
118.         iMyInput :=
119. }
120. Return
121.  
122. ; FormatInteger -- by Winkie
123. FormatAndUpdate( Int )
124. {
125.         vVar := Int
126.         If vVar < 0
127.         {
128.                 vMinus := "-"
129.                 StringTrimLeft, vVar, vVar, 1
130.         }
131.         Loop
132.         {
133.                 If vVar > 999
134.                 {
135.                         StringLen, vLen, vVar
136.                         vTrim := vLen - 3
137.                         StringTrimLeft, vPart, vVar, % vTrim
138.                         vOut := "." vPart vOut
139.                         StringTrimRight, vVar, vVar, 3
140.                 }
141.                 Else
142.                         Break
143.         }
144.         Gui, 1:Default
145.         GuiControl, Text, CounterCtrl, % vMinus vVar vOut
146. }

[skwire]

Nice job, Winkie.  Well done.   

[AndyM]

This is what I ended up with.

[skwire]

Nice, AndyM.  What are you using it for?

[AndyM]

Counting 

[app103]

It's almost similar to what you wanted, without the automatic incrementing, and without the deincrementing, and you need to have a target goal, it has a progress bar, it saves data to the registry (so it isn't portable)...and it's not written in AHK: AnotherOneDone (something I released for GOE challenge)