;
 ; AutoHotkey Version: 1.x
 ; Language:       English
 ; Platform:       WinXX
 ; Author:         Dirhael (dirhael at gmail dot com)
 ;
 ; Script Function:
 ; Enables the display of the currently active work path in Total Commanders window captioning
 ;
 
 #NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
 #SingleInstance ignore ; Only allow one running copy of this script
 #NoTrayIcon ; We don't need the tray icon for this script
 SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
 #MaxMem 1 ; While it's probably not needed, try to use as little memory as possible
 
 SetEnv,tcpp_exe,TCPowerPack.exe ; The name of the Total Commander Powerpack executable
 SetEnv,tc_exe,totalcmd.exe ; The name of the regular Total Commander executable
 SetWorkingDir %A_ScriptDir% ; Make sure that we're working in the same folder as the script's located in.
 
 IfWinNotExist ahk_class TTOTAL_CMD
 {
 
  Run, %A_WorkingDir%\%tcpp_exe%, , UseErrorLevel ; Check for TC Powerpack and run if found
 
  if ErrorLevel = ERROR ; Attempt to run the regular version of Total Commander if we can't find TC Powerpack
  {
  Run, %A_WorkingDir%\%tc_exe%, , UseErrorLevel ; Check for regular Total Commander and run if found
  }
 
  if ErrorLevel = ERROR ; Error message and exit if we can't start the application
  {
  Msgbox, 16, , ERROR: Unable to launch Total Commander.`n`n%A_WorkingDir%\%tcpp_exe% -> File Not Found!`n%A_WorkingDir%\%tc_exe% -> File Not Found!`n`nPlease make sure that you are running this application from the same directory as one (or both) of the above executables are located.
  ExitApp
  }
 
 }
 
 
 Loop
 {
  WinWaitActive ahk_class TTOTAL_CMD ; No point in continuing until the Total Commander window is active
  {
  ControlGetText, text, TMyPanel2 ; Get the current path from the "command prompt" toolbar (will work even if it's not displayed)
  StringTrimRight, text, text, 1 ; Get rid of the rightmost ">" character
  WinSetTitle %text% ; Set the title captioning
  }
 
  IfWinNotExist ahk_class TTOTAL_CMD ; If Total Commander isn't running, we'll just exit here
  ExitApp
 }