Messages - Nod5 [ switch to compact view ]

Pages: prev • 1 ... 25 26 27 28 29 [30] 31 32 33 34 35 ... 234 • next
146
Find And Run Robot / New competitor: Microsoft PowerToys Run (but FARR is better)
« on: May 23, 2020, 09:13 AM »
Microsoft keeps adding nice stuff to the revived PowerToys apps
https://github.com/microsoft/PowerToys

Most recently PowerToys Run, a launcher app that has some similarity with FindAndRunRobot
https://github.com/microsoft/PowerToys/tree/master/src/modules/launcher

Here are my subjective impressions after some quick tests.

1. PowerToys Run has a nice, clean interface with big fonts and no clutter. It takes inspiration from the launcher Wox.

1.png

FARR can be similarly minimally styled using the slenderFARR skin, display option "Large Icon Slides", dragging to hide the toolbar buttons, and using a script to hide the statusbar text.

2.png

2. Run has built in support for CMD/terminal commands through the > prefix.

3.png

FARR can do that too by creating an alias like this:

alias name: run terminal command
RegEx: ^>(.*)
Results:
cmd | C:\Windows\System32\cmd.exe /c $$1

4.png

5.png

3. PowerToys Run can search and switch to open windows. That's a nice to have feature!

4. PowerToys does not have aliases. FARR has very powerful aliases. That is a huge difference. Aliases make FARR searches and actions very easy to customize - it becomes a much more powerful and versatile tool. Even more so when combined with some small AutoHotkey scripts.

All in all I still prefer FARR. Not a big surprise I suppose!  ;D But its age is showing a bit.
- I wish the FARR default UI had a more flat and minimal design.
- To create/test/edit/share/backup FARR aliases is a bit clunky, which might prevent new users from making and using the more powerful aliases features.
- The FARR options give intricate control of search result scoring, which was perhaps more relevant for the era of slow hardrives than for new faster SSD storage.

147
Find And Run Robot / Re: FARR alias for choosing program based on file extension
« on: May 23, 2020, 05:11 AM »
Nice! Here is a helper hotkey script to more quickly go from a regular FARR search to activating the "choose program" alias for the first search match by using an exclamation character as keyboard shortcut.

Code: Autohotkey [Select]
  3. SetWorkingDir %A_ScriptDir%
  9.  
  10. ; choose program FARR alias helper hotkey script.ahk
  11. ; 2020-05-23
  12. ; by Nod5
  13.  
  14. #IfWinActive, ahk_exe FindAndRunRobot.exe
  15. ; press ! to expand first FARR match file path and append --
  16. !::
  17.   ControlGetFocus, vFocusControl, A
  18.   ; if FARR search box focus and options not open
  19.   if (vFocusControl = "TEdit1")
  20.     if !WinExist("ahk_class TOptionsForm")
  21.     {
  22.       ; show first result file full path in FARR search box
  23.       Send {down}{right}
  24.       ; append -- to trigger "choose program" alias
  25.       Send --
  26.     }
  27. Return

Screenshot of the alias
alias.png

Gif of how it all works
https://imgur.com/a/YzJlRhx

(Edit: cannot embed .mp4 video in forum posts it seems so I added link to Imgur instead)

Edit2: mouser could uppdate FARR with special variables that represent the full path of a file result, maybe %resultfile1% or similar. Then we could skip the AutoHotkey script and instead make an alias that triggers on "!" anywhere in the searchbox and reacts by doing "restartsearch %resultfile1% --".

148
Post New Requests Here / Re: Sort/organize mp3 files by bitrate, into folders
« on: May 14, 2020, 07:53 AM »
This worked for me in a quick test. But do try it out on some smaller folders first to see that it works as expected on your files, since mp3 tags and exif data can be complicated and I don't know if the function I use handles all corner cases correctly.

