Oh, and i forgot to mention that Gothi[c] kindly created me a dcmembers account before i has to ask so the site should be up soon

nogojoe> can you explain your request please ? I'm sorry, i didn't get it

Hi ak_

what I was meaning was once filenanny had done its job and put the file into a folder the next step for me is to archive that folder ie  move that folder to "I" drive.
Am just wondering if that move could be incorporated into filenanny ie an option to select a folder which to archive (move) the filenannied folders to.
thanks  nogojoe

Lanux> i'm using Subdude everyday too I'm thinking of a new version, with better season/episode recognition, but it's tough because there are so many different patterns (the "401,402,403" being the more problematic).

i was thinking maybe you can split the 1st digit only since most of the series do not run into double-digit seasons. X-Files stopped at nine but i couldn't think of others.. and i guess i'd be better off posting in the Subdude thread itself before veering off-topic.

btw, thanks for the new version of FileNanny!

P.S. what about version numbering? they'd be easier to track.

Hi ak_

Thanks for incorporating my suggestion into FileNanny. The updated program does move multiple files with same name/dif extension to the newly created folder. However, at first I didn't think it was working, as it seems to work differently than the original version. When I select the file(s) with the new version and select filenany through the right context menu nothing initially happens. At first I thought the updated program wasn't working at all, later I returned to the folder that I had run FileNanny in and the folders had been created and the files moved. It seems that I must select refresh within windows explorer for the changes to occur. With the prior version the changes were made immediately after selecting the FileNanny option. With the new version on my system the changes only occur after refreshing the folder view. I don't know if anyone else has noticed this behavior.

Thanks for the revision, I just thought I'd let you know about this behavior on my system.

However, at first I didn't think it changes were made immediately after selecting the FileNanny option. With the new version on my system the changes only occur after refreshing the folder view. I don't know if anyone else has noticed this behavior.

Thanks for the revision, I just thought I'd let you know about this behavior on my system.

I had that same problem yesterday I didn't think the new version was working 100% right but it did create the folders after a while I don't what made it work but I can only hazard a +guess.
TheBigGuy you are right, however after booting up this morning and seeing your post I tried filemannying three desktop shortcuts on the desktop worked 100% ok.

So after removing the shortcuts from the folders and deleting the folders tried filenannying the same shortcuts again didn't work !!!    tried the F5 refresh and strangely it worked.

I'm saying strange because the shortcuts were still there visible on the desktop however folders with their names had been created.
So I opened one of those newly created folders and found that another folder was inside with the shortcuts name plus filenanny   as its name.    ie:  1st folder named "tabslock" 2nd folder named "tabslock filenanny"  and strangely the shortcut was inside that folder.

I'm running XP SP3

nogojoe

Done Here is FileNanny 1.3.1 (version number kinda randomly chosen) : [not available]

Changelog :
- if the folder already exists, FileNanny uses it instead of acting lunatic (that's an improvement, isn't it ?).
- added a FileNanny.nfo info file

Source code (as usual, really messy and obscure, even for me) :

;; FileNanny
;; version 1.3.1
;; "Go to your room !"
;; by ak

#SingleInstance ignore
iniFile = %A_ScriptDir%\FileNanny.ini
if 0 = 0
{
gosub CreateGUI
gosub checkboxes
}

else
{
Iniread shiftKey, %iniFile%, options, shiftKey
Iniread similar, %iniFile%, options, similarfiles
GetKeyState kstate, Shift
if (shiftKey = 1 and kstate = "D")
  editFolder = 1
if (shiftKey = 0 and kstate = "U")
  editfolder = 1
Loop, %0%
{
param := %A_Index%
SplitPath param, fileName, dirName, extension, fileNameNoExt
rawName = %fileNameNoExt%
gosub convert
if editFolder = 1
{
  InputBox InputRawName, FileNanny, Name of the folder to create, , 320, 120, , , , , %rawName% 
  rawName = %InputRawName%
  if ErrorLevel
    ExitApp
}

dirToCreate = %dirName%\%rawName%
IfNotExist, %dirToCreate%
  FileCreateDir %dirToCreate%.FileNanny
IfExist, %dirToCreate%
  FileMoveDir %dirToCreate%, %dirToCreate%.FileNanny, 1

fileNewName = %rawName%.%extension%
FileMove %param%, %dirToCreate%.FileNanny\%fileNewName%

;; Similar files detection
if (similar = 1)
{
  Loop %dirName%\*.*
  {
    Splitpath A_LoopFilename, , , ,similarNoExt
    if (similarNoExt = rawName)
    {
      FileMove %dirName%\%A_LoopFilename%, %dirToCreate%.FileNanny\%A_LoopFilename%
    }
  }
}
;;
FileMoveDir %dirToCreate%.FileNanny, %dirToCreate%, 1
}
ExitApp
}
return

