Welcome Guest.   Make a donation to an author on the site April 24, 2014, 09:49:36 AM  *

Please login or register.
Or did you miss your validation email?


Login with username and password (forgot your password?)
Why not become a lifetime supporting member of the site with a one-time donation of any amount? Your donation entitles you to a ton of additional benefits, including access to exclusive discounts and downloads, the ability to enter monthly free software drawings, and a single non-expiring license key for all of our programs.


You must sign up here before you can post and access some areas of the site. Registration is totally free and confidential.
 
Read the Practical Guide to DonationCoder.com Forum Search Features
   
   Forum Home   Thread Marks Chat! Downloads Search Login Register  
Pages: Prev 1 [2]   Go Down
  Reply  |  New Topic  |  Print  
Author Topic: DONE: Photo Downloader Kiosk  (Read 19112 times)
skrommel
Fastest code in the west
Developer
***
Posts: 882



View Profile WWW Give some DonationCredits to this forum member
« Reply #25 on: October 18, 2008, 05:02:23 PM »

 smiley Download the pngs and place them beside the script.

Then replace the source code
[copy or print]
Gui,Add, Button,W75 Xm Ym GREFRESH Default,&Refresh
Gui,Add, Button,W75 X+5 GSELECTALL,Select &All
Gui,Add, Button,W75 X+5 GINVERT,&Invert
Gui,Add, Button,W75 X+5 GUPLOAD,&Upload
width
[copy or print]
Gui,Add,Picture,Xm Ym GREFRESH Default,reload.png
Gui,Add,Text,X+5 Ym+7 GREFRESH,&Reload
Gui,Add,Picture,X+5 Ym GSELECTALL,list-add.png
Gui,Add,Text,X+5 Ym+7 GSELECTALL,Select &All
Gui,Add,Picture,X+5 Ym GINVERT,list-remove.png
Gui,Add,Text,X+5 Ym+7 GINVERT,&Invert
Gui,Add,Picture,X+5 Ym GUPLOAD,filesave.png
Gui,Add,Text,X+5 Ym+7 GUPLOAD,&Upload

Skrommel
« Last Edit: October 20, 2008, 02:21:50 AM by skrommel » Logged

Please stop by my site at  1 Hour Software by skrommel  for downloads and more info.
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #26 on: October 19, 2008, 06:38:42 PM »

Thanks.

This line was not working:
[copy or print]
Gui,Add,Picture,Xm Ym GRELOAD Default,reload.png
Gui,Add,Text,X+5 Ym+7 GRELOAD,&Reload
So I replaced it with this one (the label was GREFRESH not GRELOAD):
[copy or print]
Gui,Add,Picture,Xm Ym GREFRESH Default,reload.png
Gui,Add,Text,X+5 Ym+7 GREFRESH,&Reload

I also neatened up the coordinates for use with the 48x48 icons:
[copy or print]
Gui,Add,Picture,Xm Ym GREFRESH Default,reload.png
Gui,Add,Text,X+2 Ym+36 GREFRESH,&Refresh
Gui,Add,Picture,X+10 Ym GSELECTALL,list-add.png
Gui,Add,Text,X+2 Ym+36 GSELECTALL,Select &All
Gui,Add,Picture,X+10 Ym GINVERT,list-remove.png
Gui,Add,Text,X+2 Ym+36 GINVERT,&Invert Selection
Gui,Add,Picture,X+10 Ym GUPLOAD,filesave.png
Gui,Add,Text,X+2 Ym+36 GUPLOAD,&Upload

And since I'm using the 48x48 icons, the pictures needed to move down a bit, so I changed this code
[copy or print]
y:=25+space
to this
[copy or print]
y:=50+space
« Last Edit: October 19, 2008, 06:41:03 PM by NinJA999 » Logged
murple
Participant
*
Posts: 23

View Profile Give some DonationCredits to this forum member
« Reply #27 on: October 20, 2008, 08:20:27 AM »

