DonationCoder.com Software > Post New Requests Here

IDEA: Volume buttons (and others) pressed on keyboard are displayed on screen

(1/9) > >>

mrpd:
I know that there are programs that display volume up or down on screen but I am looking for one that would display the volume going up or down in green color with bars. Just free floating on the screen not in a box or background that also maybe could be user adjustable for the width and height , it kinda would look like this .....

Vol +  l l l l l l l l l l l l l l l l l l l l l l l l

It also displays the mute and words of the speacial keys that are pressed on the multimedia keyboard like internet explorer, calc, mail  ect .....

I believe HP computers have something like this. Is there a program or ahk file already out there that does this?


Thanks

EDIT by brotherS: Please start topics in here with "IDEA: ..." the next time, thanks.

gottadoit:
My Logitech keyboard has a program that does exactly this, I think it is called iTouch.exe, it shows when the special keys are pressed and does exactly what you described for the volume keys

I didn't actually know about this for the first year or two after I purchased the keyboard because I didn't bother installing the driver disk or reading the manuals and it was only when I wanted to make more use of the keyboard functionality with other programs that I had a look....

HTH

jgpaiva:
My Logitech keyboard has a program that does exactly this, I think it is called iTouch.exe, it shows when the special keys are pressed and does exactly what you described for the volume keys
-gottadoit (July 19, 2006, 02:00 AM)
--- End quote ---
True, and works very well, but it's only suitable for logitech keyboards. (i have one, and when the keyboard is disconnected, my laptop's keys don't get the on screen display).

skrommel:
 :) Try my GreenOSD - Shows changing volume and selected keys on screen!

I haven't got a multimedia keyboard at hand, so please try the script and let me know what's wrong.
Download and install AutoHotkey from www.autohotkey.com to run it.

Skrommel


--- ---;GreenOSD.ahk
; Shows changing volume and selected keys on screen
;Skrommel @2006


;OSD texts, edit for other languages or special apps
On=On
Off=Off
CapsLock=CapsLock
NumLock=NumLock
ScrollLock=ScrollLock
Insert=Insert
Browser_Back=Back
Browser_Forward=Forward
Browser_Refresh=Refresh
Browser_Stop=Stop
Browser_Search=Search
Browser_Favorites=Favorites
Browser_Home=Home
Volume_Mute=Mute
Volume_Down=Vol-
Volume_Up=Vol+
Media_Next=Next
Media_Prev=Prev
Media_Stop=Stop
Media_Play_Pause=Pause
Launch_Mail=Mail
Launch_Media=Media
Launch_App1=App1
Launch_App2=App2
PrintScreen=PrintScreen

;OSD layout, edit for other color, size and other
size=40
boldness=70
statefont=Arial
actionfont=Arial
color=00FF00
delay=5
transparency=200
xposition=Center     ; xposition=Center or any number
yposition=600        ; yposition=Center or any number


#SingleInstance,Force
#Persistent,On
SetWinDelay,0

applicationname=GreenOSD

showing=0
SoundGet,volume
SoundGet,mute,,Mute

Gui,1:+Center +ToolWindow +AlwaysOnTop -Caption -Border
Gui,1:Margin,0,0
Gui,1:Color,000000
Gui,1:Font,C%color% S%size% W%boldness%,%actionfont%
Gui,1:Add,Text,vvaction1,%PrintScreen%
Gui,1:Font,C%color% S%size% W%boldness%,%statefont%
Gui,1:Add,Text,vvstate1 x+10 yp,||||||||||||||||||||
Gui,1:Show,NoActivate X%xposition% Y%yposition% AutoSize,%applicationname%1  ; NoActivate avoids deactivating the currently active window.
WinSet,TransColor,000000 %transparency%,%applicationname%1
WinGetPos,x1,y1,width1,height1,%applicationname%1
WinMove,%applicationname%1,,0,0,1,1

SetTimer,CHECK,500
Return


CHECK:
SetTimer,CHECK,100
oldmute:=mute
SoundGet,mute,,Mute
oldvolume:=volume
SoundGet,volume
If (volume=oldvolume And mute=oldmute)
{
  showing+=1
  If (showing>=delay*10)
  {
    WinMove,%applicationname%1,,0,0,1,1
    showing=0
    SetTimer,CHECK,500
  }
  Return
}

showing=0
If mute=On
{
  action1=%Volume_Mute%
  state1=%On%
}
Else
If (volume<oldvolume)
  action1=%Volume_Down%
Else
If (volume>oldvolume)
  action1=%Volume_Up%
Else
{
  action1=%Volume_Mute%
  state1=%Off%
}
If (mute=oldmute)
{
  state1=
  Loop,% Ceil(volume/5)
    state1=%state1%|
}
Gosub,SHOW1
Return


SHOW1:
GuiControl,1:,vaction1,%action1%
GuiControl,1:,vstate1,%state1%
WinMove,%applicationname%1,,%x1%,%y1%,%width1%,%height1%
Return


~CapsLock::
~NumLock::
~ScrollLock::
~Insert::
showing=0
StringTrimLeft,action,A_ThisHotkey,1
GetKeyState,state,%action%,T
action1:=%action%
If state=D
  state1:=%On%
Else
  state1:=%Off%
Gosub,SHOW1
Return


~PrintScreen::
~Browser_Back::
~Browser_Forward::
~Browser_Refresh::
~Browser_Stop::
~Browser_Search::
~Browser_Favorites::
~Browser_Home::
~Volume_Mute::
~Media_Next::
~Media_Prev::
~Media_Stop::
~Media_Play_Pause::
~Launch_Mail::
~Launch_Media::
~Launch_App1::
~Launch_App2::
showing=0
StringTrimLeft,action,A_ThisHotkey,1
action1:=%action%
state1=
Gosub,SHOW1
Return

Josh:
How do you change the screen location?

Navigation

[0] Message Index

[#] Next page