Messages - Nod5 [ switch to compact view ]

Pages: prev • 1 ... 7 8 9 10 11 [12] 13 14 15 16 17 ... 234 • next
56
Find And Run Robot / Re: displaying expanded user variables in aliases
« on: March 16, 2021, 09:25 AM »
Save to FARR_resolve_alias_variables.ahk (with UTF-8 BOM encoding). Requires AutoHotkey

Will work in most cases, but might fail on complex alias text with e.g. escaped % characters.

Code: Autohotkey [Select]
  2. SetWorkingDir %A_ScriptDir%
  6.  
  7. ; FARR_resolve_alias_variables.ahk
  8.  
  9. ; by Nod5 on 2021-03-16
  10.  
  11. ; A helper tool for FARR (Find And Run Robot) written in AutoHotkey
  12.  
  13. ; Reads alias result from active FARR "Edit Group Alias" window
  14. ; and resolves (converts) FARR's UserVar variables to text values
  15.  
  16. ; For example the variable "%uservar.Browser.Chrome%" is replaced
  17. ; with e.g. "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe"
  18.  
  19. ; How to use:
  20. ; Run script and press F8 when FARR Options "Edit Group Alias" window is active
  21. ; A MsgBox shows the results lines with resolved UserVars
  22.  
  23. ; Optional: uncomment lines near end of script to also
  24. ; - Copy text to clipboard
  25. ; - Write text to .txt file
  26.  
  27. ; Discussion
  28. ;   https://www.donationcoder.com/forum/index.php?topic=51199.0
  29.  
  30.  
  31. ; default path to FARR .ini file (edit this filepath if the .ini is in another location)
  32. vFarrIni := "C:\Users\" A_UserName "\Documents\DonationCoder\FindAndRunRobot\FindAndRunRobot.ini"
  33. return
  34.  
  35. #IfWinActive, Edit Group Alias ahk_exe FindAndRunRobot.exe ahk_class TAliasForm
  36. F8::
  37.   if !FileExist(vFarrIni)
  38.   {
  39.     MsgBox % "Error: FindAndRunRobot.ini not found.`n`nEdit script and add correct path to it."
  40.     ExitApp
  41.   }
  42.   ; get text from results editbox
  43.   ControlGetText, vText, TMemo2, A
  44.  
  45.   ; read UserVar data from FARR .ini
  46.   IniRead, vUserVars, % vFarrIni, ExtraSettings, UserVars, %A_Space%
  47.  
  48.   ; split lines to array
  49.   aUserVars := StrSplit(vUserVars, ">n>")
  50.  
  51.   ; object to store full variable/value pairs
  52.   aMap := Object()
  53.  
  54.   For Key, vLine in aUserVars
  55.   {
  56.     vLine := TRim(vLine)
  57.    
  58.     ; skip blank or comment line
  59.     if !vLine or (SubStr(vLine, 1, 2) = "//")
  60.       continue
  61.  
  62.     ; [Section]
  63.     if RegExMatch(vLine, "^\[(.+)\]$", vMatch)
  64.       vSection := vMatch1
  65.  
  66.     ; if variable line then get variable/value pair and add to map array
  67.     ; prefix variable name "uservar." and last found section name (if any)
  68.     if RegExMatch(vLine, "U)^(.+)=(.+)$", vMatch)
  69.     {
  70.       vVarName := "uservar." ( vSection ? vSection "." : "") vMatch1
  71.       vValue    := vMatch2
  72.       aMap["" vVarName] := vValue
  73.     }
  74.   }
  75.  
  76.   ; resolve
  77.   For vVarName, vValue in aMap
  78.     vText := StrReplace(vText, "%" vVarName "%", vValue) ; replace all
  79.  
  80.   ; show resolved text
  81.   MsgBox % vText
  82.  
  83.   ; put on clipboard
  84.   ;Clipboard := vText
  85.  
  86.   ; write to .txt file in this script's folder
  87.   ;FileAppend, % vText, % A_ScriptDir "\alias_resolved_" A_Now ".txt", UTF-8-RAW
  88. return
  90.  
  91.  
  92. ; ----------------------------
  93. ; notes of FARR User Variables (UserVar)
  94. ; ----------------------------
  95. ;   Used as variables in aliases
  96. ;   Set in FARR > Options > Lists > User Variables
  97. ;   Stored in FindAndRunRobot.ini
  98. ;     Default path C:\Users\<username>\Documents\DonationCoder\FindAndRunRobot\FindAndRunRobot.ini
  99.  
  100. ; Format in Options "User Variables" pane:
  101. ; -----
  102. ; TopTest=C:\folder\test.exe
  103. ; [SectionName]
  104. ; VarName=Value
  105. ; VarName2=Value2
  106. ; // comment line
  107. ;
  108. ; [Browser]
  109. ; Chrome=C:\Program Files (x86)\Google\Chrome\Application\chrome.exe
  110. ; Firefox=C:\b\firefox.exe
  111. ; -----
  112. ; Note: it is allowed to create variables above the first [Section]
  113. ; Note: comments must be on separate lines. Not allowed: VarName=Value //comment
  114.  
  115. ; -----
  116. ; Format in FARR aliases:
  117. ; -----
  118. ;   %uservar.TopTest%
  119. ;   %uservar.SectionName.VarName%
  120. ;   %uservar.Browser.Chrome%
  121. ; -----
  122.  
  123. ; -----
  124. ; Format in FindAndRunRobot.ini
  125. ; -----
  126. ; Stored as a single line, ">n>" is linebreak separator
  127. ; Example:
  128. ; UserVars=TopTest=C:\folder\test.exe>n>[SectionName]>n>VarName=Value>n>VarName2=Value2>n>// comment line>n>>n>[Browser]>n>Chrome=C:\Program Files (x86)\Google\Chrome\Application\chrome.exe>n>Firefox=C:\b\firefox.exe
  129. ; ----------------------------