Skrommel: I decided to try your script just for the fun of it, copy pasterde the code from your original post and ran the script. The only problem was that I couldn't close the window, nor do anything else with my computer since the window steels all focus. (I realise this is a "feature" of the program, but for the unknowning user testing this, it's very annoying.) I could barely launch Task Manager and had to look up how to use tskill and taskkill to kill all autohotkey.exe processes. Perhaps it would be a smart idea to include a close button in your script by default and explain to people who actually want to use this as a kiosk how to disable the close button (Just comment out the "gui, add, button" line of code for example). I'm really happy that I didn't have to restart, because I've been upgrading a Magellan GPS for a colleague on my computer for the past 2 hours and it was just about finished when I tried PhotoKiosk.

I'll have to do some research on how to close the window before I run it again. I'm guessing it's a nice program though. I'm curious on how you create the thumbnails and also about why it's not listed in your main software page? Is it too early or are you not planning on listing it there?
Logged
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #28 on: October 20, 2008, 03:26:23 PM »

Just so you know, the hard-to-exit-ness was my request, as I know some people who would love to play that type of mischief tongue but I do think it might be a good idea to at least have the key combo listed in the comments at the beginning.  (Ctrl+Shift+Alt+E).
« Last Edit: October 20, 2008, 03:28:04 PM by NinJA999 » Logged
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #29 on: October 20, 2008, 03:28:39 PM »

I also have been tweaking it a little to have a message that pops up while pictures are loading/uploading.  Since there are several lines added in different places, I'll just put the entire script here; keep in mind it is SKROMMEL'S, not mine -- I just made modifications.  Once again, this is SKROMMEL'S SCRIPT.  (I also left off the gdi functions on the bottom since it was too long -- if you want to use this script take the bottom from skrommel's)
[copy or print]
;PhotoKiosk.ahk
;PRESS CTRL+ALT+SHIFT+E TO EXIT!!!!
;Skrommel @ 2008
;Modifications by NinJA999

in:="M:,N:,O:,P:"   ; Source folders separated by comma
out:="G:\Temp2"      ; Targe folder
size:=120           ; Thumbnail size
space:=14           ; Thumbnail space
subfolders:=1       ; Traverse subfolders? 1=Yes 0=No
preview:=400        ; Width of preview window

applicationname=PhotoKiosk

#NoEnv
#SingleInstance,Force
SetBatchLines,-1
SetWinDelay,0
DetectHiddenWindows,On

OnExit,EXIT
pToken:=Gdip_Startup()

