#SingleInstance
CoordMode, ToolTip, Screen                                                      ;all coordinates are Screen related
version=Fibonacci Screen Guide v0125                                            ;version of script
Menu, tray, add, ABOUT, ABOUT                                                   ;tray Menu
Menu, tray, add,
Menu, tray, add, Exit, Exit
Menu, tray, tip,  %Version%
Menu, tray, NoStandard
Gui,1: +AlwaysOnTop -Caption +ToolWindow +0x400000                              ;create a small Gui with text High, no titlebar, +0x400000 looks like Button
Gui,1: Margin, 1, 1
Gui,1: Add, Text, w25 h15 GHigh VHigh, High                                     ;the G Gosub will jump to the High Label when pressed
Gui,1: Show, y200 x300 w25 h15,High
Gui,2: +AlwaysOnTop -Caption +ToolWindow +0x400000
Gui,2: Margin, 1, 1
Gui,2: Add, Text, w25 h15 GLow VLow, Low
Gui,2: Show, y300 x500 w25 h15 ,Low
Gui,3: +AlwaysOnTop  +ToolWindow +0x400000                                      ;
Gui,3: Margin, 1, 1
Gui,3: Add, Button,w50 gshowall x1,&Show
Gui,3: Add, Button,w50 ghideall x+1,&Hide All
Gui,3: Add, Button,w50 gABOUT x+1,&About
Gui,3: Add, Checkbox,x1 y30 vInside gDrawlines xm Checked,&Inside Lines
Gui,3: Add,DDL,x90 y25 w60 vinsideColor gDrawlines ,black||silver|grey|white|maroon|red|purple|fuchsia|green|lime|olive|yellow|navy|blue|teal|aqua
Gui,3: Add, Checkbox,x1 y55 vOutside gDrawlines xm Checked,&Outside Lines
Gui,3: Add,DDL,x90 y50 w60 voutsideColor gDrawlines ,black||silver|grey|white|maroon|red|purple|fuchsia|green|lime|olive|yellow|navy|blue|teal|aqua
gui,3: Add,statusbar,,Drag the High and Low buttons
Gui,3: Show, x100 y100 ,Fibonacci Prefs
Gosub, Drawlines
Return
High:
  PostMessage, 0xA1, 2,,, A                                                     ;Send the Left Mouse Button down to the window, allowing drag.
  KeyWait, LButton, U                                                           ;Wait for the Mouse to be released when dragged
  Gosub,Drawlines                                                               ;Redraw Lines when Mouse released
Return
Low:
  PostMessage, 0xA1, 2,,, A
  KeyWait, LButton, U                                                           ;Wait for the Mouse to be released when dragged
  Gosub,Drawlines
Return
showall:
  Gui, 1:show
  Gui, 2:show
Drawlines:                                                                      ;draw the screen lines
  Gui,3: Submit,NoHide                                                          ;get the values from the pref gui
  WinGetPos, HighX, HighY,HighWidth , HighHeight, High                          ;get postions of High box
  WinGetPos, LowX, LowY,LowWidth , LowHeight, Low                               ;get postions of Low box
  IfGreater, highx,%lowx%                                                       ;check for high to the right of low
    {
      linewidth:=highx-lowx-30
      Linestart:=highx-linewidth
    }
  Else                                                                          ;else high must be left of low
    {
      linewidth:=lowx-highx-30
      Linestart:=highx+30
    }
  Line1:=highy +(lowy-highy)/100*38.2                                           ;height calcs of each line
  Line2:=highy +(lowy-highy)/100*50
  Line3:=highy +(lowy-highy)/100*61.8
  Line4:=highy +(lowy-highy)/100*150                                            ;below low 150%
  Line5:=HighY -(lowy-highy)/100*32                                             ;above high 132%
  SplashImage 1:,% "B W" linewidth  "H2 Y" HighY "X"Linestart "CWLIME"		;high
  SplashImage 2:,% "B W" linewidth  "H2 Y" lowY  "X"Linestart "CWRED"  		;low
  SplashImage 3:,% "B W" linewidth  "H1 Y" Line1 "X"Linestart "CW"insideColor	;mid high
  SplashImage 4:,% "B W" linewidth  "H1 Y" Line2 "X"Linestart "CW"insideColor	;mid
  SplashImage 5:,% "B W" linewidth  "H1 Y" Line3 "X"Linestart "CW"insideColor  	;mid low
  SplashImage 6:,% "B W" linewidth  "H1 Y" Line4 "X"Linestart "CW"outsideColor 	;predlow
  SplashImage 7:,% "B W" linewidth  "H1 Y" Line5 "X"Linestart "CW"outsideColor	;predhigh
  If outside=0                                                                  ;if checkbox unticked, turn off lines
    {
      SplashImage 6:OFF
      SplashImage 7:off
    }
  If inside=0                                                                   ;if checkbox unticked, turn off lines
    {
      SplashImage 3:off
      SplashImage 4:off
      SplashImage 5:off
    }
