IDEA: Click counter

[Notok]

This is something that I could really use for some testing that I'm doing right now. What I want/need should be pretty simple (emphasis on "should"). I just want a small app that will run in Vista and keep a count of the number of times the mouse is clicked within a specified program. It should have easily accessible Start, Stop, and Reset buttons. It would be nice if it would show how long it's been tracking clicks and stay on top as well.

[fenixproductions]

2Noteok
The best one I've ever tried:
http://www.fridgesoft.de/odoplus.php

[Notok]

Aha, that will do, thank you I looked around but didn't find anything. I guess I just couldn't think of the right keywords.

Thanks again!

[Notok]

Okay, one thing that I'm not seeing, however, is the ability to only track clicks within one program. I see that it shows where you've clicked, but what I'd really like is to be able to set it to count the number of clicks within, say, Word, but not increase the count if I check my email, click the Start button, and so on.

I still do appreciate the suggestion, and will use it for the time being, but if it would be possible to get a program that would count clicks just within a selected app, that would be great

[VideoInPicture]

It's doable to track clicks per application but do you want click tracking for all the instances of a single application or just for one open instance. For example, I could program it so that the program just tracks the clicks in one open window of Firefox or I could program it so that it tracks the clicks in all open windows of Firefox. Tracking the clicks in a single window is simpler to program than to track the clicks in all the open windows of a given program.

[Notok]

I think that just one would be fine I would actually be looking to use this on programs that don't do multiple instances.

One thing that might be nice would be to have the ability to have it continue on into a new session (of the target app, not the counter), as long as it's not difficult. I would think this to be little more than just requiring the user to reset stats rather than clearing them automatically the next time the counter is started. I could also potentially see this as being a roundabout way to count clicks in another instance, but I digress

Thanks!

[skrommel]

  Try CliCount!

Rightclick the tray menu to change the title to watch and reset the counters.

Skrommel

[Select]

;CliCount.ahk
; Count clicks in a user defined window
;Skrommel @ 2008

#NoEnv
#SingleInstance,Force
#Persistent,On
SetTitleMatchMode,2

applicationname=CliCount

OnExit,EXIT
Gosub,TRAYMENU
buttons=lrm
IniRead,title,%applicationname%.ini,Settings,title
If title=Error
  title=
Loop,Parse,buttons
{
  IniRead,%A_LoopField%button,%applicationname%.ini,Settings,%A_LoopField%button
  If %A_LoopField%button=ERROR
    %A_LoopField%button=0
}
Return


~*LButton::
~*RButton::
~*MButton::
StringTrimLeft,hotkey,A_ThisHotkey,2
MouseGetPos,,,mwin
WinGetTitle,mtitle,ahk_id %mwin%
IfInString,mtitle,%title%
  %hotkey%+=1
Return


TRAYMENU:
Menu,Tray,NoStandard
Menu,Tray,DeleteAll
Menu,Tray,Add,%applicationname%,SHOW
Menu,Tray,Add,
Menu,Tray,Default,%applicationname%
Menu,Tray,Add,E&xit,EXIT
Menu,Tray,Tip,%applicationname%
Return


SHOW:
InputBox,newtitle,%applicationname%,Left:`t%lbutton%`nRight:`t%rbutton%`nMiddle:`t%mbutton%`n`nPart of Window Caption:,,,,,,,,%title%
If ErrorLevel=1
  Return
title=%newtitle%
MsgBox,4,%applicationname%,Reset counters?
IfMsgBox,No
  Return
lbutton=0
rbutton=0
mbutton=0
Return


EXIT:
IniWrite,%title%,%applicationname%.ini,Settings,title
IniWrite,%lbutton%,%applicationname%.ini,Settings,lbutton
IniWrite,%rbutton%,%applicationname%.ini,Settings,rbutton
IniWrite,%mbutton%,%applicationname%.ini,Settings,mbutton
ExitApp

[Notok]

Any chance someone could compile this for me?

And thank you very much for that

[wreckedcarzz]

I will; I'll edit this post in a minute with it up.

EDIT: Here ya go

[Notok]

yay, thank you much!