Multiple screen capture but slip each in to each file!

[huancoi]

I have a pc with 2 monitor, i already use screenshot captor to capture complete workspace. But i want to slip screenshot of each monitor in 2 file (not in just one like default setup).
Please hlep.

[mouser]

Oh that's an interesting idea.. First time it has come up.. Let me chew on it...

[huancoi]

The software is geat, but i need to slip the screenshot everytime i capture. And when i capture to many screenshot, the work is hard.

[Ath]

but i need to slip the screenshot everytime i capture

What does "slip" mean in this context?

[huancoi]

oh, i mean separate picture for each monitor.

[Ath]

Ah, well, but for now you could use "Grab current Screen" (default hotkey is PrtScr I think), switch to the other screen and press the same hotkey again? Yes, there will be a time difference of a few (milli)seconds, but the filename timestamps will be quite close.
Eventually you'd want the screen number to be part of the filename as the files will/should have the same timestamp, but I think (from looking at the File Naming config screen) that's not yet available for the filename pattern.

[huancoi]

So , i have to do it twice, quite unconvenient.

[KodeZwerg]

oh, i mean separate picture for each monitor.

So , i have to do it twice, quite unconvenient.

You want one-action to do several different seperated things, a bit uncommon.

Suggestion to Mouser: add simple scripting like support where User can run script by Hotkey to capture whatever scriptfile contains?
eg for a Region script: Monitor 1, xPos 50, yPos 100, xSize 640, ySize 480, Interval 0
eg for Grab Window: Monitor 0, GrabWindow_Name, Interval 0

Something like that would make this User happy.

edit
Or way more easy scripting handling, scriptfile just contain "action 1;action 2;action 3" etc
And in your GUI let User define Actions. In my head this sounds nice.

[Ath]

So , i have to do it twice, quite unconvenient.

That's why I wrote "...for now you could use..." (emphasis added).
I'm assuming you have turned off all dialogs and popups from SSC, just saving the image? That would make it a quick action.

@Mouser said he'll look into it, and that will probably take a few days, please apply some patience.

Another alternative is you grab the entire desktop and split the images that are wider than 1 monitor into multiple images using ImageMagick (no affiliation)
You can configure that as a Post-Capture tool in Screenshot Captor, if you like.

[mouser]

I'm surprised that I don't have a commandline option to capture a specific monitor screen by monitor # in my MiniCap program (the little brother to Screenshot Captor), so the least I can do is add that right away in the next day or so.

[Ath]

Adding a "save for separate monitors" feature to Screenshot Capture would also give the desire/requirement/prerequisite to get the matching monitor number in the filename, so you'd have to add that as a variable too, I guess. And maybe also for MiniCap?

[huancoi]

I'm surprised that I don't have a commandline option to capture a specific monitor screen by monitor # in my MiniCap program (the little brother to Screenshot Captor), so the least I can do is add that right away in the next day or so.

Thank you, that would be nice.

[mouser]

I have added the commandline option "-capturemon #" to minicap, it will be in next upload.

[Ath]

I have added the commandline option "-capturemon #" to minicap, it will be in next upload.

To ease the use of this new feature I wrote a CMD script to capture multiple monitors to multiple files, as close in time as possible:
(only used PowerShell code highlighter for readability)
Change any settings to your likings, can be fired from a AHK hotkey script, optional parameter: nr. of monitors to capture sequentially, defaults to 2

Code: ( powershell)

