topbanner_forum
  *

avatar image

Welcome, Guest. Please login or register.
Did you miss your activation email?

Login with username, password and session length
  • Friday March 29, 2024, 2:49 am
  • Proudly celebrating 15+ years online.
  • Donate now to become a lifetime supporting member of the site and get a non-expiring license key for all of our programs.
  • donate

Last post Author Topic: Transpose 2.3.2.3  (Read 53182 times)

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.6.0
« Reply #25 on: October 30, 2011, 05:19 PM »
Note I just uploaded 2.2.6.0 again.  Just removed a line in About Box referring to EditPadLite7. No other changes. The latest EditPadLite7 the menu change hotkey function works. No need for me to jury rig anymore.


MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.0
« Reply #26 on: December 01, 2011, 03:45 PM »
Transpose 2.2.7.0 Removed mouse click side-effect when back tic key or Win Click is used to copy selected text to clipboard in browsers. Now it sends right arrow key to clear selection.

Added hotkey string "qqTab" (invoke by pressing the letter 'q' twice then Tab key) in supported browsers to select all text in an edit box and copy to clipboard.  Also if Selector.exe is running, hotkey ^{NumPadDiv} is sent to bring up the Selector window in Clipboard mode.

For example, if you have Notepad in your Selector ListBox you can use Paste or Control-V Button to open Notepad with the clipboard text.  Admittedly it's a right-handed option so you can select all text and copy to clipboard in one motion without taking your hand off the mouse.

Edit: Put the mouse click back in to clear selection. Less of a side effect in browsers than the arrow key.  Esp. if there's a horiz. scrollbar active. :)  Guess that's why I used Click originally.

Old version number new upload. :)
« Last Edit: December 01, 2011, 04:32 PM by MilesAhead »

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.1
« Reply #27 on: December 01, 2011, 08:36 PM »
Transpose 2.2.7.1 Now clears clipboard before copy when handling back tic/Win Click.

This enables it to copy selected off a web page as well as an edit box/form. Should also get rid of the "ding" when the mouse is clicked to clear the selection.

superboyac

  • Charter Member
  • Joined in 2005
  • ***
  • Posts: 6,347
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.1
« Reply #28 on: December 01, 2011, 09:41 PM »
Ah!  Another fellow Transpose user!  Miles...when are we gonna jam?

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.1
« Reply #29 on: December 02, 2011, 02:00 AM »
Ah!  Another fellow Transpose user!  Miles...when are we gonna jam?

Heh heh. Glad someone is using it. :)

I did my first AHK hotstring in this last update. It's kind of my catch-all script I always have running.

Never really looked at the hotstring facility until yesterday. Interesting alternative to the hold key down bit.
« Last Edit: December 02, 2011, 02:07 AM by MilesAhead »

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.2
« Reply #30 on: December 03, 2011, 08:18 PM »
Transpose 2.2.7.2 Added Hotkey Alt Click in supported browser windows.

Purpose: You are on a page that has a url in text that's not enabled as a link. Ordinarily you would select text, open new tab, paste, or use a tab extension to enable automating that action. With this Transpose update, select the text and Alt Click the mouse on a neutral spot. It's done for you. (The reason to click on a neutral spot is a Click is sent to the page to clear the text selection.)

This hotkey is only enabled while a supported browser window is active. It gets the exe path of the browser from the active window and runs it.  The selection is only added as a command line param.
Therefore it should be safe. If you select "del *.*" and do Alt Click the result would be(assuming firefox browser)  running this command "c:\program files\mozilla firefox\firefox.exe del *.*" which will just produce a 404 error.  Not delete files. :)
« Last Edit: December 05, 2011, 02:16 PM by MilesAhead »

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.2.7.3
« Reply #31 on: December 05, 2011, 08:51 PM »
Transpose 2.2.7.3 Removed a couple of redundant text copy to clipboard keys. I think I've come up with a smooth AutoCopy selected text to clipboard.  Select text but hold left mouse button down until you press and release Shift.  If selected text is copied to clipboard you should hear a tone.