Return
hideall:                                                                        ;turn off lines, hide high and low
  SplashImage 1:off
  SplashImage 2:off
  SplashImage 3:off
  SplashImage 4:off
  SplashImage 5:off
  SplashImage 6:off
  SplashImage 7:off
  Gui 1:hide
  Gui 2:hide
Return
ABOUT:
  Gui,9:Font,Bold
  Gui,9:Add,Text,x+10 yp+10,%version%
  Gui,9:Font
  Gui,9:Add,Text,xm+10,'%Version%' draws Lines on the Screen as per the name .
  Gui,9:Add,Text,xm+10,Use by dragging the high and low to new positions
  Gui,9:Add,Text,xm+10,its only real purpose is to draw Lines on stock market graphs.
  Gui,9:Add,Text,xm+10,The original Idea and request by Aquarelle
  Gui,9:Font,CBlue underline
  Gui,9:Add,Text,xm+10,http://www.donationcoder.com/Forums/bb/index.php?topic=4859.0
  Gui,9:Add,Text,y+0,`t
  Gui,9:Font
  Gui,9:Font,Bold
  Gui,9:Add,Text,xm+10 yp+10,DonationCoder
  Gui,9:Font
  Gui,9:Add,Text,xm+10,Please support the DonationCoder community
  Gui,9:Font,CBlue underline
  Gui,9:Add,Text,xm+10 GDONATIONCODER,www.DonationCoder.com
  Gui,9:Font
  Gui,9:Add,Text,y+0,`t
  Gui,9:Font,Bold
  Gui,9:Add,Text,xm+10 yp+10,AutoHotkey
  Gui,9:Font
  Gui,9:Add,Text,xm+10,This program was made using AutoHotkey
  Gui,9:Font,CBlue underline
  Gui,9:Add,Text,xm+10 GAUTOHOTKEY,www.AUTOHOTKEY.com
  Gui,9:Font
  Gui,9:Add,Text,y+0,`t
  Gui,9:Font,Bold
  Gui,9:Add,Text,xm+10 yp+10,made by DoubleBogey (dB)
  Gui,9:Font
  Gui,9:Add,Text,xm+10,Find more mini-apps like this visit
  Gui,9:Font,CBlue underline
  Gui,9:Add,Text,xm+10 GDONATIONCODER,www.DonationCoder.com
  Gui,9:Font
  Gui,9:Add,Text,y+0,`t
  Gui,9:Add,Button,GABOUTOK Default w75,&OK
  Gui,9:Show,,About %Version%
Return
ABOUTOK:
  Gui, 9:Destroy
Return
DONATIONCODER:
  Run,http://www.donationcoder.com,,UseErrorLevel
Return
AUTOHOTKEY:
  Run,http://www.autoHotkey.com,,UseErrorLevel
Return
3Guiclose:                                                                      ;close button on pref gui used
  MsgBox, 4, , Do you want to Exit %version% now? (Press YES or NO)
  IfMsgBox No                                                                   ;if No, do nothing
      Return
Exit:
  ExitApp