DonationCoder.com Software > Post New Requests Here

IDEA: Single hotkey to call an AddressBook

(1/2) > >>

davcom:
I don't know if anyone else struggles with this but I always feel like I'm jumping through hoops (multiple clicks/menu's) to use any software in the world (or on my mobile but thats a separate matter) to _quickly_ find someones phone number or contact details.

Is it possible to build a program that no matter what else I'm running I can push a single (definable?) hotkey to start or bring into focus an address book ?

Requirements are :
 that it must be a single key (ok maybe a 2 key combo if nec)
 that it is a 'shortlist as you type" search field on combined name, address, any phone number
 that it can be called from anywhere (you could be knee deep in Excel, or Latex, or some Python coding, but you can still call up your AB at the drop of a hat)

The ramifications of linking to anyone elses AddressBook system I really don't want to go near. Far too convoluted to build an API to handle whoever has what. However, any approach that allows other systems to access the data in the AddressBook system suggested here would probably be of interest to many (even if it's a capability for manual import into any other AddressBook such as Outlook/Express, Windows (Live) Mail, T'bird, etc)

To be functional it must be QUICK and straightforward. Straightforward does not mean simple, it will likely be quite sophisticated, but the aim is to very quickly find someones appropriate phone number(s) to contact them, send a fax, or know the address to send an email to (capability to auto-call default email program if addy clicked or go to website if URL clicked ?). Possibility of dated notes regarding contact detail changes (phone number or address changes but you can still search on the older information to see correlations with other contacts ? ie. Maintain a history of previous contact details per person or business ?)

At the risk of seeming ignorant (with 30 years in the IT industry) there may be something around that does it the way I'm suggesting, but to my mind (so far) every AddressBook supplier seems to have focused on what information is required not how people actually need it to work to be efficient ? Here's a thought.. imagine Outlook with a single hotkey approach (from anywhere in your PC) to bringing up your Contact List !? Productivity may well soar ! (I know my stress levels would reduce but I prefer T'bird any day)

At present my preference is to use Evernote because of the free-format approach (to add notes to the contact data, and I do have a structure within each note that is applied) and Evernotes very powerful search & shortlist approach plus its ability to call programs from email addresses and URL's within the note.

Anyone else struggle with QUICK access to their addressbook ?

MilesAhead:
Instead of reinventing address book programs, why not take the approach of a hotkey that sits in the tray that will launch any shortcut?

I say shortcut because presumably that will allow any command line options, working directory etc., to be set without my hotkey having to worry about it.

Here's a super simple first attempt.

Default is F11 key.
First time you press the hotkey you have to select the shortcut.
You can change the hotkey via Tray Menu.

When the hotkey is quit from the tray it saves the shortcut and hotkey to .ini file.
At this point to change the shortcut you would either edit the .ini file manually
or just delete the .ini file and hit the hotkey again to select another shortcut.

For example, if I want to press F11 and have AudioGrabber pop up, I press F11 then navigate to the AudioGrabber shortcut to initialize it. After that, when the hotkey is running, every time I press F11 AudioGrabber pops up.

In your case you would navigate to your favorite address book.
Any clipboard pasting etc. should be a feature of the address book, not the launcher.

Try it and see if you like it. It's a bit crude but you should only have to initialize it once.


--- ---;
; Name: OneKey
; Author: MilesAhead
; Platform: Windows XP or later
;
; Script Function:
; A shortcut is opened when a (single) hotkey is pressed
;   such as F11 etc..
;
;   Menu command allows hotkey to be set by user.
;
;   Note that if you try to change F11 to Alt-F11 it
;   will fire the hotkey rather than change it. Until
;   I learn the "ignore" setting, if there is one, the
;   work-around is to set the hotkey to something that
;   does not contain an active hotkey.
;
;   Hotkey and shortcut is saved to ini file
;   Hotkey can be specified on command line

#SingleInstance force
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
Menu Tray,NoStandard
Menu Tray,Add
Menu Tray,Add,About OneKey,DoAbout
Menu Tray,Add
Menu Tray,Add,Set Keyboard Hotkey,DoKeyboard
Menu Tray,Add
Menu Tray,Add,Quit,DoQuit
Menu Tray,Tip,OneKey to launch shortcut

IniFile = %A_ScriptDir%\%A_ScriptName%
IniFile := RegExReplace(IniFile,"i)ahk$","ini")
IniFile := RegExReplace(IniFile,"i)exe$","ini")

If 0 = 1
{
  KHotKey = %1%
}
Else
{
  KHotKey := "F11"
  IniRead,KHotkey,%IniFile%,Settings,KeyboardHotkey,%KHotKey%
}

Hotkey,%KHotKey%,DoHotKey,UseErrorLevel
If ErrorLevel
{
  MsgBox, 4112, OneKey, %KHotKey% is not a valid Hotkey
  ExitApp
}

IniRead,shortcut,%IniFile%,Settings,Shortcut,%A_Space%
result := _EmptyWorkingSet()
return

DoHotKey:
  If shortcut =
  {
    ;MsgBox, 4112, OneKey, Shortcut not assigned!
    FileSelectFile,shortcut,35,%A_StartMenuCommon%,Select Shortcut, shortcut (*.lnk)
  }
  If shortcut <>
  {
    Run,%shortcut%
  }
Return


DoAbout:
  FileGetVersion,filever,OneKey.exe
  MyMsg =
  (
OneKey v %filever% Copyright (c) 2011 www.FavesSoft.com`n
Press %KHotKey% to launch shortcut`n
  )
  MsgBox, 4160, About OneKey, %MyMsg%
Return

DoKeyboard:
  Gui, Add, Hotkey, x6 y7 w140 h20 vHotkey,%KHotkey%
  Gui, Add, Button, x156 y7 w110 h20 gGO , Set Hotkey
  Gui, Show, w273 h39, Set Hotkey
Return

GO:
  SaveKHotkey := KHotkey
  Gui, Submit
  KHotkey := Hotkey
  ;MsgBox, 0, , %KHotkey% is Hotkey
  Gui,Destroy
  Hotkey,%KHotkey%,DoHotKey,UseErrorLevel
  If ErrorLevel
  {
    KHotkey := SaveHotkey
    Hotkey,%KHotkey%,DoHotKey
  }
Return

DoIniWrite:
  IniWrite,%KHotKey%,%IniFile%,Settings,KeyboardHotkey
  IniWrite,%shortcut%,%IniFile%,Settings,Shortcut
return

DoQuit:
  GoSub,DoIniWrite
  ExitApp

  _EmptyWorkingSet()
  {
    Return DllCall("psapi.dll\EmptyWorkingSet", "UInt", -1)
  }

ewemoa:
I don't know if I'm missing the point here, but FWIW, Thunderbird looks like it supports a command line option "-addressbook":

  http://kb.mozillazine.org/Run_Address_Book_from_Command_Line
  http://support.mozillamessaging.com/bg/kb/Standalone+address+book

I wonder if an AutoHotkey or AutoIt script wrapped around that could be of any use...

AndyM:
What AddressBook do you use?

MilesAhead:
I'm not exactly sure what the OP wants but it sounds like a form filler function that's specific to addresses and phone numbers.

Navigation

[0] Message Index

[#] Next page