DONE: Skinny Paste

[pulphero]

I've tried many of the clip 'n paste apps but find they either do too much or don't easily do what I want done.

Here's what I'm looking for:

A hotkey-enabled pop-up with a plain text list of 10 short phrases (could be URLs, could be single words, could be sentences). Click the phrase and it pastes as plain text into the active application. That's it! Nothing fancy. As lightweight as possible, too.

I realize that lots of software, e.g., AceText, can do this for me. But I don't need additional functionality and would like to keep it clean and simple.

Thanks!

-- Bob

[mouser]

sounds like a good idea for a coding snack to me.

[skwire]

A hotkey-enabled pop-up with a plain text list of 10 short phrases (could be URLs, could be single words, could be sentences). Click the phrase and it pastes as plain text into the active application. That's it! Nothing fancy. As lightweight as possible, too.

Can each of your ten entries be contained on one line or do you envision multiline entries i.e. an entry with a carriage return?

[mouser]

quick tip, for FARR users, it's really easy to make an alias with a list of items you can quickly paste into running application, and which you can search through and choose by typing.
just make an alias and in the results put a list of items like so:



though i still think this is a perfect case for a simple coding snack.

[rjbull]

Maybe Solway's CLIPTEXT ?  It's lightweight all right; only 140K download.  You'd need to check it works on late-model Windows, though.

Solway's own screenshot:

[pulphero]

Can each of your ten entries be contained on one line or do you envision multiline entries i.e. an entry with a carriage return?

One line - though multi-line entries would be nice in case a need for them arises down the road.

[pulphero]

Maybe Solway's CLIPTEXT ?  It's lightweight all right; only 140K download.  You'd need to check it works on late-model Windows, though.

Thanks! I downloaded the software and gave it a spin.

It works as advertised but it's not right for me because clicking a clip only loads it into the clipboard. I need the clip pasted in the active app. I wasn't able to set a hotkey, either.

Also - and maybe this is an example of ClipText not working well with later versions of Windows - clicking a clip shuts down the program.

[skwire]

@pulphero: Any particular hotkey you would like to use?

[pulphero]

@pulphero: Any particular hotkey you would like to use?

Yes - the one I have mapped to my middle mouse button: CONTROL SHIFT Q

[skwire]

Here you go (source/binary included):  SkinnyPaste

Create a clips.txt file in the same folder as the SkinnyPaste executable and then run SkinnyPaste.exe.  Put one clip per line in this format: <menu caption>|<clip text>

Code

My email|pulphero@pulphero.com
Homepage|http://www.pulphero.com

If you make changes to the clips.txt file, simply right-click the tray icon and choose reload.  Currently, you can only have single line clips but you can have as many as you would like i.e. more than ten.  At this point, I just wanted to see if this is what you had in mind.

Here's the code for the folks that don't want to download the zip.

Code: (autohotkey)

SetBatchLines, -1

; Read clips.txt file into a variable.
FileRead, myClips, % A_ScriptDir . "\clips.txt"

Loop, Parse, myClips, `n, `r
{
    If ( A_LoopField != "" )
    {
        ; Extract menu entry text before the first pipe character.
        MenuEntry := SubStr( A_LoopField, 1, InStr( A_LoopField, "|" ) - 1 )
        
        ; Build the menu using the extracted text. 
        Menu, ClipMenu, Add, % MenuEntry, OnClipMenu
    }
}
Return ; End of auto-execute section.


OnClipMenu:
{
    Loop, Parse, myClips, `n, `r
    {
        If ( A_LoopField != "" )
        {
            If ( A_Index = A_ThisMenuItemPos )
            {
                ; Extract all text from the first pipe character to the end of the string.
                Clip := SubStr( A_LoopField, -( StrLen( A_LoopField ) - InStr( A_LoopField, "|" ) - 1 ) )
                
                ; Activate the window that active when the clip menu was instantiated.
                WinActivate, % "ahk_id " . activeID
                WinWaitActive, % "ahk_id " . activeID
                
                ; Saved previous clipboard contents.        
                SavedClip := ClipboardAll
                
                ; Put extracted clip contents on the clipboard and give it a second.
                Clipboard := Clip
                ClipWait, 1
                
                ; Paste clip contents.
                SendInput, ^v
                
                ; Restore saved clipboard contents.
                Clipboard := SavedClip
            }
        }
    }
}
Return


