IDEA: delete files in one folder according to files in another folder

[lijieliang]

I have some files in one folder and these same files in another folder with a lot more files. How do I delete these files in that folder with a lot more files?
thank you in advance.

[skwire]

To clarify, you have a list of files in, say, Folder A.  If those same filenames exist in Folder B, you want them deleted.  Is this correct?

[lijieliang]

that's correct.

[skwire]

Try this (source/binary included):  Download

Code: AutoIt [Select]

1. ; Set environment.
2. SetBatchLines, -1
3. SetControlDelay, -1
4. DetectHiddenWindows, On
5. SetWorkingDir, %A_ScriptDir%
6.  
7. ; Build main GUI.
8. GoSub, Gui_Build_Main
9.  
10. Return ; End of auto-execute section.
11.  
12.  
13. Gui_Build_Main:
14. {
15.     ; Build GUI.
16.     Gui, Margin, 3, 5
17.     Gui, Add, Text    , xm     ym    w50  h20 Right 0x200                  , Folder #1:
18.     Gui, Add, Edit    , xm+55  ym    w270 h20             vFolder_1        ,
19.     Gui, Add, Button  , xm+330 ym    w30  h20             vBrowse_1 gBrowse, ...
20.     Gui, Add, Text    , xm     ym+25 w50  h20 Right 0x200                  , Folder #2:
21.     Gui, Add, Edit    , xm+55  ym+25 w270 h20             vFolder_2        ,
22.     Gui, Add, Button  , xm+330 ym+25 w30  h20             vBrowse_2 gBrowse, ...
23.     Gui, Add, Button  , xm+170 ym+53 w190 h25             vDelete   gDelete, &Delete matching files to Recycle Bin
24.     Gui, Add, Statusbar
25.         SB_SetText( "Ready.", 1 )
26.     GUI_ID := WinExist()
27.     Gui, Show, AutoSize Center, Match & Recycle
28. }
29. Return
30.  
31.  
32. GuiEscape:
33. GuiClose:
34. {
35.     ExitApp
36. }
37. Return
38.  
39.  
40. Delete:
41. {
42.     Gui, 1: Submit, NoHide
43.  
44.     ; Basic pre-check.
45.     If ( Folder_1 = "" OR Folder_2 = "" OR ! FileExist( Folder_1 ) OR ! FileExist( Folder_2 ) )
46.     {
47.         MsgBox, 48, Error, Please select valid folders.
48.         Return
49.     }
50.  
51.     Loop, % Folder_1 . "\*.*", 0, 0
52.     {
53.         SB_SetText( "Processing: " . A_LoopFileName, 1 )
54.  
55.         If FileExist( Folder_2 . "\" . A_LoopFileName )
56.         {
57.             FileRecycle, % Folder_2 . "\" . A_LoopFileName
58.         }
59.     }
60.  
61.     SB_SetText( "Done.", 1 )
62. }
63. Return
64.  
65.  
66. Browse:
67. {
68.     Gui, 1: Submit, NoHide
69.     If ( A_GuiControl = "Browse_1" )
70.     {
71.         Folder_1 := ""
72.         FileSelectFolder, Folder_1, , 2, Select first folder.
73.         If ( ErrorLevel != 1 )
74.         {
75.             GuiControl, Text, Folder_1, % Folder_1
76.         }
77.     }
78.     Else If ( A_GuiControl = "Browse_2" )
79.     {
80.         Folder_2 := ""
81.         FileSelectFolder, Folder_2, , 2, Select second folder.
82.         If ( ErrorLevel != 1 )
83.         {
84.             GuiControl, Text, Folder_2, % Folder_2
85.         }
86.     }
87.     ; Right justify the edit control's content if longer than the control's length
88.     SendMessage, 0xB1, 500, 500, Edit1 ; 0xB1 is EM_SETSEL
89.     SendMessage, 0xB1, 500, 500, Edit2 ; 0xB1 is EM_SETSEL
90. }
91. Return

[lijieliang]

that does the job. thanks a lot.

[skwire]

You're welcome.  Happy to help.