CreateGUI:
  gui destroy
  RegRead, regTest, HKEY_CLASSES_ROOT, *\shell\FileNanny
  if strlen(regTest) = 0
  {
    button1Text = Add context menu item
    button1Action = addCMI
  }
  else
  {
    button1Text = Remove context menu item
    button1Action = remCMI
  }
  
  sendToFolder = %UserProfile%\SendTo
  ifnotExist %sendToFolder%\filenanny.lnk
  {
    button2text = Add 'Send to' shortcut
    button2action = addST
  }
  else
  {
    button2text = Remove 'Send to' shortcut
    button2action = remST
  }
  
  Gui, Add, Button, x126 y225 w70 h30 gQuit, Quit
  Gui, Add, Tab, x3 y5 w315 h260 vSelectedTab, Configuration|Options
  Gui, Font, s9 w600
  Gui tab, Configuration
  Gui font, norm
  Gui, Add, Button, x90 y65 w140 h30 g%button1Action% vCMIb, %button1Text%
  Gui, Add, Button, x90 y125 w140 h30 g%button2Action% vSTb, %button2Text%
  Gui tab, Options
  if strlen(regTest) = 0
  {
    regTest = n/a
    disabledOrNot = disabled
  }
  Gui, Add, text, x26 y59 w190 h20 vCurrentCMI, Current : %regTest%
  Gui, Add, Button, x226 y55 w70 h20 %disabledOrNot% gchangeCMI vCMIc, Change
  Gui, Add, GroupBox, x16 y35 w290 h50 , Context menu text
  Gui, Add, CheckBox, x16 y95 w300 h30 vshiftKey gini, Holding the Shift key is required to modify `nfolder name before its creation
  Gui, Add, GroupBox, x16 y135 w290 h50 , Convert these to spaces
  Gui, Add, CheckBox, x30 y150 w50 h30 vconvDot gini, .
  Gui, Add, CheckBox, x80 y150 w50 h30 vconvMinus gini, -
  Gui, Add, CheckBox, x130 y150 w50 h30 vconvUnderscore gini, _
  Gui, Add, CheckBox, x180 y150 w50 h30 vconvPercent gini, `%20
  Gui, Add, CheckBox, x16 y195 w300 h30 vsimilar gini, Move similar files
  Gui, Show, h270 w320, FileNanny
return

ini:
Gui submit, NoHide
Iniwrite %shiftKey%, %iniFile%, options, shiftkey
Iniwrite %convDot%, %iniFile%, convert, dots
Iniwrite %convMinus%, %iniFile%, convert, minus
Iniwrite %convUnderscore%, %iniFile%, convert, underscore
Iniwrite %convPercent%, %iniFile%, convert, percent
Iniwrite %similar%, %iniFile%, options, similarfiles
return

checkBoxes:
Iniread shiftKey, %iniFile%, options, shiftKey
Iniread convDot, %iniFile%, convert, dots
Iniread convMinus, %iniFile%, convert, minus
Iniread convUnderscore, %iniFile%, convert, underscore
Iniread convPercent, %iniFile%, convert, percent
Iniread similar, %iniFile%, options, similarfiles
Guicontrol ,,shiftKey, %shiftKey%
Guicontrol ,,convDot, %convDot%
Guicontrol ,,convMinus, %convMinus%
Guicontrol ,,convUnderscore, %convUnderscore%
Guicontrol ,,convPercent, %convPercent%
Guicontrol ,,similar, %similar%
return

convert:
Iniread convDot, %iniFile%, convert, dots
Iniread convMinus, %iniFile%, convert, minus
Iniread convUnderscore, %iniFile%, convert, underscore
Iniread convPercent, %iniFile%, convert, percent
if convDot = 1
  StringReplace rawName, rawName, ., %A_SPACE%, A
  
if convMinus = 1
  StringReplace rawName, rawName, -, %A_SPACE%, A
  
if convUnderscore = 1
  StringReplace rawName, rawName, _, %A_SPACE%, A
  