57
Find And Run Robot / Re: displaying expanded user variables in aliases
« on: March 15, 2021, 11:14 AM »
I don't think FARR has that feature built in, but it would be a useful feature. I have AutoHotkey code that resolves the FARR user variables. I'l clean that up and post here as a helper tool for FARR when I have more time.

58
Coding Snacks / Re: Lightweight App that displays files in folders/subfolders & allows launching
« on: March 15, 2021, 11:10 AM »
Here you go.
-GirkovArpa (March 14, 2021, 08:28 PM)
Neat! I will experiment with that.

59
Coding Snacks / Re: Lightweight App that displays files in folders/subfolders & allows launching
« on: March 14, 2021, 01:49 PM »
Here you go.
-GirkovArpa (March 12, 2021, 11:00 AM)
That looks nice, seems functional for this request.

Off topic: I have come across Sciter a few times before but haven't made anything with it. I see you have a small test repo that transpiles some ahk to sciter here https://github.com/GirkovArpa/ahk-to-sciter . Let me ask: do you know of some Sciter project with AutoHotkey interop, like what is available for Python https://github.com/sciter-sdk/pysciter ?

60
Post New Requests Here / Re: IDEA: Pull icon from exe and put on the containing folder
« on: February 11, 2021, 04:39 AM »
Neat idea, so I made an AutoHotkey version with a hotkey and also a command line mode for easy use from FARR.

Uses COM to get the focused file's path more reliably than sending keys to the context menu.
Uses SHGetSetFolderCustomSettings method which makes the new folder icon show immediately, see Microsoft doc.

