DonationCoder.com Software > Post New Requests Here

IDEA: Click counter

<< < (2/2)

Notok:
I think that just one would be fine :) I would actually be looking to use this on programs that don't do multiple instances.

One thing that might be nice would be to have the ability to have it continue on into a new session (of the target app, not the counter), as long as it's not difficult. I would think this to be little more than just requiring the user to reset stats rather than clearing them automatically the next time the counter is started. I could also potentially see this as being a roundabout way to count clicks in another instance, but I digress :)

Thanks!

skrommel:
 :) Try CliCount!

Rightclick the tray menu to change the title to watch and reset the counters.

Skrommel


--- ---;CliCount.ahk
; Count clicks in a user defined window
;Skrommel @ 2008

#NoEnv
#SingleInstance,Force
#Persistent,On
SetTitleMatchMode,2

applicationname=CliCount

OnExit,EXIT
Gosub,TRAYMENU
buttons=lrm
IniRead,title,%applicationname%.ini,Settings,title
If title=Error
  title=
Loop,Parse,buttons
{
  IniRead,%A_LoopField%button,%applicationname%.ini,Settings,%A_LoopField%button
  If %A_LoopField%button=ERROR
    %A_LoopField%button=0
}
Return


~*LButton::
~*RButton::
~*MButton::
StringTrimLeft,hotkey,A_ThisHotkey,2
MouseGetPos,,,mwin
WinGetTitle,mtitle,ahk_id %mwin%
IfInString,mtitle,%title%
  %hotkey%+=1
Return


TRAYMENU:
Menu,Tray,NoStandard
Menu,Tray,DeleteAll
Menu,Tray,Add,%applicationname%,SHOW
Menu,Tray,Add,
Menu,Tray,Default,%applicationname%
Menu,Tray,Add,E&xit,EXIT
Menu,Tray,Tip,%applicationname%
Return


SHOW:
InputBox,newtitle,%applicationname%,Left:`t%lbutton%`nRight:`t%rbutton%`nMiddle:`t%mbutton%`n`nPart of Window Caption:,,,,,,,,%title%
If ErrorLevel=1
  Return
title=%newtitle%
MsgBox,4,%applicationname%,Reset counters?
IfMsgBox,No
  Return
lbutton=0
rbutton=0
mbutton=0
Return


EXIT:
IniWrite,%title%,%applicationname%.ini,Settings,title
IniWrite,%lbutton%,%applicationname%.ini,Settings,lbutton
IniWrite,%rbutton%,%applicationname%.ini,Settings,rbutton
IniWrite,%mbutton%,%applicationname%.ini,Settings,mbutton
ExitApp

Notok:
Any chance someone could compile this for me?

And thank you very much for that :)

wreckedcarzz:
I will; I'll edit this post in a minute with it up.

EDIT: Here ya go :D

Notok:
yay, thank you much!

Navigation

[0] Message Index

[*] Previous page