if convPercent = 1
  StringReplace rawName, rawName, `%20, %A_SPACE%, A
return

ChangeCMI:
RegRead, regTest, HKEY_CLASSES_ROOT, *\shell\FileNanny
transform,eperluette,chr,0x26
Inputbox newCMI, Enter new context menu text, Please choose the text that will appear in the context menu., , , , , , , , %regTest%
If ErrorLevel
{
  return
}
else
{
  RegWrite, REG_SZ, HKEY_CLASSES_ROOT, *\shell\FileNanny, , %newCMI%
  Guicontrol,, currentCMI, Current : %newCMI%
}
return

AddCMI:
RegWrite, REG_SZ, HKEY_CLASSES_ROOT, *\shell\FileNanny, , FileNann&y !
RegWrite, REG_SZ, HKEY_CLASSES_ROOT, *\shell\FileNanny\command, , "%A_ScriptFullPath%" "`%L"
Guicontrol,, CMIb, Remove context menu item
Guicontrol +gremCMI, CMIb
Guicontrol,, currentCMI, Current : FileNann&y !
Guicontrol enable, CMIc
return

RemCMI:
RegDelete HKEY_CLASSES_ROOT, *\shell\FileNanny
Guicontrol,, CMIb, Add context menu item
Guicontrol +gaddCMI, CMIb
Guicontrol,, currentCMI, Current : n/a
Guicontrol disable, CMIc
return

addST:
FileCreateShortcut, %A_ScriptFullPath%, %sendToFolder%\filenanny.lnk
Guicontrol,, STb, Remove 'Send to' shortcut
Guicontrol +gremST, STb
return

remST:
FileDelete, %sendToFolder%\filenanny.lnk
Guicontrol,, STb, Add 'Send to' shortcut
Guicontrol +gaddST, STb
return

Quit:
GuiClose:
GuiEscape:
  ExitApp
return

Here is FileNanny 1.4 :  (see attachment in previous post)
Changelog :
- Added the Autoarchive feature to automatically move newly created folders to an archive folder.

Thanks ak_ for your explanation.

tried the 1.4 version and it works ok except it did not remove (delete) the file that was filenannied   .....that was until I hit F5  then it disappeared.

Carried on and tried another file from a folder on the desktop and it did the same didn't remove the file after being filenannied however this time I just closed the folder that file was in and reopened the same folder and it had gone.

Dunno if perhaps you could include a auto-refresh at the end of the code might solve the problem.

Thanks for the autoarchive option that works just great.

nogojoe

nogojoe> i assume you use Windows Explorer ? I guess i could send a "F5" to the active window if this window is Explorer, but i don't really like the idea. The main reason is that the problem doesn't come from my code but from the fact that, obvisouly, the file explorer you use doesn't automatically refresh.

that's ok ak_ it's just a minor thing that I can live with .At least I know about it other than that it works just fine.
I guess the file explorer is Window's Explorer as I don't run anything else as a file explorer.

Thanks nogojoe

Wow.
Hello all.
You know I really can't remember how I came to find this thread today but I am glad I did
Reading through, it is interesting to see the changes made from the start up to where the program is up to now.
Let me say thank you so much for this useful utility!!
It's great.
EDIT: Let me just add that, as I have browsed this thread I have downloaded and tried each development and looked at the changes and the versions.
After trying the most recent one I decided to go back... I'm not criticising here, it is just that I only need the functions that your version number 1.0.47.6  gives me.
To do the original function of file>folder and the added bonus option of choosing the name of the created folder.
Brilliant.
I must admit though, it was the refresh thing that helped me decide 
Maybe it's just the amount of coffee I drink - no patience!
Seriously though the older one is great for me.  I don't need any archiving etc functions.
This program fills a gap where nothing, as far as I know, has done in the past.
I really love it and have used it a few times already sisnce just having downloaded it less than an hour ago!
Cheers 

I just tested it by going through the versions and it seems that the version I quoted there is the last one that doesn't have that 'problem'.
It is strange I agree. As if there is something causing a delay or hang but I know there is nothing much happening behind the scenes once the program has done the folder creation renaming etc so erm...I'm no programmer at all apart from some customisations of windows with various batchfiles and the odd vbs script so I can't help I'm afraid - wish I could!
Is it a good idea to add an auto refresh after every file move?
Would that interfere with anything else explorer wise I wonder?
I will watch this space as it's interesting to see it develop. 
Like a mini soap opera you have going here 

Hmm that is weird.
That's what I get from the properties of it!
I will attempt to attach it.
PLEASE PEOPLE DO NOT DOWNLOAD THIS AS AN UPDATE - IT ISN'T!
Here you go - have a looksee.
Cheers 

Oh right. Oops.  I haven't bothered with AutoHotkey. I installed it once and was um, confused. That is about as far as I took it 
Been using the program so much since I got it mate, I must spread the word about this File Nanny!

This might help with auto refresh. It's one of the lines in the toggle hidden files/extensions script found here
http://www.autohotkey.com/forum/topic27739.html

 PostMessage, 0x111, 28931,,, ahk_id %ID%

In that script there's a 500ms Sleep command to allow time for the changes