DonationCoder.com Software > Post New Requests Here

IDEA: DropFolder

(1/8) > >>

apfel:
Had a nice Idea, while cleaning my Desktop from old files/Downloads etc.

A floating Icon for droping Files/Folders, which opens a menu with configured Move/Copy(while holding Ctrl+drop) Paths.
- with Window Levels: Normal, OnTop, Desktop
- lock/unlock position of icon
- png skin support/Transparency Slider/Icon Size Slider

Would make move/copy actions much more easier.

apfel

skrommel:
 :) Here's an early draft.

DropFolder - Drop files on a floating icon to move or copy files to user defined folders.

Press Ctrl while dropping to copy files

Skrommel


--- ---;DropFolder.ahk
; Drop files on a floating icon to move or copy files to user defined folders
; Press Ctrl while dropping to copy files
;Skrommel

#NoEnv
#SingleInstance,Force
SetWindelay,0

paths=C:\Archive\Work,C:\Archive\Games,C:\Archive\Photos
picture=C:\Windows\Web\Wallpaper\Wind.jpg
transparency=150
x=100
y=100
w=32
h=
location=AlwaysOnTop

Gosub,MENU
OnMessage(0x112,"WM_SYSCOMMAND")
If location=AlwaysOnTop
  guioptions:="+" location
If w<>
  pictureoptions:="H-1 W" w
Else
  pictureoptions:="W-1 H" h
Gui,Margin,0,0
Gui,% "-Caption +ToolWindow +LastFound -Resize " guioptions
guiid:=WinExist()
Gui,Add,Picture,% pictureoptions " GMOVEWINDOW",% picture
Gui,Show,% "X" x " Y" y
WinSet,Transparent,% transparency
Return


GuiDropFiles:
GetKeyState,ctrl,Control,P
where:=A_GuiControl
filecount:=A_EventInfo
guix:=A_GuiX
guiy:=A_GuiY
files:=A_GuiEvent
Menu,menu,Show
Return


MENU:
Loop,Parse,paths,`,
  Menu,menu,Add,% A_LoopField,COPY
Menu,menu,Add
Menu,menu,Add,&Browse...,BROWSE
Menu,menu,Add,&Cancel,CANCEL
Return


COPY:
FileCreateDir,%A_ThisMenuItem%
If ctrl=D
  Loop,Parse,files,`n
    FileCopy,%A_LoopField%,%A_ThisMenuItem%
Else
  Loop,Parse,files,`n
    FileMove,%A_LoopField%,%A_ThisMenuItem%
Return


BROWSE:
FileSelectFolder,target,,3
If target=
  Return
FileCreateDir,%target%
If ctrl=D
  Loop,Parse,files,`n
    FileCopy,%A_LoopField%,%target%
Else
  Loop,Parse,files,`n
    FileMove,%A_LoopField%,%target%
Return


CANCEL:
Return


;Stolen from SKAN at http://www.autohotkey.com/forum/topic32768.html
MOVEWINDOW:
  PostMessage,0xA1,2,,,A   ;WM_NCLBUTTONDOWN=0x00A1 HTCAPTION=2
Return


;Stolen from Lexicos at http://www.autohotkey.com/forum/topic18260.html
WM_SYSCOMMAND(wParam)
{
  Global guiid
  If (A_Gui && wParam = 0xF020) ; SC_MINIMIZE
    WinRestore,ahk_id %guiid%
}


GuiClose:
  ExitApp

nudone:
what a brilliant idea.  :up:

VideoInPicture:
http://customdesktoplogo.wikidot.com/

This seems like it could be an extension of Custom Desktop Logo so I added in drop folder capability into Custom Desktop Logo V2.0. Screenshots below:

IDEA: DropFolder1
IDEA: DropFolder2
IDEA: DropFolder3
IDEA: DropFolder4
IDEA: DropFolder5
IDEA: DropFolder6

With the drop folder option enabled in the tray icon or the settings panel, you can move the logos around as well as still have them animated or static. Custom Desktop Logo uses PNG images so it does alpha blending on the graphics to make them look smooth when displayed on the desktop. Multi-monitor support should also work.

Hold down CTRL while drag and dropping to copy instead of moving. Change the paths of the target folders in the "Drop Folder" tab of the settings panel. You can specify an alternate name for the folders or leave the name field blank to tell Custom Desktop Logo to display the folder path. Click on the logo itself to get a list of your target folders that you can simply open. All the file copying and moving operations are done in a multi-threaded fashion so you can perform multiple copy/move operations at the same time.

There are a couple of limitations with the drop folder capability right now. (1) I hard coded the program to limit it to 20 drop folders in the list. (2) I would like to have a copy/move status indicator for large operations.

Download Custom Desktop Logo 2.0 at http://customdesktoplogo.wikidot.com/. Source code is included on the source code download page (written in C#). Requires .Net 2.0 Framework or later to run it.

CleverCat:
I get an unhandled exception error when loading?

Navigation

[0] Message Index

[#] Next page