See the about dialog for current sets of hotkeys.

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.0
« Reply #32 on: December 06, 2011, 01:15 PM »
Transpose 2.3.0.0 IE Browser is no longer supported.  Also listed editors and browsers that support Control-t Transpose function in About Dialog.

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.1
« Reply #33 on: December 06, 2011, 05:04 PM »
Transpose 2.3.0.1 Now AutoCopy using Shift/Release while Left Mouse Button down no longer sends a Click to deselect the text.  AutoCopy sounds a tone to verify something was copied to clipboard. Deselecting the text is no longer needed as an indicator. Also it interfered with timing letting off the mouse button.  Now it's not so touchy.  Select text and keep mouse button down.  Press and release Shift key. You should hear the tone as text is now in clipboard.

If you want to clear the selection just click the mouse yourself.  The text will still be in the clipboard.

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.3
« Reply #34 on: May 08, 2012, 03:44 PM »
Transpose 2.3.0.3 Chromium browsers were using ahk_class Chrome_WidgetWin_0. I see now they have changed in the latest snapshots to ahk_class Chrome_WidgetWin_1. I have added that so that stuff like +LButton and ^LButton to open links in background and foreground respectively, works for the new snapshots. (For me, holding down both control and shift, then clicking, just to open a link in a foreground tab is way too awkward.)

Here's my latest source

;
; Transpose - copyright 2012 www.favessoft.com
;
; Utility to transpose 2 characters to the left of the caret
; in editors and/or browsers, for typo fix on the fly.
;
; I use this script as a kind of catch all for hotkeys
; that don't need ini file settings. See About Dialog
; for details
;
; Author: MilesAhead
;
; Use Visit Hotkey Page Tray Menu command to get latest version
; and view Windows Requirements.
;
; Use Donate Tray Menu command to support future releases
;
; FavesSoft Windows Utilities are free for you to use
; at your own risk.
;
; MilesAhead
;
#SingleInstance force
#NoEnv
#Warn UseUnsetLocal, Off
DetectHiddenWindows, On
SetTitleMatchMode,2
SendMode Input
SetWorkingDir %A_ScriptDir%
CoordMode,ToolTip,Screen
#Hotstring EndChars `t
Menu Tray,NoStandard
Menu Tray,Add,Donate,DoDonate
Menu Tray,Add,Visit Hotkey Page,DoVisit
Menu Tray,Add,About Transpose,DoAbout
Menu Tray,Add
Menu Tray,Add,Quit,DoQuit
Menu Tray,Default,About Transpose
if (A_IsCompiled)
{
  Menu Tray,Icon,%A_ScriptFullPath%,1
  Menu Tray, Icon, About Transpose, Transpose.exe,, 24
  Menu Tray, Icon, Visit Hotkey Page, Transpose.exe,2, 24
  Menu Tray, Icon, Donate, Transpose.exe,3, 24
  Menu Tray, Icon, Quit, Transpose.exe,4, 24
}
Menu Tray,Tip,Transpose

TMin := 0
TSec := 0
Selected := ""
KeyHHCmd := "KeyHH -AutoIt C:\Program Files\AutoIt3\WinAPIEx.chm::/html/libfunctions.htm"
GroupAdd,EditorGroup, ahk_class TFormEditPadLite  ;EditPadLite
GroupAdd,EditorGroup, ahk_class TFormEditPadLite7 ;EditPadLite7
GroupAdd,EditorGroup, ahk_class wxWindowClassNR   ;FBIde
GroupAdd,EditorGroup, ahk_class SciTEWindow       ;Scite
GroupAdd,EditorGroup, ahk_class MAINFBEDIT        ;FBEdit
GroupAdd,EditorGroup, ahk_class Notepad           ;Notepad
GroupAdd,EditorGroup, ahk_class TFormMain         ;TreePad
GroupAdd,EditorGroup, ahk_class Chrome_WidgetWin_0   ;Chromium Browser
GroupAdd,EditorGroup, ahk_class Chrome_WidgetWin_1   ;Chromium 20.x
GroupAdd,EditorGroup, ahk_class MozillaUIWindowClass ;Firefox Browser
GroupAdd,EditorGroup, ahk_class MozillaWindowClass   ;Firefox 4 Browser
GroupAdd,EditorGroup, ahk_class OperaWindowClass     ;Opera 11
GroupAdd,EditorGroup, BBCeditor ; BBCeditor

