Drawing Shapes in AHK (Proof-of-Concept)

[Masonjar13]

I wrote a function for someone on one of the AHK forums to get coords based off known coords, length, and angle. I then decided to play into it a bit and draw some shapes. Here's a pretty good demo I made, although, please note that for polygons, it will never have more inner-vectors compared to the outer-vectors, because I wanted it that way  

Instructions:

•  Run script
•  Open a new paint window, full-screen
•  The rest should be self-explanatory (starting coords are always the center of the screen)

AHK-Draw Demo

Code: Autohotkey [Select]

1. #SingleInstance Force
2. #Persistent
3. CoordMode, Mouse, Screen
4. SetBatchLines -1
5. Process,Priority,,R
6.  
7. ; Make Gui's
8. Gui,1:Add,Button,gCircle w130 h50,Circle
9. Gui,1:Add,Button,gPolygon w130 h50,Polygon
10. Gui,1:Add,Button,gSpiral w130 h50,Spiral
11. Gui,2:Add,Text,,Radius:
12. Gui,2:Add,Edit,vlen Limit4,
13. Gui,2:Add,Button,gCircleOK,Draw!
14. Gui,3:Add,Text,,Layer count:
15. Gui,3:Add,Edit,vLcnt Limit5,
16. Gui,3:Add,Text,ym,Narrowness (1 - 100):
17. Gui,3:Add,Edit,vNarrow Limit3,
18. Gui,3:Add,Button,gSpiralOk,Draw!
19. Gui,4:Add,Text,,Outward radius:
20. Gui,4:Add,Edit,vOrad Limit4,
21. Gui,4:Add,Text,,`nInward radius:
22. Gui,4:Add,Edit,vIrad Limit4,
23. Gui,4:Add,Text,ym,Outward vectors (count):
24. Gui,4:Add,Edit,vOvec Limit3,
25. Gui,4:Add,Text,,`nInward vectors (count):
26. Gui,4:Add,Edit,vIvec Limit3,
27. Gui,4:Add,Text,ym,Angle:
28. Gui,4:Add,Edit,vPang Limit4,
29. Gui,4:Add,Button,gPolygonOk,Draw!
30.  
31. ; main gui
32. +1::
33. Gui,1:Show,,Draw
34. return
35.  
36. Circle: ; circle gui
37. Gui,1:Submit
38. Gui,2:Show,,Draw Circle
39. return
40. CircleOK: ; draw circle
41. Gui,2:Submit
42. BlockInput MouseMove
43.  
44. Loop 361
45. {
46.     GetPosFromAngle(mx,my,A_ScreenWidth/2,A_ScreenHeight/2,len,A_Index)
47.     MouseMove,% mx,% my,0
48.     if(A_Index=1)
49.         Send {LButton down}
50. }
51. Send {LButton up}
52. BlockInput MouseMoveOff
53. return
54.  
55. Spiral: ; spiral gui
56. Gui,1:Submit
57. Gui,3:Show,,Draw Spiral
58. return
59. SpiralOK: ; draw spiral
60. Gui,3:Submit
61. ind:=0
62. BlockInput MouseMove
63. MouseMove,% A_ScreenWidth/2,% A_ScreenHeight/2,0
64. Send {LButton down}
65.  
66. Loop %Lcnt%
67. {
68.     Loop 360
69.     {
70.         ind++
71.         GetPosFromAngle(mx,my,A_ScreenWidth/2,A_ScreenHeight/2,ind*(Narrow*0.01),A_Index)
72.         MouseMove,% mx,% my,0
73.     }
74. }
75. Send {LButton up}
76. BlockInput MouseMoveOff
77. return
78.  
79. Polygon: ; polygon gui
80. Gui,1:Submit
81. Gui,4:Show,,Draw Polygon
82. return
83. PolygonOk: ; draw polygon
84. Gui,4:Submit
85. if(Ovec+Ivec > 360){
86.     msgbox,,Error,Can not have more than 360 vectors.
87.     return
88. }
89. ind:=0
90. BlockInput MouseMove
91.  
92. GetPosFromAngle(mx,my,A_ScreenWidth/2,A_ScreenHeight/2,Orad,Pang)
93. MouseMove,% mx,% my,0
94. Send {LButton down}
95. Lpc:= Ovec + Ivec
96. Ovec--
97. iys:=1
98.  
99. Loop % Lpc
100. {
101.     ind+=360/Lpc
102.     GetPosFromAngle(mx,my,A_ScreenWidth/2,A_ScreenHeight/2,iys?Irad:Orad,ind+Pang)
103.     MouseMove,% mx,% my,0
104.     Ivec-=iys ? 1 : 0
105.     Ovec-=!iys ? 1 : 0
106.     iys:=Ivec < 1 ? 0 : !iys
107.     Sleep 15 ; seems to be inconsistent during multiple runs without delay
108. }
109. Send {LButton up}
110. BlockInput MouseMoveOff
111. return
112.  
113. +2:: ; stop drawing
114. if(GetKeyState("LButton"))
115.     Send {LButton up}
116. reload
117.  
118. +3:: ; kill
119. if(GetKeyState("LButton"))
120.     Send {LButton up}
121. ExitApp
122.  
123. ; ***function(s)***
124.  
125. GetPosFromAngle(ByRef x2,ByRef y2,x1,y1,len,ang){
126.     ang := (ang-90) * 0.0174532925
127.     x2 := x1 + len * cos(ang)
128.     y2 := y1 + len * sin(ang)
129. }

Demo pics

The hotkeys are Shift+1 to bring up the main gui, Shift+2 to instantly interrupt the drawing, Shift+3 to kill the script.

I encourage modification of this code, but request acknowledgement if my function is used elsewhere, thanks!  

[mouser]

neat.