^+q:: ; Change hotkey to suit.
{
    ; Get the ID of the active window.
    WinGet, activeID, ID, A
    
    ; Show the clip menu.
    Menu, ClipMenu, Show
}
Return

[pulphero]

How cool - thanks very much! I'll try it out tonight.

[pulphero]

The script does exactly what I want. It works perfectly, and it's going to save me a lot of time.

Thanks again for giving me in a day what I've spent weeks searching for.

-- Bob

[skwire]

Thanks again for giving me in a day what I've spent weeks searching for.

You're very welcome.  I'm glad I could help.

[nogojoe]

Thanks again for giving me in a day what I've spent weeks searching for.

You're very welcome.  I'm glad I could help.

Another great coding snack Skwire  thanks.love it

btw how do you get seperator eg <menu caption>|<clip text> for the text file from off the keyboard .excuse my ignorance on this one .Just been copy pasting it for my purposes

Just found it my keyboard has it as 2 vertical dashes not a full vertical dash .Fluked finding it by changing the  hotkey to crtl shift \  and I hit shift | by mistake lol 

nogojoe

[sri]

To the OP: You just described ClipX!

[skwire]

To the OP: You just described ClipX!

Not really.  IMHO, the OP didn't want a clipboard manager; he wanted a quick-paste menu for some pre-determined pieces of text.  Not quite the same.

[222fbj]

You might try Notetab - a free/light text editor, which includes a clipboard.

To use the clipboard go to (menu) Document>Use as Pasteboard

http://notetab.com/

[pulphero]

You might try Notetab - a free/light text editor, which includes a clipboard.

I've used (and still use, every day) NoteTab Pro for years - but it doesn't do what I asked for and which skwire helpfully created for me.

[msteph]

skwire, this looks like a very handy little app but I must be doing something wrong (wouldn't be the first time) because it doesn't work for me as it does for pulphero.

I created the clips.txt file. ran SkinnyPaste.exe, pressed CONTROL SHIFT Q to bring up the list but when I click on one of the items, that text is not pasted into metapad (my active application) but rather whatever is already on the clipboard is pasted.

IOW, for some reason SkinnyPaste is not reading the chosen item to the clipboard for it to then be pasted.

Also you say "If you make changes to the clips.txt file, simply right-click the tray icon and choose reload."

If I right-click the tray icon, the only choices I see are "Suspend Hotkeys", "Pause Script" and "Exit", no 'reload' option.

What am I doing wrong?

[pulphero]

It sounds like you're running the executable. If you run the script itself and then right-click its icon in the task bar, you'll see the Reload option.

When I run the executable I don't see that option, either.

[skwire]

It sounds like you're running the executable. If you run the script itself and then right-click its icon in the task bar, you'll see the Reload option.

When I run the executable I don't see that option, either.

Yep, it has to do with running the executable.  I'm fixing it so give me just a minute.

[skwire]

Here's an updated version that includes a modified tray menu that should work with either the .ahk or the .exe file.

SkinnyPaste

@msteph: I'm not sure what the issue could be on your system.  I downloaded Metapad and it seems to work fine here.  That being said, I did increase the clipboard wait period in this latest build.  Could you please clear your cache, redownload, and try again?  You'll know you have the newer version if the tray menu only shows two entries now.  Please let me know how it goes.  Thanks.

[msteph]

>When I run the executable I don't see that option, either.


pulphero, when you run the executable, either the old one or the brand new one, does the app actually work?

[msteph]

@msteph: I'm not sure what the issue could be on your system.  I downloaded Metapad and it seems to work fine here.  That being said, I did increase the clipboard wait period in this latest build.  Could you please clear your cache, redownload, and try again?  You'll know you have the newer version if the tray menu only shows two entries now.  Please let me know how it goes.  Thanks.

skwire, downloaded the new .exe, cleared the cache and ran it.  It now does show the two entries in the tray as you mention ("Reload clips" and "Exit") but it still doesn't pick up the item I click on, just whatever's on the clipboard.  If the clipboard is blank/empty (via CCleaner) then nothing is pasted.

Hmmmm....

In any case, thank you very much (and pulphero) for responding so quickly to my post!

[pulphero]

>When I run the executable I don't see that option, either.


pulphero, when you run the executable, either the old one or the brand new one, does the app actually work?

Like a charm.