GroupAdd,BrowserGroup, ahk_class Chrome_WidgetWin_0   ;Chrome Browser
GroupAdd,BrowserGroup, ahk_class Chrome_WidgetWin_1   ;Chromium 20.x
GroupAdd,BrowserGroup, ahk_class MozillaUIWindowClass ;Firefox Browser
GroupAdd,BrowserGroup, ahk_class MozillaWindowClass   ;Firefox 4 Browser
GroupAdd,BrowserGroup, ahk_class OpWindow             ;Opera Browser
GroupAdd,BrowserGroup, ahk_class OperaWindowClass     ;Opera 11

GroupAdd, ChromeGroup, ahk_class Chrome_WidgetWin_0   ;Chrome Browser
GroupAdd, ChromeGroup, ahk_class Chrome_WidgetWin_1   ;Chromium 20.x

GroupAdd,ExplorerGroup, ahk_class CabinetWClass
GroupAdd,ExplorerGroup, ahk_class ExploreWClass

#IfWinActive ahk_Group EditorGroup
^t::
  ClipSaved := ClipboardAll ; save entire clipboard
  Clipboard= ; clear clipboard
  Send {Shift Down}{Left}{Shift Up} ; select char left of caret
  Send ^c ; copy char
  ClipWait,0 ;give copy time to complete
  ; the caret is positioned to insert
  ; the char from the clipboard. Editor
  ; must be in Insert Mode for it to work.
  ; The char is inserted, and caret positon restored.
  ;
  Send {Right}
  Send {BackSpace}
  Send {Left}
  Send {Raw}%Clipboard% ; avoid puntuaction being interpreted
  Send {Right}
  Clipboard := ClipSaved
  ClipSaved = ; free memory
Return

#IfWinActive ahk_group ChromeGroup
^LButton::
  Send, ^+{LButton}
Return

#IfWinActive ahk_group ChromeGroup
+LButton::
  Send, ^{LButton}
Return

#IfWinActive ahk_Group BrowserGroup
::qq::
  Clipboard =
  Send,^a
  Send,^c
  ClipWait,1
  Send,{Right}
  Process,Exist,selector.exe
  if ErrorLevel
    Send,^{NumPadDiv}
Return

!LButton::
  pPath := WinGetProcessPath("A")
  Clipboard =
  Send,^c
  ClipWait,1
  Selected = %Clipboard%
  Click
  if pPath && Selected
    Run, %pPath% %Selected%
Return

^F10::
  Clipboard =
  Send ^c
  ClipWait,1
  Click
  Sleep, 100
  Selected = %Clipboard%
  if Selected
    Run,http://www.thefreedictionary.com/%Selected%
Return

+F10::
  TMin := 0
  TSec := 0
  Clipboard =
  Send ^c
  ClipWait,2
  Selected = %Clipboard%
  gosub,ShowResults
Return

^F9::
  Clipboard =
  Send,^{LEFT}^+{RIGHT}
  Sleep,10
  Send,^c
  ClipWait,0
  Selected := Clipboard
  Send,{Right}
  Run,http://www.thefreedictionary.com/%Selected%
Return

; AutoCopy to clipboard in supported browsers
;
; Select text with mouse, holding left mouse
; button down. Press and release Shift, then release
; mouse button. If text copied to clipboard the
; selection will be cleared.
;
~Shift::
  if not GetKeyState("LButton")
    Return
  Clipboard =
  Send ^c
  ClipWait,1
  Selected = %Clipboard%
  if not Selected
    Return
  SoundPlay,*48
Return

#IfWinActive ahk_Group ExplorerGroup
MButton::
  MouseClick, left, , , 2
Return