Code: Autohotkey [Select]
  3. SetWorkingDir %A_ScriptDir%
  7.  
  8. ; sort mp3 files into folders based on bitrate and if they are VBR or not
  9. ; AutoHotkey script
  10. ; by nod5
  11. ; 2020-05-14
  12.  
  13. ; ---------------------------------------
  14. ; folder with mp3 files that we want to sort move
  15.  
  16. sourcefolder      := "C:\some\folder"
  17.  
  18. ; also recurse in sourcefolder? 1 means yes, 0 means no
  19. recurse := 1
  20.  
  21. ; target folder where we want the files to end up in subfolders
  22. ; for example VBR files go to \VBR subfolder, 128kbs CBR files got to \128 subfolder
  23.  
  24. destinationfolder := "D:\this other\location"
  25.  
  26. ; ---------------------------------------
  27.  
  28. ; disable recurse if in/out folders are same, to avoid endless loop
  29. if (sourcefolder = destinationfolder)
  30.   recurse := 0
  31.  
  32. ; recursively loop sourcefolder for mp3 files and move to a destinationfolder subfolder
  33. Loop, Files, % sourcefolder "\*.mp3", % recurse ? "R" : ""
  34. {
  36.   ; get audio properties as object
  37.   ; we need these two properties:
  38.   ; System.Audio.EncodingBitrate      examples: 128000 (which is 128kbs), 320000, 263704, ...
  39.   ; System.Audio.IsVariableBitRate    value -1 if VBR otherwise value 0
  40.   Props := ["System.Audio.IsVariableBitRate", "System.Audio.EncodingBitrate"]
  41.   obj := Filexpro(A_LoopFilePath,, Props*)           ; v.90 By SKAN on D1CC @ goo.gl/jyXFo9
  42.  
  43.   ; if VBR then move to subfolder "\VBR"
  44.   if (obj["System.Audio.IsVariableBitRate"] = "-1")
  45.     subfolder := "VBR"
  46.   else
  47.   {
  48.     ; else move CBR to matching bitrate folder, for example "\128"
  49.     ; get bitrate in kbs, for example 128000 -> 128
  50.     subfolder := SubStr(obj["System.Audio.EncodingBitrate"],1,-3)
  51.   }
  52.   if subfolder
  53.   {
  54.     if !FileExist(destinationfolder "\" subfolder)
  55.       FileCreateDir, % destinationfolder "\" subfolder
  56.     FileMove, % A_LoopFilePath, % destinationfolder "\" subfolder
  57.   }
  58. }
  59. ToolTip DONE
  60. sleep 2000
  62.  
  63.  
  64.  
  65. ; function: Filexpro
  66. ; get extended properties from file
  67. ; by SKAN 2018-12-11
  68. ; https://www.autohotkey.com/boards/viewtopic.php?t=59882
  69.  
  70. Filexpro( sFile := "", Kind := "", P* ) {           ; v.90 By SKAN on D1CC @ goo.gl/jyXFo9
  71. Local
  72. Static xDetails
  73.  
  74.   If ( sFile = "" )
  75.     {                                                           ;   Deinit static variable
  76.         xDetails := ""
  77.         Return
  78.     }
  79.  
  80.   fex := {}, _FileExt := ""
  81.  
  82.   Loop, Files, % RTrim(sfile,"\*/."), DF
  83.     {
  84.         If not FileExist( sFile:=A_LoopFileLongPath )
  85.           {
  86.               Return
  87.           }
  88.  
  89.         SplitPath, sFile, _FileExt, _Dir, _Ext, _File, _Drv
  90.  
  91.         If ( p[p.length()] = "xInfo" )                          ;  Last parameter is xInfo
  92.           {
  93.               p.Pop()                                           ;         Delete parameter
  94.               fex.SetCapacity(11)                               ; Make room for Extra info
  95.               fex["_Attrib"]    := A_LoopFileAttrib
  96.               fex["_Dir"]       := _Dir
  97.               fex["_Drv"]       := _Drv
  98.               fex["_Ext"]       := _Ext
  99.               fex["_File"]      := _File
  100.               fex["_File.Ext"]  := _FileExt
  101.               fex["_FilePath"]  := sFile
  102.               fex["_FileSize"]  := A_LoopFileSize
  103.               fex["_FileTimeA"] := A_LoopFileTimeAccessed
  104.               fex["_FileTimeC"] := A_LoopFileTimeCreated
  105.               fex["_FileTimeM"] := A_LoopFileTimeModified
  106.           }              
  107.         Break            
  108.     }
  109.  
  110.   If Not ( _FileExt )                                   ;    Filepath not resolved
  111.     {
  112.         Return
  113.     }        
  114.  
  115.  
  116.   objShl := ComObjCreate("Shell.Application")
  117.   objDir := objShl.NameSpace(_Dir)
  118.   objItm := objDir.ParseName(_FileExt)
  119.                                                                
  120.   If ( VarSetCapacity(xDetails) = 0 )                           ;     Init static variable
  121.     {
  122.         i:=-1,  xDetails:={},  xDetails.SetCapacity(309)
  123.        
  124.         While ( i++ < 309 )
  125.           {
  126.             xDetails[ objDir.GetDetailsOf(0,i) ] := i
  127.           }
  128.  
  129.         xDetails.Delete("")
  130.     }
  131.  
  132.   If ( Kind and Kind <> objDir.GetDetailsOf(objItm,11) )        ;  File isn't desired kind  
  133.     {
  134.         Return
  135.     }
  136.  
  137.   i:=0,  nParams:=p.Count(),  fex.SetCapacity(nParams + 11)
  138.  
  139.   While ( i++ < nParams )
  140.     {
  141.         Prop := p[i]
  142.        
  143.         If ( (Dot:=InStr(Prop,".")) and (Prop:=(Dot=1 ? "System":"") . Prop) )
  144.           {
  145.               fex[Prop] := objItm.ExtendedProperty(Prop)
  146.               Continue
  147.           }
  148.          
  149.         If ( PropNum := xDetails[Prop] ) > -1
  150.           {
  151.               fex[Prop] := ObjDir.GetDetailsOf(objItm,PropNum)
  152.               Continue
  153.           }  
  154.     }
  155.  
  156.   fex.SetCapacity(-1)
  157. Return fex  
  158.  
  159. }

Alternatively if you want a GUI approach you could drag all the mp3 files into Mp3Tag, sort by columns bitrate and VBR, select a range of files e.g. all with 128 kbs and use right click context menu action "move...".

149
Find And Run Robot / Re: Launch, stay open and continue searching
« on: April 27, 2020, 12:54 PM »
Another small wrinkle related to the current launch and stay open option: FARR moves focus to the searchbox, instead of keeping focus at the line of the result that was launched.

Here is an AutoHotkey script that somewhat works around both issues. Somewhat since it only works when launching a result that points to file/folder path (not a complex alias result that launches multiple files, passes parameters or other extras). I imagine the script might also fail to keep focus in some situations, depending on how long it takes for the launched file to open in the default app for that extension.

Code: Autohotkey [Select]
  3. SetWorkingDir %A_ScriptDir%
  8.  
  9. ; FARR helper script to launch a file and continue search and keep focus in results list
  10.  
  11. ; 2020-04-27 by Nod5
  12.  
  13. ; Hotkey: Alt+Enter
  14. ; - launches the selected FARR result (a file or folder)
  15. ; - FARR continues searching
  16. ; - FARR stays open and keeps its focus in the results window
  17.  
  18. ; note: does nothing if the selected result is not an existing file/folder.
  19. ; In other words does nothing if the result is an complex alias result.
  20.  
  21. #IfWinActive, ahk_exe FindAndRunRobot.exe
  22. !Enter::
  23.   ; only react if user has focused FARR results list
  24.   ControlGetFocus, vFocusControl, A
  25.   if (vFocusControl != "TNextGrid1")
  26.     Return
  27.   ; get FARR window handle
  28.   vHwnd := WinExist("A")
  29.   ; use ctrl+C to get the path to selected file in FARR results
  30.   ; note: only works if result is a path to a single file (not a complex alias result)
  31.   clip := ClipToVar()
  32.   If !FileExist(clip)
  33.     Return
  34.   ; run the file
  35.   Run % clip
  36.   ; keep the FARR window active
  37.   While WinActive("ahk_id " vHwnd) and (A_Index < 100)
  38.     sleep 10
  39.   WinActivate, % "ahk_id " vHwnd
  40. Return
  42.  
  43. ;function: copy selection to clipboard to variable
  44. ClipToVar() {
  45.   cliptemp := clipboardall ;backup
  46.   clipboard =
  47.   send ^c
  48.   clipwait, 1
  49.   clip := clipboard
  50.   clipboard := cliptemp    ;restore
  51.   return clip
  52. }

150
Official Announcements / Re: Upgrading forum Dec 28, 2019
« on: April 25, 2020, 04:48 PM »
Some forums that run on phpBB have inline code and use a [c]tag like this[/c]. For example https://www.autohotkey.com/boards/
I found this customization page https://www.phpbb.com/customise/db/bbcode/inline_bbcode/ but I'm not sure if that is what AutoHotkey and others use today. I know that DC uses SMF though, so maybe that phpBB stuff is not relevant anyway?

I like to use inline code formatting in instructions e.g. when describing some command to type in the terminal or an exact filepath. Less ambiguous than just using quote marks or bold and more compact than adding a code block, especially if there are many small such snippets in a text.

Pages: prev • 1 ... 25 26 27 28 29 [30] 31 32 33 34 35 ... 234 • next
Go to full version