StringRight,right,out,1
If (right="\")
  StringTrimRight,out,out,1

START:
Gui,Destroy
Gui,Show,% "X Y W" A_ScreenWidth " H" A_ScreenHeight,%applicationname%
Gui,+Resize +0x300000 +AlwaysOnTop -Resize +OwnDialogs ;WS_VSCROLL | WS_HSCROLL
Gui,+LastFound
guiid:=WinExist()

WinSetUnMovable(guiid)
DllCall("RegisterShellHookWindow",UInt,guiid)
msgnum:=DllCall("RegisterWindowMessage",Str,"SHELLHOOK")
OnMessage(msgnum,"ShellMessage")
GroupAdd,MyGui,ahk_id %guiid%
WinSet,Top,,ahk_id %guiid%
WinSetTitle,ahk_id %guiid%,,% applicationname " - Reading pictures..."

Gui,3:Destroy
Gui,3:+Owner1
Gui,3:+AlwaysOnTop +ToolWindow -Caption
Gui,3:Margin,10,10
Gui,3:Font, s24
Gui,3:Add,Text,Xm Ym vProgressText,% "Reading pictures, please wait..."
Gui,3:Show

subfolder:=A_Now
counter:=0
x:=space
y:=50+space
Loop,Parse,in,`,
{
  source:=A_LoopField
  StringRight,right,source,1
  If (right="\")
    StringTrimRight,source,source,1

  Loop,%source%\*.*,0,% subfolders
  {
    If A_LoopFileExt Not In GIF,JPG,JPEG,JPE,BMP,ICO,CUR,ANI,PNG,TIF,Exif,WMF,EMF
      Continue
    counter+=1
    path_%counter%:=A_LoopFileLongPath
    pBitmap := Gdip_CreateBitmapFromFile(A_LoopFileLongPath)
    w:=Gdip_GetImageWidth(pBitmap)
    h:=Gdip_GetImageHeight(pBitmap)
    Gdip_DisposeImage(pBitmap)
    If (w>h)
      Gui,Add,Picture,% "X" x " Y" y+(size-size*h/w)/2 " W" size " H-1 GPICTURE AltSubmit V" check%counter%,%A_LoopFileLongPath%
    Else
      Gui,Add,Picture,% "X" x+(size-size*w/h)/2 " Y" y " H" size " W-1 GPICTURE AltSubmit V" check%counter%,%A_LoopFileLongPath%
    Gui,Add,CheckBox,% "X" x-space " Y" y+size " W" space " H" space,% "" ; " W" size+space-1 " H" space*2,% "" ;% A_LoopFileName
    Gui,Add,Edit,% "X" x+1 " Y" y+size " W" size-2 " H" space*2 " -HScroll -VScroll",% A_LoopFileName

    x:=x+size+space*2
    If (x>A_ScreenWidth-size)
    {
      x:=space
      y:=y+size+space*2
    }
  }
}
;Gui,Add, Button,W75 Xm Ym GREFRESH Default,&Refresh
;Gui,Add, Button,W75 X+5 GSELECTALL,Select &All
;Gui,Add, Button,W75 X+5 GINVERT,&Invert
;Gui,Add, Button,W75 X+5 GUPLOAD,&Upload

Gui,Add,Picture,Xm Ym GREFRESH Default,reload.png
Gui,Add,Text,X+2 Ym+36 GREFRESH,&Refresh
Gui,Add,Picture,X+10 Ym GSELECTALL,list-add.png
Gui,Add,Text,X+2 Ym+36 GSELECTALL,Select &All
Gui,Add,Picture,X+10 Ym GINVERT,list-remove.png
Gui,Add,Text,X+2 Ym+36 GINVERT,&Invert Selection
Gui,Add,Picture,X+10 Ym GUPLOAD,filesave.png
Gui,Add,Text,X+2 Ym+36 GUPLOAD,&Upload

OnMessage(0x115, "OnScroll") ; WM_VSCROLL
OnMessage(0x114, "OnScroll") ; WM_HSCROLL

WinMove,ahk_id %guiid%,,,,,% A_ScreenHeight-1
WinMove,ahk_id %guiid%,,,,,% A_ScreenHeight
WinSetTitle,ahk_id %guiid%,,% "Finished reading pictures"
GuiControl,3:,ProgressText,% "Finished reading pictures"
Sleep, 1000
Gui,3:Destroy
Return


PICTURE:
MouseGetPos,mx,my,mwin,mctrl
StringTrimLeft,control,mctrl,6
Gui,2:Destroy
Gui,2:+Owner1
Gui,2:Margin,0,0
Gui,2:+AlwaysOnTop +ToolWindow
Gui,2:Add,Picture,% "X" 0 " Y" 0 " W" 400 " H-1 GPREVIEW",% path_%control%
Gui,2:Show
Return


PREVIEW:
Return


REFRESH:
subfolder:=A_Now
Gui,2:+AlwaysOnTop -Border -Resize
Gui,2:Show,X0 Y0 W%A_ScreenWidth% H%A_ScreenHeight%,PhotoKiosk
Gosub,START
Gui,2:Destroy
Return


SELECTALL:
WinGet,controls,ControlList,ahk_id %guiid%
Loop,Parse,controls,`n
{
  If A_LoopField Contains Button
    GuiControl,,% A_LoopField,1
  If (A_LoopField="Button" counter)
    Break
}
Return


INVERT:
WinGet,controls,ControlList,ahk_id %guiid%
Loop,Parse,controls,`n
{
  If A_LoopField Contains Button
  {
    GuiControlGet,checked,,% A_LoopField
    If checked=1
      GuiControl,,% A_LoopField,0
    Else
      GuiControl,,% A_LoopField,1
  }
  If (A_LoopField="Button" counter)
    Break
}
Return


UPLOAD:
Gui,3:Destroy
Gui,3:+Owner1
Gui,3:+AlwaysOnTop +ToolWindow -Caption
Gui,3:Margin,10,10
Gui,3:Font, s24
Gui,3:Add,Text,Xm Ym vProgressText,% "Uploading pictures..."
Gui,3:Show

FileCreateDir,% out "\" subfolder "\"
WinGet,controls,ControlList,ahk_id %guiid%
Loop,Parse,controls,`n
{
  If A_LoopField Contains Button
  {
    GuiControlGet,checked,,% A_LoopField
    If checked=1
    {
      StringTrimLeft,control,A_LoopField,6
     
      FileCopy,% path_%control%,% out "\" subfolder "\"
      WinSetTitle,ahk_id %guiid%,,% "Uploading " path_%control% "..."
      GuiControl,3:,ProgressText,% "Uploading " path_%control% "..."
    }
  }
  If (A_LoopField="Button" counter)
    Break
}
WinSetTitle,ahk_id %guiid%,,% "Finished uploading pictures"
GuiControl,3:,ProgressText,% "Finished uploading pictures"
Sleep, 1000
Gui,3:Destroy
Return


GuiSize:
  UpdateScrollBars(A_Gui,A_GuiWidth,A_GuiHeight)
Return


GuiClose:
Return


^+!e::
EXIT:
Gdip_Shutdown(pToken)
DllCall("CloseHandle",UInt,hDir)
ExitApp
Return


ShellMessage(wParam,lParam)
{
  Global guiid
  If (lParam<>guiid)
  {
    WinSet,Top,,ahk_id %guiid%
    WinActivate,ahk_id %guiid%
  }
}
Return


WinSetUnMovable(hwnd)
{
  hSysMenu:=DllCall("GetSystemMenu","Int",hWnd,"Int",FALSE)
  nCnt:=DllCall("GetMenuItemCount","Int",hSysMenu)
  DllCall("RemoveMenu","Int",hSysMenu,"UInt",nCnt-6,"Uint","0x400")
  DllCall("DrawMenuBar","Int",hWnd)
}
Return


#IfWinActive ahk_group MyGui
WheelUp::
WheelDown::
+WheelUp::
+WheelDown::
  ; SB_LINEDOWN=1, SB_LINEUP=0, WM_HSCROLL=0x114, WM_VSCROLL=0x115
  OnScroll(InStr(A_ThisHotkey,"Down") ? 1 : 0, 0, GetKeyState("Shift") ? 0x114 : 0x115, WinExist())
Return
#IfWinActive


UpdateScrollBars(GuiNum, GuiWidth, GuiHeight)
{
  static SIF_RANGE=0x1, SIF_PAGE=0x2, SIF_DISABLENOSCROLL=0x8, SB_HORZ=0, SB_VERT=1
 
  Gui, %GuiNum%:Default
  Gui, +LastFound
 
  ; Calculate scrolling area.
  Left := Top := 9999
  Right := Bottom := 0
  WinGet, ControlList, ControlList
  Loop, Parse, ControlList, `n
  {
    GuiControlGet, c, Pos, %A_LoopField%
    if (cX < Left)
      Left := cX
    if (cY < Top)
      Top := cY
    if (cX + cW > Right)
      Right := cX + cW
    if (cY + cH > Bottom)
      Bottom := cY + cH
  }
  Left -= 8
  Top -= 8
  Right += 8
  Bottom += 8
  ScrollWidth := Right-Left
  ScrollHeight := Bottom-Top
 
  ; Initialize SCROLLINFO.
  VarSetCapacity(si, 28, 0)
  NumPut(28, si) ; cbSize
  NumPut(SIF_RANGE | SIF_PAGE, si, 4) ; fMask
 
  ; Update horizontal scroll bar.
  NumPut(ScrollWidth, si, 12) ; nMax
  NumPut(GuiWidth, si, 16) ; nPage
  DllCall("SetScrollInfo", "uint", WinExist(), "uint", SB_HORZ, "uint", &si, "int", 1)
 
  ; Update vertical scroll bar.
;     NumPut(SIF_RANGE | SIF_PAGE | SIF_DISABLENOSCROLL, si, 4) ; fMask
  NumPut(ScrollHeight, si, 12) ; nMax
  NumPut(GuiHeight, si, 16) ; nPage
  DllCall("SetScrollInfo", "uint", WinExist(), "uint", SB_VERT, "uint", &si, "int", 1)
 
  if (Left < 0 && Right < GuiWidth)
      x := Abs(Left) > GuiWidth-Right ? GuiWidth-Right : Abs(Left)
  if (Top < 0 && Bottom < GuiHeight)
      y := Abs(Top) > GuiHeight-Bottom ? GuiHeight-Bottom : Abs(Top)
  if (x || y)
      DllCall("ScrollWindow", "uint", WinExist(), "int", x, "int", y, "uint", 0, "uint", 0)
}


OnScroll(wParam, lParam, msg, hwnd)
{
  static SIF_ALL=0x17, SCROLL_STEP=10
 
  bar := msg=0x115 ; SB_HORZ=0, SB_VERT=1
 
  VarSetCapacity(si, 28, 0)
  NumPut(28, si) ; cbSize
  NumPut(SIF_ALL, si, 4) ; fMask
  if !DllCall("GetScrollInfo", "uint", hwnd, "int", bar, "uint", &si)
    return
 
  VarSetCapacity(rect, 16)
  DllCall("GetClientRect", "uint", hwnd, "uint", &rect)
 
  new_pos := NumGet(si, 20) ; nPos
 
  action := wParam & 0xFFFF
  if action = 0 ; SB_LINEUP
    new_pos -= SCROLL_STEP
  else if action = 1 ; SB_LINEDOWN
    new_pos += SCROLL_STEP
  else if action = 2 ; SB_PAGEUP
    new_pos -= NumGet(rect, 12, "int") - SCROLL_STEP
  else if action = 3 ; SB_PAGEDOWN
    new_pos += NumGet(rect, 12, "int") - SCROLL_STEP
  else if action = 5 ; SB_THUMBTRACK
    new_pos := NumGet(si, 24, "int") ; nTrackPos
  else if action = 6 ; SB_TOP
    new_pos := NumGet(si, 8, "int") ; nMin
  else if action = 7 ; SB_BOTTOM
    new_pos := NumGet(si, 12, "int") ; nMax
  else
    return
 
  min := NumGet(si, 8, "int") ; nMin
  max := NumGet(si, 12, "int") - NumGet(si, 16) ; nMax-nPage
  new_pos := new_pos > max ? max : new_pos
  new_pos := new_pos < min ? min : new_pos
 
  old_pos := NumGet(si, 20, "int") ; nPos
 
  x := y := 0
  if bar = 0 ; SB_HORZ
    x := old_pos-new_pos
  else
    y := old_pos-new_pos
  ; Scroll contents of window and invalidate uncovered area.
  DllCall("ScrollWindow", "uint", hwnd, "int", x, "int", y, "uint", 0, "uint", 0)
 
  ; Update scroll bar.
  NumPut(new_pos, si, 20, "int") ; nPos
  DllCall("SetScrollInfo", "uint", hwnd, "int", bar, "uint", &si, "int", 1)
}

Skrommel, if you don't want me to post this, I'll take it off.

PS sorry for the bump but it wouldn't let me put it in the earlier post because it was too long
« Last Edit: October 20, 2008, 03:31:43 PM by NinJA999 » Logged
mouser
First Author
Administrator
*****
Posts: 32,700



see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #30 on: October 21, 2008, 04:20:08 AM »

thanks for sharing -- i'm sure skrommel won't mind.
(you could also attach the file as an .ahk)
Logged
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #31 on: October 21, 2008, 10:30:15 AM »

I will probably attach it once I finish adding a few other user-friendly features I'm working on.  Again, Skrommel, if you mind, I'll take down the code and just use the features on my own personal system.
Logged
Target
Honorary Member
**
Posts: 1,361



see users location on a map View Profile WWW Give some DonationCredits to this forum member
« Reply #32 on: October 27, 2008, 06:34:21 PM »

I realise that this is probably a non issue given the work already done on Skrommels script, but I really hate to leave a job half done...

've amended my code so that it works as intended, ie it correctly detects removable media.  Also added the option to set the defaults (from the tray menu).

still looking at displaying image aspect ratio correctly...
Logged

"Look wise, say nothing, and grunt. Speech was given to conceal thought" - Sir William Osler
VideoInPicture
Honorary Member
**
Posts: 467



see users location on a map View Profile WWW Give some DonationCredits to this forum member
« Reply #33 on: October 27, 2008, 09:47:19 PM »

I haven't played around with the AHK code enough to give a good image scaling function in that will preserve the aspect ratio in AHK, but below is what I wrote to scale images in Circle Dock that preserves the aspect ratio while maximizing the image size given a desired size. I think it should be pretty easy for you guys to transfer this C# code to AHK form.

Formatted for C# with the GeSHI Syntax Highlighter [copy or print]
  1.        /// <summary>
  2.        /// Returns a bitmap resized to fit inside NewWidth and NewHeight without aspect ratio change. Uses high quality scaling.
  3.        /// Returns null if an error is encountered.
  4.        /// </summary>
  5.        /// <param name="Bitmap">Image to resize.</param>
  6.        /// <param name="NewWidth">Width of the resized bitmap.</param>
  7.        /// <param name="NewHeight">Height of the resized bitmap.</param>
  8.        public static Bitmap ScaleBySizeBestFit(ref Bitmap Bitmap, int NewWidth, int NewHeight)
  9.        {
  10.            try
  11.            {
  12.                Bitmap scaledBitmap = new Bitmap(NewWidth, NewHeight);
  13.  
  14.                // Scale the bitmap in high quality mode.
  15.                using (Graphics gr = Graphics.FromImage(scaledBitmap))
  16.                {
  17.                    gr.SmoothingMode = System.Drawing.Drawing2D.SmoothingMode.HighSpeed;
  18.                    gr.PixelOffsetMode = System.Drawing.Drawing2D.PixelOffsetMode.HighSpeed;
  19.                    gr.CompositingQuality = System.Drawing.Drawing2D.CompositingQuality.HighSpeed;
  20.                    gr.InterpolationMode = System.Drawing.Drawing2D.InterpolationMode.High;
  21.  
  22.                    double scaledBitmapAspectRatio = (double)scaledBitmap.Width / (double)scaledBitmap.Height;
  23.                    double sourceBitmapAspectRatio = (double)Bitmap.Width / (double)Bitmap.Height;
  24.  
  25.                    int bestLeft, bestRight, bestTop, bestBottom, calcWidth, calcHeight;
  26.  
  27.                    if (sourceBitmapAspectRatio > scaledBitmapAspectRatio)      // The source bitmap is wider
  28.                    {
  29.                        bestLeft = 0;
  30.                        bestRight = scaledBitmap.Width;
  31.  
  32.                        calcHeight = (int)((double)scaledBitmap.Width / sourceBitmapAspectRatio);
  33.                        bestTop = (scaledBitmap.Height - calcHeight) / 2;
  34.                        bestBottom = calcHeight;
  35.                    }
  36.                    else
  37.                    {
  38.                        bestTop = 0;
  39.                        bestBottom = scaledBitmap.Height;
  40.  
  41.                        calcWidth = (int)((double)scaledBitmap.Height * sourceBitmapAspectRatio);
  42.                        bestLeft = (scaledBitmap.Width - calcWidth) / 2;
  43.                        bestRight = calcWidth;
  44.                    }
  45.  
  46.                    gr.DrawImage(Bitmap, new Rectangle(bestLeft, bestTop, bestRight, bestBottom), new Rectangle(0, 0, Bitmap.Width, Bitmap.Height), GraphicsUnit.Pixel);
  47.                }
  48.  
  49.                return scaledBitmap;
  50.            }
  51.            catch (Exception)
  52.            {
  53.                return null;
  54.            }
  55.        }
  56.    }
Logged

Author of Circle Dock: http://circledock.wikidot.com
Author of Video In Picture: http://videoinpicture.wikidot.com
Author of Webcam Signature: http://webcamsignature.wikidot.com
Author of Easy Unicode Paster: http://easyunicodepaster.wikidot.com
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #34 on: October 29, 2008, 02:41:33 PM »

Okay, so here's the version I'll probably end up using for the tournament.
Again, Skrommel, if you mind, I'll take down the code and just use the added features on my own personal system.

http://aldwin.us/PhotoKiosk/ - here you can find the PhotoKiosk AHK along with the needed icons
http://aldwin.us/PhotoKiosk/PhotoKiosk.exe - A direct link to the EXE (contains all needed icons)

If it seems OK, maybe this topic is now DONE instead of IDEA?
Logged
Target
Honorary Member
**
Posts: 1,361



see users location on a map View Profile WWW Give some DonationCredits to this forum member
« Reply #35 on: October 30, 2008, 11:39:50 PM »

Updated my scripts to fix the remaining issues (image aspect ratios, correcting the alignment) and it now works as intended

ninja999 - i can't get your script to find any images??
Logged

"Look wise, say nothing, and grunt. Speech was given to conceal thought" - Sir William Osler
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #36 on: October 30, 2008, 11:45:40 PM »

first off, it's not my script, just my mods to skrommel's excellent program.

and you must set the origin directory in the ini.
Logged
Target
Honorary Member
**
Posts: 1,361



see users location on a map View Profile WWW Give some DonationCredits to this forum member
« Reply #37 on: October 31, 2008, 12:15:08 AM »

aha! I was looking at the hard code (DOH!!)
Logged

"Look wise, say nothing, and grunt. Speech was given to conceal thought" - Sir William Osler
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #38 on: October 31, 2008, 07:53:39 PM »

Mhm, I realized I would be running this on systems without AHK, and therefore would need to run the EXE.  But, each system would have different drive letters, so I had to put an ini part in.
Logged
Target
Honorary Member
**
Posts: 1,361



see users location on a map View Profile WWW Give some DonationCredits to this forum member
« Reply #39 on: November 17, 2008, 11:11:19 PM »

and at the risk of flogging a dead horse (just one of my superpowers!!), here's a single file version...

EDIT: bug fix posted 06/07/09

* Picturosk.ahk (9.97 KB - downloaded 197 times.)
* Picturosk.exe (212.65 KB - downloaded 153 times.)
« Last Edit: July 05, 2009, 11:11:10 PM by Target » Logged

"Look wise, say nothing, and grunt. Speech was given to conceal thought" - Sir William Osler
NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #40 on: November 18, 2008, 12:01:20 PM »

So to reiterate, here is the link to all the files of my modified version of Skrommel's:
http://aldwin.us/PhotoKiosk/
Here's the single exe file:
http://aldwin.us/PhotoKiosk/PhotoKiosk.exe

And I used it at the tournament and it worked great.  So, can I put this in the finished snacks or does a moderator have to do it?
Logged
jgpaiva
Global Moderator
*****
Posts: 4,710



Artificial Idiocy

see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #41 on: November 18, 2008, 12:11:57 PM »

So, can I put this in the finished snacks or does a moderator have to do it?
Done Wink
Logged

NinJA999
Supporting Member
**
Posts: 79



see users location on a map View Profile Give some DonationCredits to this forum member
« Reply #42 on: November 18, 2008, 01:37:39 PM »

thank you  smiley
Logged
Pages: Prev 1 [2]   Go Up
  Reply  |  New Topic  |  Print  
 
Jump to:  
   Forum Home   Thread Marks Chat! Downloads Search Login Register  

DonationCoder.com | About Us
DonationCoder.com Forum | Powered by SMF
[ Page time: 0.071s | Server load: 0.12 ]