@echo off
:: MultiMonitorShot.cmd: Grab multiple monitors screenshots to separate files
:: Usage: MultiMonitorShot [monitors]
:: Monitors defaults to 2
:: Settings:
:: Number of monitors to capture, override with 1st argument to script
set SSCOUNT=2
if not "%1" == "" set SSCOUNT=%1
:: Screenshot storage path, including a trailing \ when not empty
set SSPATH=
:: Filename and monitor prefixes
set SSPREFIX=screenshot
set SSMONPREFIX=monitor
:: Extension, not including the period
set SSFILETYPE=png
:: Set date format using variables as in https://www.donationcoder.com/software/mouser/popular-apps/minicap#commandline-options
:: Initially set to YYYY-mm-DD-HH-MM-SS
set SSDATE=$dt:%%Y-%%m-%%d-%%H-%%M-%%S$
:: Aditional MiniCap options can be specified here
set MCOPTIONS=
:: Path to MiniCap.exe, include trailing \ if not empty
set MCPATH=
:: ----------------------------------
:: Leave the rest of the script as is
setlocal EnableDelayedExpansion
set /a LMAX=%SSCOUNT%-1
:: Start multiple MiniCap instances in parallel to get screenshots as close in time as possible
for /l %%N in (0,1,%LMAX%) do (
	set /a O=%%N+1
	start %MCPATH%MiniCap.exe -save "%SSPATH%%SSPREFIX%-%SSDATE%-%SSMONPREFIX%-!O!.%SSFILETYPE%" -capturemon %%N -exit -stderr %MCOPTIONS%
	REM Append the part after the colon to the previous line for logging any errors: >>"%0.%%N.errorlog"
)

Edit1: Modified to number the screenshots according to the Windows monitor numbers (1..n) instead of from 0 to n-1
Edit2: Fixed setting to not have a double period before the extension
Edit3: Added setting for additional MiniCap options

[mouser]

Awesome, thanks Ath! huancoi, maybe that will be useful to you.

[huancoi]

Awesome, thanks Ath! huancoi, maybe that will be useful to you.

Thank you!

[huancoi]

I have added the commandline option "-capturemon #" to minicap, it will be in next upload.

To ease the use of this new feature I wrote a CMD script to capture multiple monitors to multiple files, as close in time as possible:
(only used PowerShell code highlighter for readability)
Change any settings to your likings, can be fired from a AHK hotkey script, optional parameter: nr. of monitors to capture sequentially, defaults to 2

Code: ( powershell)

@echo off
:: MultiMonitorShot.cmd: Grab multiple monitors screenshots to separate files
:: Usage: MultiMonitorShot [monitors]
:: Monitors defaults to 2
:: Settings:
:: Number of monitors to capture, override with 1st argument to script
set SSCOUNT=2
if not "%1" == "" set SSCOUNT=%1
:: Screenshot storage path, including a trailing \ when not empty
set SSPATH=
:: Filename and monitor prefixes
set SSPREFIX=screenshot
set SSMONPREFIX=monitor
:: Extension, not including the period
set SSFILETYPE=png
:: Set date format using variables as in https://www.donationcoder.com/software/mouser/popular-apps/minicap#commandline-options
:: Initially set to YYYY-mm-DD-HH-MM-SS
set SSDATE=$dt:%%Y-%%m-%%d-%%H-%%M-%%S$
:: Aditional MiniCap options can be specified here
set MCOPTIONS=
:: Path to MiniCap.exe, include trailing \ if not empty
set MCPATH=
:: ----------------------------------
:: Leave the rest of the script as is
setlocal EnableDelayedExpansion
set /a LMAX=%SSCOUNT%-1
:: Start multiple MiniCap instances in parallel to get screenshots as close in time as possible
for /l %%N in (0,1,%LMAX%) do (
	set /a O=%%N+1
	start %MCPATH%MiniCap.exe -save "%SSPATH%%SSPREFIX%-%SSDATE%-%SSMONPREFIX%-!O!.%SSFILETYPE%" -capturemon %%N -exit -stderr %MCOPTIONS%
	REM Append the part after the colon to the previous line for logging any errors: >>"%0.%%N.errorlog"
)

Edit1: Modified to number the screenshots according to the Windows monitor numbers (1..n) instead of from 0 to n-1
Edit2: Fixed setting to not have a double period before the extension
Edit3: Added setting for additional MiniCap options

OMG! You are so awesome!