Podcast Conversion and dates

[oblivion]

I am a bit of a podcast addict. Sadly, I get a bit behind and -- because I TRY to be organised -- I keep my podcasts in a single folder, so I can sort them in date order, and transfer the oldest first to my MP3 player.

Mostly, this works very well. But one of the podcasts I regularly get comes in M4A format. Although the software I use to transfer stuff to my player converts things on the fly, I prefer to do the conversion myself so I can control the output quality and filesize a bit better.

So far, I have found the easiest way to do this is to use fre:ac (the new version of BonkEnc, still free though) to do the conversion to MP3, output the files somewhere away from the originals, then use another little freebie (filedate) to re-datestamp the new files to match the originals, so they don't get sorted to the end of the list. Fiddly and time-consuming, especially if you've only just got round to it after a few weeks of letting M4As build up...

Two related requests, then. Either a program that can suck in an audio file (or a list of files) and squirt out an MP3 with the same time/datestamp as the original, optionally deleting the original... or if doing that is too complex for a "snack", a program that can display two lists of files, allow them to be lined up by hand in case filenames don't quite match, then apply the date/timestamps from the source list to the destination list.

[mouser]

interesting...  in thinking about a general purpose solution, one question is, can you keep the base filenames the same?
if so then a good general purpose solution might be an app that scans a directory and sets the file date stamps for all sets of files with same basename (and different extensions) to the date of earliest datestamp in the set.

[skwire]

Either a program that can suck in an audio file (or a list of files) and squirt out an MP3 with the same time/datestamp as the original

-oblivion (March 21, 2011, 09:30 AM)

fre:ac actually comes with a commandline version in its install so that, combined with a small bit of AHK script, would make this a piece of cake.  Heck, you could even use the lame.exe file directly.  Do you have AutoHotkey installed?

[oblivion]

fre:ac actually comes with a commandline version in its install so that, combined with a small bit of AHK script, would make this a piece of cake.  Heck, you could even use the lame.exe file directly.  Do you have AutoHotkey installed?

-skwire (March 21, 2011, 11:17 AM)

I've got a portable copy somewhere, but I've never tried to use it. You're a proper programmer, I just pretend to know what it's about sometimes. 

(I can sometimes write very simple and mechanistic black boxes -- take some input textfile, chop it up, put it back together in a different order, exit. Anything requiring screen design or direct access to the Windows API, I'm running away so fast people are choking on the dust.)

[oblivion]

Do you have AutoHotkey installed?

-skwire (March 21, 2011, 11:17 AM)

Okay, just had a bit of a look at the helpfile for it. It looks like a file loop could be used to retrieve the file list and operate on them one at a time, and if I can throw commands at fre:ac or Lame, I might even be able to puzzle something out.

What I'm less sure about is -- as I suggested previously -- putting a front end on it. To make it reliable, I'd want a front end on it that allowed the specification of the input and output sources and a path to LAME or fre:ac or whatever, and I suppose to make it bulletproof it'd probably have to be able to specify encoder options and suddenly it's looking like I really should be running away from all this ui stuff   

[skwire]

Here's a proof-of-concept script.  

• Save this to <whatever>.ahk and put it in your fre:ac folder.
• Edit the myOutputDir variable to an output folder of your choice.
• Run the script.  You should see a small square begging for you to drop some files on it.
• Drop some files on it!
• They will be converted to mp3 and placed in your chosen output directory with the original modification times.

Code: Autohotkey [Select]

1. ; Set up environment.
2. #NoEnv
3. #SingleInstance, Off
4. SetBatchLines, -1
5. SetControlDelay, -1
6. DetectHiddenWindows, On
7. SetTitleMatchMode, 2
8. SetWorkingDir, %A_ScriptDir%
9.  
10. ; Variables.
11. AppName     := "Podblivion"
12. myOutputDir := "c:\tmp2"
13.  
14. ; Build simple drop target.
15. Gui, Add, Text, xm ym w150 h150 Center 0x200 vtxtDisplay, Drop files here...
16. Gui, Show, , % AppName
17. Return ; End of auto-execute section.
18.  
19.  
20. GuiDropFiles:
21. {
22.     myFiles := A_GuiEvent
23.     Loop, Parse, myFiles, `n
24.     {
25.         If ( A_LoopField != "" )
26.         {
27.             myFilePath := A_LoopField
28.            
29.             ; Notify user that we're doing something.
30.             SetTimer, Progress, On
31.            
32.             ; Get modified time of dropped file.
33.             FileGetTime, modTime, % myFilePath, M
34.            
35.             ; Crack path and form up output filename with mp3 extension.
36.             SplitPath, myFilePath, , , , myFileNameNoExt
37.             myOutputFile := myOutputDir . "\" . myFileNameNoExt . ".mp3"
38.            
39.             ; Set parameters for the freaccmd.exe program.
40.             cmdParams := "-e LAME -m VBR -b -q 5 -d " . myOutputDir . " """ . myFilePath . """"
41.            
42.             ; Convert file.
43.             RunWait, % A_ScriptDir . "\freaccmd.exe " . cmdParams, , Hide
44.            
45.             ; Set output file's modified time to input file's value.
46.             FileSetTime, % modTime, % myOutputFile, M
47.         }
48.     }
49.     SetTimer, Progress, Off
50.     GuiControl, Text, txtDisplay, Drop files here...
51. }
52. Return
53.  
54.  
55. Progress:
56. {
57.     GuiControl, Text, txtDisplay, Converting |
58.     Sleep, 250
59.     GuiControl, Text, txtDisplay, Converting /
60.     Sleep, 250
61.     GuiControl, Text, txtDisplay, Converting -
62.     Sleep, 250
63.     GuiControl, Text, txtDisplay, Converting \
64.     Sleep, 250
65. }
66. Return
67.  
68.  
69. GuiClose:
70. GuiEscape:
71. {
72.     ExitApp
73. }
74. Return

[oblivion]

interesting...  in thinking about a general purpose solution, one question is, can you keep the base filenames the same?
if so then a good general purpose solution might be an app that scans a directory and sets the file date stamps for all sets of files with same basename (and different extensions) to the date of earliest datestamp in the set.

-mouser (March 21, 2011, 09:32 AM)

Sorry, I didn't notice this response before. I don't see why you couldn't constrain most conversion apps to work in that way, and it occurs to me that a general purpose app that took that approach might be useful for all sorts of things where you might want the creation date to be retained in a different file format. Photos as well as audio -- maybe even MORE than audio, since I suspect my idiosyncratic approach to podcasts may not be "normal." 

[oblivion]

Here's a proof-of-concept script. 

-skwire (March 21, 2011, 12:07 PM)

Thanks!

It doesn't seem to want to work, though. The script is in the freac app directory (\portableapps\freacportable\app\freac) and freaccmd.exe is present in the same place. I can drop an m4a onto it and it does the "converting" thing for a little while then stops, but I can't find any sign of the output file in the folder I specified (g:\temp) or, indeed, anywhere else.

Any idea what might be going wrong, or how I can watch what it's doing in more detail, perhaps?

[skwire]

Any idea what might be going wrong, or how I can watch what it's doing in more detail, perhaps?

-oblivion (March 23, 2011, 05:58 AM)

On line 43, you can take off the "Hide" keyword.  This will allow you to see the freaccmd.exe window.