IDEA? simple startup manager with timer

[dbarton]

Basically I want to boot up, and have a window to ask if I want to run my IM cleint and a couple of other things that normally load.

If I don't answer in a few seconds, they will load by default.  If I say No, it will complete without these loaded..




{EDIT:} mods, did I post this in the wrong area?

[mouser]

you posted in the right place.. could be a useful idea too.

might be nice though to be able to provide a list of programs and then configure for each one whether after the timeout it will run by default or not run by default.

so on startup the user would be presented with a list of programs (maybe with a checkbox next to each one that was either checked or unchecked based on configuration), and then an OK button.  If no action is taken then it will timeout after a few seconds and run the checked programs.

[brotherS]

Basically I want to boot up, and have a window to ask if I want to run my IM cleint and a couple of other things that normally load.

If I don't answer in a few seconds, they will load by default.  If I say No, it will complete without these loaded..

Startup Delayer comes very close: http://www.donationcoder.com/forum/index.php?topic=1399.0

[dbarton]

I just had a look at startup delayer, and doesn''t seem like it's meant for this, but I appreciate the tip..

[skrommel]

Try AskToRun!

It shows a timed confirmation dialog before running programs.
Edit the apps= line to add programs, separate them by commas.
You can also change the timer= to change the countdown time.

To change the default action, just change the defaulttext, othertext, defaultaction and otheraction lines.

Edited 2008.03.23

Skrommel

Code

;AskToRun.ahk
; Shows a timed confirmation dialog before running programs.
; Edit the apps= line to add programs, separate them by commas.
; Edit the timer= line to change the countdown time.
; To change the default action, edit the lines
;  defaulttext and othertext and defaultaction and otheraction.
;Skrommel @ 2008

apps=Notepad.exe,Calc.exe ; Programs to run, separated by commas
timer=10                  ; Seconds to wait before default action
defaulttext=No            ; Text displayed on the default button
othertext=Yes             ; Text displayed on the other button
defaultaction=DONT        ; DO or DONT
otheraction=DO            ; DO or DONT
prompt=Run these apps?    ; Text displayed in the dialog
seconds=sec               ; Text displayed after the counter

#NoEnv
#SingleInstance,Force

applicationname=AskToRun

StringReplace,apps,apps,`,,`n,All
Gui,+ToolWindow +AlwaysOnTop
Gui,Add,Text,,`n%prompt%`n`n%apps%`n
Gui,Add,Button,w75 Default Vcounter G%defaultaction%,&%defaulttext% (%timer% %seconds%)
Gui,Add,Button,w75 x+5 G%otheraction%,&%othertext%
Gui,Show,,%applicationname%
SetTimer,COUNTDOWN,1000
Return


COUNTDOWN:
timer-=1
GuiControl,,counter,&%defaulttext% (%timer% %seconds%)
If timer=0
  Goto,DONT
Return


DO:
SetTimer,COUNTDOWN,Off
Loop,Parse,Apps,`n
  Run,%A_LoopField%,,UseErrorLevel
ExitApp


GuiClose:
DONT:
SetTimer,COUNTDOWN,Off
ExitApp

[brotherS]

skrommel for the rescue! 

[yksyks]

I just had a look at startup delayer, and doesn''t seem like it's meant for this, but I appreciate the tip..

It does exactly what you need (and more), just enable the Advanced mode.

[dbarton]

very cool!!!

and is there an easy change for default to be "no"?
not as easy as changing ..


If timer=0
  Goto,YES
Return

to say

If timer=0
  Goto,NO
Return

kinda, but countdown indicator is now wrong, and the code is a bit confusing to this AHK newbie.

[skrommel]

Try the updated script above!

Skrommel

[dbarton]

Now that's cool!

I kinda learned AHK overnight, and banged something together that works, so now I'm torn, but this is very cool. I'll use mine on one machine and yours on the other

I called mine BootBoy.