Code: Autohotkey [Select]
  2. SetWorkingDir %A_ScriptDir%
  7.  
  8. ; SetExplorerFolderIcon.ahk
  9. ; 2021-02-11
  10. ; by Nod5
  11. ; In Explorer press [F8] to set the focused file's first icon as parent folder icon
  12. ; -----------------------------------
  13. ; Default mode:
  14. ;   Select a file in Explorer and press [F8].
  15. ;   To close the script right click its tray menu icon and Exit.
  16.  
  17. ; Command line mode:
  18. ;   Pass as parameter a HWND window handle to a specific Explorer window
  19. ;   to act on that window's focused file and parent folder.
  20. ;
  21. ; Optional: use this script from FARR (Find And Run Robot)
  22. ;   Create a FARR alias and use this as the result line (modify the path):
  23. ;   Set Explorer parent folder icon | C:\some\folder\SetExplorerFolderIcon.ahk %LASTHWND%
  24. ; -----------------------------------
  25.  
  26. ; if parameter is Explorer HWND then act on that window and exit
  27. if (vHwnd := A_Args[1])
  28. {
  29.   if WinExist("ahk_class CabinetWClass ahk_id " vHwnd)
  30.     GetFocusedFileSetIcon(vHwnd)
  32. }
  33. ; else hotkey mode: create Explorer hotkey and await user action
  34. else
  35. {
  36.   Hotkey, IfWinActive, ahk_class CabinetWClass
  37.   Hotkey, F8, GetFocusedFileSetIcon
  38. }
  39. return
  40.  
  41. GetFocusedFileSetIcon(vHwnd := "")
  42. {
  43.   vFile := ExplorerGetFocusedFilepath(vHwnd)
  44.   if FileExist(vFile)
  45.   {
  46.     SplitPath, vFile, , vFolder
  47.     SetFolderIcon(vFolder, vFile, 0)
  48.   }
  49. }
  50.  
  51.  
  52. ; function: ExplorerGetFocusedFilepath(vHwnd := "")  v210211
  53. ; return filepath of focused item in vHwnd (or active) Explorer window
  54. ExplorerGetFocusedFilepath(vHwnd := "")
  55. {
  56.   vHwnd := vHwnd ? vHwnd : WinActive("A")
  57.   if vHwnd and WinExist("ahk_class CabinetWClass ahk_id " vHwnd)
  58.     for Window in ComObjCreate("Shell.Application").Windows
  59.       if (Window.HWND = vHwnd)
  60.         ; https://docs.microsoft.com/en-us/windows/win32/shell/shellfolderview-focuseditem
  61.         return vFile := Window.Document.FocusedItem.Path
  62. }
  63.  
  64.  
  65. ; function: SetFolderIcon() update Explorer folder icon in desktop.ini via SHGetSetFolderCustomSettings
  66. ; by teadrinker 2017-10-09 https://www.autohotkey.com/boards/viewtopic.php?p=174984#p174984
  67. ; https://docs.microsoft.com/en-us/windows/win32/api/shlobj_core/nf-shlobj_core-shgetsetfoldercustomsettings
  68. ; https://docs.microsoft.com/en-us/windows/win32/api/shlobj_core/ns-shlobj_core-shfoldercustomsettings
  69. SetFolderIcon(folderPath, iconPath, iconIndex)  {
  70.    static FCSM_ICONFILE := 0x10, FCS_FORCEWRITE := 0x2
  71.    if !A_IsUnicode  {
  72.       VarSetCapacity(WiconPath, StrPut(iconPath, "UTF-16")*2, 0)
  73.       StrPut(iconPath, &WiconPath, "UTF-16")
  74.    }
  75.    VarSetCapacity(SHFOLDERCUSTOMSETTINGS, size := 4*5 + A_PtrSize*10, 0)
  76.    NumPut(size, SHFOLDERCUSTOMSETTINGS)
  77.    NumPut(FCSM_ICONFILE, SHFOLDERCUSTOMSETTINGS, 4)
  78.    NumPut(A_IsUnicode ? &iconPath : &WiconPath, SHFOLDERCUSTOMSETTINGS, 4*2 + A_PtrSize*8)
  79.    NumPut(iconIndex, SHFOLDERCUSTOMSETTINGS, 4*2 + A_PtrSize*9 + 4)
  80.    DllCall("Shell32\SHGetSetFolderCustomSettings", Ptr, &SHFOLDERCUSTOMSETTINGS, WStr, folderPath, UInt, FCS_FORCEWRITE)
  81. }
  82.  
  83. ; -----------------------------------
  84. ; notes on desktop.ini files
  85. ; -----------------------------------
  86. ; https://docs.microsoft.com/en-us/windows/win32/shell/how-to-customize-folders-with-desktop-ini
  87. ; "text file that allows you to specify how a file system folder is viewed."
  88. ; See also https://hwiegman.home.xs4all.nl/desktopini.html
  89.  
  90. ; Format:
  91. ; -----
  92. ; [.ShellClassInfo]
  93. ; IconResource=C:\test\file.exe,0     ; <filepath, icon-index>
  94. ; -----
  95. ; To remove the custom folder icon delete desktop.ini
  96.  
  97. ; If we just write the file then the new folder icon does not show immediately (must close/reopen Explorer)
  98. ; If we instead use SHGetSetFolderCustomSettings the new icon shows immediately.
  99. ; SHGetSetFolderCustomSettings also hides the desktop.ini file.
  100. ; https://docs.microsoft.com/en-us/windows/win32/api/shlobj_core/nf-shlobj_core-shgetsetfoldercustomsettings
  101. ; https://docs.microsoft.com/en-us/windows/win32/api/shlobj_core/ns-shlobj_core-shfoldercustomsettings
  102. ; AutoHotkey function: SetFolderIcon()
  103. ; by Teadrinker 2017-10-09 https://www.autohotkey.com/boards/viewtopic.php?p=174984#p174984
  104. ; -----------------------------------

Pages: prev • 1 ... 7 8 9 10 11 [12] 13 14 15 16 17 ... 234 • next
Go to full version