+MButton::
  Progress, zh0 B fs12 CTBlue,Press a letter to open`nExplorer to that drive
  Input,keypress,L1
  Progress, OFF
  dr := keypress . ":\"
  StringUpper,dr,dr
  If FileExist(dr)
  {
    Run,Explorer.exe /e`,%keypress%:\
  }
  else
  {
    Progress, zh0 B fs12 CTRed,%dr% Drive Does Not Exist!
    Sleep,3000
    Progress, OFF
  }
Return

;Newsbin floating Groups List
;show posts on Group Middle Click
#IfWinActive ahk_class XTPDockingPaneMiniWnd
MButton::
  Send,^l
Return

;if UltraSearch 1.5 is minimized to Tray
;pressing Shift Backspace should open window
;
;requires UltraSearch 1.5 or later as previous
;versions do not have "single instance" behavior
#IfWinExist UltraSearch
  +BS::
  Run,C:\Utils\UltraSearch\UltraSearch.exe
Return


ShowResults:
    Loop, parse, Selected, `n, `r
    {
        StartPos := RegExMatch(A_LoopField,"[0-9]+:")
        if (!StartPos)
            continue
        StringMid,found,A_LoopField,StartPos,5
        if (found)
        {
            found = %found%
            StringLeft,nstr,found,InStr(found,":") - 1
            TMin := TMin + nstr
            ;StringMid,nstr,found,InStr(found,":") + 1,2
            StringRight,nstr,found,2
            TSec := TSec + nstr
            if (TSec // 60)
            {
                TMin := TMin + TSec // 60
                TSec := Mod(TSec,60)
            }
        }
    }
    TSec := (StrLen(TSec)=1) ? "0" TSec : TSec
    MsgBox, 4160, Transpose, Total Time:  %TMin%:%TSec%
Return

DoAbout:
  FileGetVersion,filever,Transpose.exe
  MyMsg =
  (
Transpose v %filever% Copyright (c) 2012 www.FavesSoft.com`n
Control-t Transposes the 2 characters left of the caret`n
Supports edit controls in Chrome, Firefox and Opera Browsers.
Supports EditPadLite, EditPadLite7, FBIde, FBEdit, Scite, Notepad,
and TreePadLite Editors`n
Chrome Browsers:`n`nControl-Click opens link in new foreground Tab`nShift-Click in new background Tab`n`nChrome. Firefox, and Opera Browsers:`n`nAlt Click opens Selected Text in new tab if valid URL`nShift/Release with left mouse key down to AutoCopy Text`nqq Tab in Edit Copies All text to Clipboard, triggers Selector`n`nControl F9 key looks up word left of caret on`nThe Free Dictionary   Control F10 key looks up selection`n`nShift F10 key to total AllMusic play times`n
Middle Mouse Click in Explorer to Double-Click`n
Shift Middle Click an empty spot in Explorer to open a Drive Letter`n`n
Note: IE Browser is not supported.
  )
  if WinExist("UltraSearch.exe")
    MyMsg := MyMsg . "Shift Backspace Displays UltraSearch 1.5 if running in Tray"
  MsgBox, 4160, About Transpose, %MyMsg%
Return

DoDonate:
  Run,"http://www.favessoft.com/donate.html"
Return

DoVisit:
  Run,"http://www.favessoft.com/hotkeys.html"
Return

DoQuit:
  ExitApp

--- Helper Functions ---

; Usage: WinGetProcessPath("A") to get program path for active window
; returns "" on error, program path on success
;
; e.g. chromium browser might return C:\Program Files\Chromium\chrome.exe
;
; adapted from WinGetProcessName by Lexikos
;
WinGetProcessPath(WinTitle="", WinText="", ExcludeTitle="", ExcludeText="")
{
  WinGet pid, PID, %WinTitle%, %WinText%, %ExcludeTitle%, %ExcludeText%
  if !hproc := DllCall("OpenProcess", "uint", 0x410, "int", false, "uint", pid)
      return
  VarSetCapacity(name, 520)
  static hmod := DllCall("LoadLibrary", "str", "psapi") ; Preload psapi.dll.
  DllCall("psapi\GetModuleFileNameEx", "ptr", hproc, "ptr", 0, "str", name, "uint", 260)
  DllCall("CloseHandle", "ptr", hproc)
  return name
}

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.4
« Reply #35 on: June 23, 2012, 08:55 PM »
Transpose 2.3.0.4 Added hit test so that pressing middle mouse button in an Explorer Window only sends a double click if the mouse pointer is in the client area of the window.  The idea is to avoid unintentionally double clicking the caption bar as it may conflict with other hotkey apps.

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #36 on: June 24, 2012, 12:35 AM »
Transpose 2.3.0.5 Fixed bug in "hit test" code that determines where in the window the mouse was clicked.

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #37 on: June 24, 2012, 07:03 AM »
Transpose the 2 character left of the caret ?

I am using Firefox.
Is it useful for this browser ?

 What is the caret ?

Best Regards

 :P

tomos

  • Charter Member
  • Joined in 2006
  • ***
  • Posts: 11,959
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #38 on: June 24, 2012, 08:32 AM »
What is the caret ?

Cursor, you know when you're typing - it blinks:

Screenshot - 2012-06-24 , 15_19_06.png
Tom

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #39 on: June 24, 2012, 02:47 PM »
What is the caret ?

Cursor, you know when you're typing - it blinks:
 (see attachment in previous post)

 :-*
I undertand now.

http://img329.imageshack.us/img329/1451/muyfelizna4.gif
Transpose 2.3.2.3

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #40 on: June 24, 2012, 03:08 PM »
I am thinking about the middle mouse click
One of my often moves is go to see the main goldmine window
Goldmine is my CRM and knowledge base. I use continually.
So the clicks to make active the goldmine windows are very very often. May be 300 times a day.
At the present I need to move the mouse to click on the icon in the task bar or in the window in the task bar (excuse my english) . I'll put a screenshot.
Inside FF  when i click in the middle mouse click I paste. But I really i am used to use Ditto or Ctrl-V.
MilesAhead script ReOpen give the possibility to use the middle mouse click to hotkey and see a list.
So.
I think for me is specially useful that the middel mouse click have the following special function.

Really two functions.

If goldmine is open :
Activate his window
This way

http://img715.imageshack.us/img715/8408/mozart24062012210049.png
Transpose 2.3.2.3


If Goldmine is not open, then open the program with this command :

Y:\GoldminePrg\gmw5.exe /i:esm /u:JOSE /p:

http://img3.imageshack.us/img3/962/mozart24062012205151mod.png
Transpose 2.3.2.3

so I need an If ?

Sorry I think I must open a new post for this problem. But the idea comes from the using of Miles in his scripts.





MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #41 on: June 24, 2012, 03:31 PM »
ReOpen is stable. I don't plan any updates. I don't use it myself anymore. I use FolderCache and ReRun to accomplish the same thing. ReRun can capture command line args where ReOpen can't.  Also AutoIt3 hotkey handling is not as good as AHK_L. In ReOpen I just test if middle mouse button is down. Way too primitive to add stuff onto.

Try something like this in ahk_l

~MButton::
  Process,Exist,gmw5.exe
  if (ErrorLevel) ; process is running
    WinActivate,gmw5_window_title ; whatever the title or class is
  else
    Run,Y:\GoldminePrg\gmw5.exe /i:esm /u:JOSE /p:
return

If you only want the middle button click to fire in certain windows or
on the desktop see the help for #IfWinActive directive.

You may have to experiment with quoting the command line params but it shouldn't take much to get it working.

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #42 on: June 24, 2012, 04:50 PM »
ReOpen is stable. I don't plan any updates. I don't use it myself anymore. I use FolderCache and ReRun to accomplish the same thing. ReRun can capture command line args where ReOpen can't.  Also AutoIt3 hotkey handling is not as good as AHK_L. In ReOpen I just test if middle mouse button is down. Way too primitive to add stuff onto.

Try something like this in ahk_l

~MButton::
  Process,Exist,gmw5.exe
  if (ErrorLevel) ; process is running
    WinActivate,gmw5_window_title ; whatever the title or class is
  else
    Run,Y:\GoldminePrg\gmw5.exe /i:esm /u:JOSE /p:
return

If you only want the middle button click to fire in certain windows or
on the desktop see the help for #IfWinActive directive.

You may have to experiment with quoting the command line params but it shouldn't take much to get it working.


 :-*
Going to learn.
ReOpen is stable. I am a witness  :P

http://img101.imageshack.us/img101/7251/besotene2.gif
Transpose 2.3.2.3



P.D. Finally I get after a hard fight with my ignorance :

https://www.donation...?topic=31417.new#new

 :P
« Last Edit: June 24, 2012, 06:16 PM by Contro »

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #43 on: June 24, 2012, 06:19 PM »
Glad you got it working. :)

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #44 on: June 30, 2012, 04:41 PM »
Ejem.
I think is better here, but I repeat in the other post :

https://www.donation...?topic=31417.new#new

What I need now is very similar to the middle button script but more simple : Don't require a hotkey (or shorcut combination)

But is for Firefox

And Firefox uses tabs and have many many names for the active window

so I try a script with three most common possible situation, but the command if don't accept

This is the code :

  Process, Exist, firefox.exe
  if (ErrorLevel) ; process is running
;    WinActivate, Administrador de complementos - Mozilla Firefox
WinActivate, Webs Generales - Speed Dial - Mozilla Firefox
; WinActivate, Búsqueda personalizada de Google - Mozilla Firefox
; WinActivate,
  else
     Run M:\Archivos de programa\Mozilla Firefox\firefox.exe
  return

Only admits one winactivation Line. And I don't know what window need finally to be activated.

How can i use more than one window ?

Best Regards
 :-*

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #45 on: June 30, 2012, 05:34 PM »
Use the Window Spy to get the class name for firefox window of the version of FF you are using.  They change the class name when they feel like it as they update versions of browsers. For example

GroupAdd,FireFoxGroup, ahk_class MozillaUIWindowClass ;Firefox Browser
GroupAdd,FireFoxGroup, ahk_class MozillaWindowClass   ;Firefox 4 Browser
GroupAdd,FireFoxGroup, ahk_class NewFFClass   ;whatever new FF version class is

  Process, Exist, firefox.exe
  if (ErrorLevel) ; process is running
    WinActivate, ahk_group FireFoxGroup
  else
     Run M:\Archivos de programa\Mozilla Firefox\firefox.exe
  return



To pick out particular tabs then you'd have to ask on ahk forum.

Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.5
« Reply #46 on: June 30, 2012, 08:16 PM »
Running to try.
Best Regards
 :-*

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.7
« Reply #47 on: October 02, 2012, 11:13 AM »
Transpose 2.3.0.7 Added code to Shift-Backspace handler that detects Everything Search. There is a global variable EverythingShortcut to be set to the shortcut used to launch Everything in background mode. This enables the script to get the exact name of the everything executable rather than forcing a rename of the file without the version numbers.

On Shift-Backsapce if Everything process is running, it just sends the hotkey on(I have Shift-Backspace set as my Everything hotkey.) If the process is not detected, the script uses the path gleaned from the shortcut to launch it.

This way I don't have to include Everything in my startup apps.

The source is included if you wish to comment all this out. :)


Contro

  • Supporting Member
  • Joined in 2007
  • **
  • Posts: 3,940
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.7
« Reply #48 on: October 02, 2012, 05:30 PM »
Running to try Miles
http://img101.imageshack.us/img101/7251/besotene2.gif
Transpose 2.3.2.3

MilesAhead

  • Supporting Member
  • Joined in 2009
  • **
  • Posts: 7,736
    • View Profile
    • Donate to Member
Re: Transpose 2.3.0.7
« Reply #49 on: October 02, 2012, 07:21 PM »
Running to try Miles
http://img101.imageshack.us/img101/7251/besotene2.gif
Transpose 2.3.2.3


 :Thmbsup: