Welcome Guest.   Make a donation to an author on the site October 02, 2014, 07:30:59 AM  *

Please login or register.
Or did you miss your validation email?


Login with username and password (forgot your password?)
Why not become a lifetime supporting member of the site with a one-time donation of any amount? Your donation entitles you to a ton of additional benefits, including access to exclusive discounts and downloads, the ability to enter monthly free software drawings, and a single non-expiring license key for all of our programs.


You must sign up here before you can post and access some areas of the site. Registration is totally free and confidential.
 
The N.A.N.Y. Challenge 2013! Download dozens of custom programs!
   
   Forum Home   Thread Marks Chat! Downloads Search Login Register  
Pages: [1]   Go Down
  Reply  |  New Topic  |  Print  
Author Topic: IDEA: Draw on your desktop  (Read 9850 times)
Toptiger5
Participant
*
Posts: 14

View Profile Give some DonationCredits to this forum member
« on: March 25, 2008, 10:15:44 AM »

This is so simple I can't believe I can't find apps that are good enough for this one!

I want an app that lives in your taskbar and runs all the time (starts at startup, runs all the time unless you exit it) and when you rightclick it you get simple options like "red, blue, black, green". No more colors, only those. It will let you "draw" on your desktop wallpaper, and the scribbles will be autosaved (so if you reboot your computer, the notes will still be there).

I have seen apps like this before, but they have disadvantages...

-The good ones are not freeware.
-They have big chunky toolbars instead of a simple taskbar icon.
-They have too many unnecessary colors. (Who needs to scribble captions and reminders in pink? And what's the difference between scribbling them in dark blue and light blue?)
-The app is like a transparent window, so when you are using it you can not use the desktop icons. The app I want should be "integrated" with the Windows desktop wallpaper, so that you can scribble AND click the icons without having to close the drawing app.

Thanks!
Logged
f0dder
Charter Honorary Member
***
Posts: 8,774



[Well, THAT escalated quickly!]

see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #1 on: March 25, 2008, 10:33:50 AM »

This actually isn't super-easy to do, for a number of reasons... one would need to resort to kludgy hacks, or injecting code into explorer.exe (which is also quite a hack, and won't work if the user has another shell than explorer, and will impose 32/64bit trouble as well).
Logged

- carpe noctem
mouser
First Author
Administrator
*****
Posts: 33,435



see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #2 on: March 25, 2008, 10:45:30 AM »

This was the subject of a recent thread here:
http://www.donationcoder....m/index.php?topic=11716.0
Logged
kartal
Supporting Member
**
Posts: 1,529


View Profile Give some DonationCredits to this forum member
« Reply #3 on: March 25, 2008, 10:49:47 AM »

try this one

http://technet.microsoft....ysinternals/bb897434.aspx
Logged
Toptiger5
Participant
*
Posts: 14

View Profile Give some DonationCredits to this forum member
« Reply #4 on: March 25, 2008, 01:25:29 PM »

This actually isn't super-easy to do, for a number of reasons... one would need to resort to kludgy hacks, or injecting code into explorer.exe (which is also quite a hack, and won't work if the user has another shell than explorer, and will impose 32/64bit trouble as well).
hmm... didn't know that. Not good with this coding stuff...
Logged
cbbibleboy
Honorary Member
**
Posts: 17


View Profile Give some DonationCredits to this forum member
« Reply #5 on: June 04, 2008, 01:45:43 PM »

It may be a bit too late now, but I'll start work on this. Even if this thread has been abandoned, it seems like a useful app.
Logged
mouser
First Author
Administrator
*****
Posts: 33,435



see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #6 on: June 04, 2008, 01:57:39 PM »

no thread is every truly abandoned on DC smiley
Logged
lanux128
Global Moderator
*****
Posts: 6,102



see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #7 on: June 04, 2008, 09:07:14 PM »

i never had a need for these except on my son's PC where i let him scribble with the mouse and i use a program called 'Gribouille'. anyway, good luck to you cbbibleboy! Thmbsup
Logged

cranioscopical
Friend of the Site
Supporting Member
**
Posts: 4,170



see users location on a map View Profile Read user's biography. Give some DonationCredits to this forum member
« Reply #8 on: June 04, 2008, 09:10:01 PM »

Quote from: mouser
no thread is every truly abandoned on DC

A little unrestrained at times, perhaps  Wink
Logged

Chris
Conquer
Honorary Member
**
Posts: 50



View Profile Give some DonationCredits to this forum member
« Reply #9 on: June 29, 2008, 09:09:07 PM »

[copy or print]
CoordMode, Mouse, Screen
 
Black    = 000000
Green    = 008000
Silver    = C0C0C0
Lime       = 00FF00
Gray       = 808080
Olive       = 808000
White    = FFFFFF
Yellow    = FFFF00
Maroon    = 800000
Navy    = 000080
Red       = FF0000
Blue       = 0000FF
Purple    = 800080
Teal       = 008080
Fuchsia    = FF00FF
Aqua    = 00FFFF

hh := A_ScreenHeight - 51
ww := A_ScreenWidth / 3
ColorChoice = Black
LineWidth = 11
xpos=0
ypos=0
word=

Gui 2: Color, black
Gui 2: Add, Button, Default x-100 y1 gokbt,
Gui 2: +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui 2: Add, Edit, vword x20 y1 w%ww%,
 Gui 2: Add, DropDownList, w80 x+20 y1 choose2 vColorChoice gchange, Aqua|Black|Blue|Fuchsia|Gray|Green|Lime|Maroon|Navy|Olive|Purple|Red|Silver|Teal|White|Yellow|
Gui 2: Add, DropDownList, w40 x+20 y1 choose4 vLineWidth gchange2, 8|9|10|11|12|14|16|18|20|22|24|26|28|36|48|72|
Gui 2: Show, x-1 y%hh% w%A_ScreenWidth% h22

Gui, 1:+LastFound +AlwaysOnTop
Gui, 1:-Caption
Gui, 1:Color, FF0000
WinSet, TransColor, FF0000
GuiHwnd := WinExist()
Gui, 1:Show
Gui, 1:Maximize

SetTimer, DrawLine, 100

return


okbt:
Gui 2: Submit, NoHide
StringLen, length, ww
Send {Ctrl down}
Send {a}
Send {Ctrl up}
Send {del}
fontsize := LineWidth * 3
MouseGetPos, xpos, ypos
Gui 3: Destroy
Gui 3: Color, EEAA99
Gui 3: +LastFound +AlwaysOnTop +ToolWindow -Caption
WinSet, TransColor, EEAA99
gui 3: font, s%fontsize% C%ColorChoice%, Verdana 
Gui 3: Add, Text, x1 y1, %word%
Gui 3: Show, x%xpos% y%ypos% w%A_ScreenWidth%
length=
return



DrawLine:
GetKeyState, state, LButton 
GetKeyState, state2, Ctrl
MouseGetPos, M_x, M_y
if state = D
if state2 = D
{

sleep 25
MouseGetPos, M_x2, M_y2
Canvas_DrawLine(GuihWnd, M_x, M_y, M_x2, M_y2, LineWidth, %ColorChoice%)

loop 30
{
GetKeyState, state, LButton 
GetKeyState, state2, Ctrl
if state = U
{
break
}
else if state2 = U
{
break
}
sleep 25
MouseGetPos, M_x3, M_y3
Canvas_DrawLine(GuihWnd, M_x3, M_y3, M_x2, M_y2, LineWidth, %ColorChoice%)
sleep 25
MouseGetPos, M_x2, M_y2
Canvas_DrawLine(GuihWnd, M_x3, M_y3, M_x2, M_y2, LineWidth, %ColorChoice%)
}
}
return

Canvas_DrawLine(hWnd, p_x1, p_y1, p_x2, p_y2, p_w, p_color) ; r,angle,width,color)
   {
   p_x1 -= 1, p_y1 -= 1, p_x2 -= 1, p_y2 -= 1
   hDC := DllCall("GetDC", UInt, hWnd)
   hCurrPen := DllCall("CreatePen", UInt, 0, UInt, p_w, UInt, Convert_BGR(p_color))
   DllCall("SelectObject", UInt,hdc, UInt,hCurrPen)
   DllCall("gdi32.dll\MoveToEx", UInt, hdc, Uint,p_x1, Uint, p_y1, Uint, 0 )
   DllCall("gdi32.dll\LineTo", UInt, hdc, Uint, p_x2, Uint, p_y2 )
   DllCall("ReleaseDC", UInt, 0, UInt, hDC)  ; Clean-up.
   DllCall("DeleteObject", UInt,hCurrPen)
   }

Convert_BGR(RGB)
   {
   StringLeft, r, RGB, 2
   StringMid, g, RGB, 3, 2
   StringRight, b, RGB, 2
   Return, "0x" . b . g . r
   }
   
return
   
change:
Gui 2: submit
Gui 2: Color, %ColorChoice%
Gui 2: Show, x-1 y%hh% w2000 h22
return

change2:
Gui 2: submit
Gui 2: Show, x-1 y%hh% w2000 h22
return
   
esc::exitapp 
 
^r::
WinSet, Redraw,, ahk_id %GuiHwnd%
Gui 3: Cancel
return
   
   
   
   
   
   

(Not my work)
« Last Edit: June 29, 2008, 09:10:54 PM by Conquer » Logged
skrommel
Fastest code in the west
Developer
***
Posts: 882



View Profile WWW Give some DonationCredits to this forum member
« Reply #10 on: July 05, 2008, 07:21:20 PM »

 smiley Here's DesktopDrawer - Draw on your desktop!

Just run the script, paint using your mouse, press Esc to exit, or use the toolbar.

I was unable to post the whole code because of size limitations on the forum, so you have to download two files:
The script requires Gdip.ahk from http://www.autohotkey.com/forum/topic32238.html
and COM.ahk from http://www.autohotkey.com/forum/topic22923.html

Just place the ahk-files in the same folder as the script.

It's an early release! I'm having trouble with GDI+, Vista won't always update the desktop, and it's lacking in functionality, but give it a try.

Skrommel

[copy or print]
;DesktopDrawer.ahk
; Paint on your desktop
; Just run the script, paint using your mouse, press Esc to quit
; Requires Gdip.ahk from http://www.autohotkey.com/forum/topic32238.html
;       and COM.ahk from http://www.autohotkey.com/forum/topic22923.html
;Skrommel @ 2008

#SingleInstance, Force
#NoEnv
SetBatchLines,-1
SetWorkingDir %A_ScriptDir%
SetWinDelay,0

applicationname=DesktopDrawer


START:
IniRead,penwidth,%applicationname%.ini,Settings,penwidth
IniRead,pencolor,%applicationname%.ini,Settings,pencolor
If penwidth=ERROR
  penwidth=4
If pencolor=ERROR
  pencolor=FF0000

wallpaperfile=wallpaper.bmp
drawingfile=drawing.png

If !pToken := Gdip_Startup()
{
  MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
  ExitApp
}


;GUI
Gui,1:Destroy
Gui,1:-Caption +E0x80000 +LastFound -AlwaysOnTop -ToolWindow +OwnDialogs
Gui,1:Show, NA
hwnd1:= WinExist()
width1:=A_ScreenWidth
height1:=A_ScreenHeight
hbm1 := CreateDIBSection(width1,height1)
hdc1 := CreateCompatibleDC()
obm1 := SelectObject(hdc1, hbm1)
pGraphic1 := Gdip_GraphicsFromHDC(hdc1)


;LOADWALLPAPER
RegRead,tile,HKEY_CURRENT_USER,Control Panel\Desktop,TileWallpaper
RegRead,style,HKEY_CURRENT_USER,Control Panel\Desktop,WallpaperStyle
RegRead,wallpaper,HKEY_CURRENT_USER,Control Panel\Desktop,WallPaper
RegRead,background,HKEY_CURRENT_USER,Control Panel\Colors,Background
If wallpaper=%A_Scriptdir%\%wallpaperfile%
{
  IniRead,tile,%applicationname%.ini,Settings,tile
  IniRead,style,%applicationname%.ini,Settings,style
  IniRead,wallpaper,%applicationname%.ini,Settings,wallpaper
}
Else
{
  background:=DECR_G_BTOHEXRGB(background)
  IniWrite,%tile%,%applicationname%.ini,Settings,tile
  IniWrite,%style%,%applicationname%.ini,Settings,style
  IniWrite,%wallpaper%,%applicationname%.ini,Settings,wallpaper
}

width3 := A_ScreenWidth
height3 := A_ScreenHeight
pBitmap3 := Gdip_CreateBitmap(width3,height3)
pGraphic3 := Gdip_GraphicsFromImage(pBitmap3)
pBitmapFile3 := Gdip_CreateBitmapFromFile(wallpaper)
fileWidth3 := Gdip_GetImageWidth(pBitmapFile3)
fileHeight3 := Gdip_GetImageHeight(pBitmapFile3)
Gdip_SetSmoothingMode(pGraphic3, 4)
Gdip_SetInterpolationMode(pGraphic3, 7)

hBrush:= Gdip_BrushCreateSolid("0xFF" background)
Gdip_FillRectangle(pGraphic3, hBrush, 0, 0, width3, height3)
Gdip_DeleteBrush(hBrush)

If tile=1  ;tile
{
  x:=-1*filewidth3
  y:=0
  Loop
  {
    x+=filewidth3
    If (x>=A_ScreenWidth)
    {
      x:=0
      y+=fileheight3
      If (y>=A_ScreenHeight)
        Break
    }
    Gdip_DrawImage(pGraphic3, pBitmapFile3, x, y, filewidth3, fileheight3, 0, 0, filewidth3, fileheight3)
  }
}
Else
If style=2  ;stretch
  Gdip_DrawImage(pGraphic3, pBitmapFile3, 0, 0, width3, height3, 0, 0, filewidth3, fileheight3)
Else  ;center
  Gdip_DrawImage(pGraphic3, pBitmapFile3, width3/2-filewidth3/2, height3/2-fileheight3/2, filewidth3, fileheight3, 0, 0, filewidth3, fileheight3)

Gdip_DisposeImage(pBitmapFile3)

Gdip_DrawImage(pGraphic1, pBitmap3, 0, 0, width3, height3, 0, 0, width3, height3)


;LOADDRAWING
width2 := A_ScreenWidth
height2 := A_ScreenHeight
pBitmap2 := Gdip_CreateBitmap(width2,height2)
pGraphic2 := Gdip_GraphicsFromImage(pBitmap2)
pBitmapFile2 := Gdip_CreateBitmapFromFile(drawingfile)
fileWidth2 := Gdip_GetImageWidth(pBitmapFile2)
fileHeight2 := Gdip_GetImageHeight(pBitmapFile2)
Gdip_SetSmoothingMode(pGraphic2, 4)
Gdip_SetInterpolationMode(pGraphic2, 7)
Gdip_DrawImage(pGraphic2, pBitmapFile2, 0, 0, fileWidth2, fileheight2, 0, 0, fileWidth2, fileHeight2)
Gdip_DisposeImage(pBitmapFile2)

Gdip_DrawImage(pGraphic1, pBitmap2, 0, 0, width2, height2, 0, 0, width2, height2)

hBrush:=Gdip_BrushCreateSolid("0xFF" pencolor)
hPen := Gdip_CreatePen("0xFF" pencolor, penwidth)
DllCall("gdiplus\GdipSetPenLineCap197819",UInt,hpen,UInt,2,UInt,2,UInt,0)

Loop,10
  UpdateLayeredWindow(hwnd1, hdc1, 0, 0, width1, height1, 25*A_Index+5)

;TOOLBAR
Gui,4:Destroy
Gui,4:Margin,0,0
Gui,4:+LastFound +AlwaysOnTop +ToolWindow +OwnDialogs
Gui,4:Font,C000000 S20,Wingdings 
Loop,5
  Gui,4:Add,Text,% "x+0 yp GPEN Vwidth_" A_Index*2,% Chr(0x8B+A_Index*2)
Gui,4:Add,Picture,xm w0 h0
colors=000000|FFFFFF|FF0000|00FF00|0000FF
Loop,Parse,colors,|
{
  Gui,4:Font,C%A_LoopField% S24,Wingdings 
  Gui,4:Add,Text,x+0 GPEN Vcolor_%A_LoopField%,% Chr(0x6C)
}
Gui,4:Font, 
Gui,4:Add,Edit,xm,
Gui,4:Add,Button,xm w40 Default GSAVE,&Save
Gui,4:Add,Button,x+0 w40 GEXIT,&Quit
Gui,4:Add,Button,x+0 w40 GCLEAR,&Clear
Gui,4:Show,x0 y0 NA
hwnd4:= WinExist()

OnMessage(0x201, "WM_LBUTTONDOWN")
OnExit,Exit
Return


PEN:
StringSplit,part_,A_GuiControl,_
If part_1=color
  pencolor:=part_2
If part_1=width
  penwidth:=part_2
Gdip_DeleteBrush(hBrush)
Gdip_DeletePen(hPen)
hBrush:=Gdip_BrushCreateSolid("0xFF" pencolor)
hPen := Gdip_CreatePen("0xFF" pencolor, penwidth)
DllCall("gdiplus\GdipSetPenLineCap197819",UInt,hpen,UInt,2,UInt,2,UInt,0)
IniWrite,%pencolor%,%applicationname%.ini,Settings,pencolor
IniWrite,%penwidth%,%applicationname%.ini,Settings,penwidth
Return


UPDATE(pBitmap,width,height,x=0,y=0)
{
  Local empty

  Gdip_DrawImage(pGraphic1, pBitmap, x, y, width, height, x, y, width, height)
  UpdateLayeredWindow(hwnd1, hdc1, 0, 0, width1, height1)
}


SAVETOFILE:
Gdip_SaveBitmapToFile(pBitmap2, drawingfile)

Gdip_DrawImage(pGraphic3, pBitmap2, 0, 0, width3, height3, 0, 0, width3, height3)
UpdateLayeredWindow(hwnd3, hdc3, 0, 0, width3, height3)
Gdip_SaveBitmapToFile(pBitmap3, wallpaperfile)

RegWrite,REG_SZ,HKEY_CURRENT_USER,Control Panel\Desktop,TileWallpaper,0
RegWrite,REG_SZ,HKEY_CURRENT_USER,Control Panel\Desktop,WallpaperStyle,2
RegWrite,REG_SZ,HKEY_CURRENT_USER,Control Panel\Desktop,WallPaper,%A_Scriptdir%\%wallpaperfile%
Gosub,CHANGEWALLPAPER
Return


CLEANUP:
Gui,4:Destroy
Loop,10
  UpdateLayeredWindow(hwnd1, hdc1, 0, 0, width1, height1, 255-A_Index*25-5)

SelectObject(hdc1, obm1)
DeleteObject(hbm1)
DeleteDC(hdc1)
Gdip_DeleteGraphics(pGraphic1)

Gdip_DeletePen(hPen)
Gdip_DeletePen(hBrush)

Gdip_DeleteGraphics(pGraphic2)
Gdip_DisposeImage(pBitmap2)

Gdip_DeleteGraphics(pGraphic3)
Gdip_DisposeImage(pBitmap3)

Gdip_Shutdown(pToken)
Return


CLEAR:
FileDelete,%A_ScriptDir%\%wallpaperfile%
FileDelete,%A_ScriptDir%\%drawingfile%
Gosub,CLEANUP
Goto,START


GuiEscape:
GuiClose:
SAVE:
Gosub,SAVETOFILE

EXIT:
Gosub,CLEANUP
ExitApp


WM_LBUTTONDOWN(wParam, lParam)
{
  Local empty

  mx:=lParam & 0xFFFF
  my:=lParam >> 16

  Gdip_FillEllipse(pGraphic1, hBrush, mx-penwidth/2, my-penwidth/2, penwidth, penwidth)
  UpdateLayeredWindow(hwnd1, hdc1, 0, 0, width1, height1)

  Gdip_FillEllipse(pGraphic2, hBrush, mx-penwidth/2, my-penwidth/2, penwidth, penwidth)

  OnMessage(0x200, "WM_MOUSEMOVE")
  OnMessage(0x202, "WM_LBUTTONUP")
}


WM_LBUTTONUP(wParam, lParam)
{
  OnMessage(0x200, "") ;"WM_MOUSEMOVE"
  OnMessage(0x202, "") ;"WM_LBUTTONUP"
}


WM_MOUSEMOVE(wParam, lParam)
{
  Local empty

  oldlbutton:=lbutton
  GetKeyState,lbutton,LButton,P
  If (lbutton="U")
    Return

  oldmx:=mx
  oldmy:=my
  mx:=lParam & 0xFFFF
  my:=lParam >> 16

  Gdip_DrawLine(pGraphic1, hPen, oldmx, oldmy, mx, my)
  UpdateLayeredWindow(hwnd1, hdc1, 0, 0, width1, height1)

  Gdip_DrawLine(pGraphic2, hPen, oldmx, oldmy, mx, my)
}


RGBTOBGR(rgb)
{
  StringMid, prefix, rgb, 1, 2
  offset=0
  If (prefix="0x")
    offset=2
  Else
    prefix=
  StringMid, r, rgb,% 1+offset, 2
  StringMid, g, rgb,% 3+offset, 2
  StringMid, b, rgb,% 5+offset, 2
  Return, prefix . b . g . r
}


DECR_G_BTOHEXRGB(rgb)
{
  StringSplit,color_,rgb,%A_Space%   ;Transform dec "R G B" to hex "RGB"
  rgb=
  Loop,% color_0
  {
    tempcolor:=color_%A_Index%
    SetFormat,Integer,Hex
    EnvAdd,tempcolor,0x100
    SetFormat,Integer,Dec
    StringRight,tempcolor,tempcolor,2
    rgb=%rgb%%tempcolor%
  }
  Return,rgb
}


CHANGEWALLPAPER:
;Stolen from Sean at http://www.autohotkey.com/forum/topic16905.html
sFile = %A_Scriptdir%\%wallpaperfile%
sOpt  := "STRETCH"

WPSTYLE_CENTER  := 0
WPSTYLE_TILE    := 1
WPSTYLE_STRETCH := 2
WPSTYLE_MAX     := 3

COM_Init()
pad := COM_CreateObject("{75048700-EF1F-11D0-9888-006097DEACF9}", "{F490EB00-1240-11D1-9888-006097DEACF9}")

DllCall(NumGet(NumGet(1*pad)+28), "Uint", pad, "int64P", WPSTYLE_%sOpt%<<32|8, "Uint", 0) ; SetWallpaperOptions
/*
DllCall(NumGet(NumGet(1*pad)+24), "Uint", pad, "int64P", nOpt:=8, "Uint", 0); GetWallpaperOptions
RegExMatch("CENTER TILE STRETCH MAX", "(?:\w+\s+){" . nOpt>>32 . "}(?<OPTION>\w+\b)", WPSTYLE_)
MsgBox,   % WPSTYLE_OPTION
*/
DllCall(NumGet(NumGet(1*pad)+20), "Uint", pad, "Uint", COM_Unicode4Ansi(wFile,sFile), "Uint", 0) ; SetWallpaper
DllCall(NumGet(NumGet(1*pad)+12), "Uint", pad, "Uint", 7) ; ApplyChanges

COM_Release(pad)
COM_Term()
Return


#Include Gdip.ahk
;Download from tic at http://www.autohotkey.com/forum/topic32238.html

#Include COM.ahk
;Download from Sean at http://www.autohotkey.com/forum/topic22923.html
« Last Edit: July 08, 2008, 08:14:09 PM by skrommel » Logged

Please stop by my site at  1 Hour Software by skrommel  for downloads and more info.
jgpaiva
Global Moderator
*****
Posts: 4,710



Artificial Idiocy

see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #11 on: July 05, 2008, 07:27:54 PM »

skrommel: Looks like you found a forum limitation. Your post is too big. I tried adding the final closing to the quote tag and a spoiler tag, but it looks like the text can't get any bigger than that (and from what i understand, it didn't get the whole code you posted the first time). Maybe it's better for you to post it as an attachment.

PS: I just noticed i tried to edit it at the same time you were editing it too. Sorry!!
Logged

mouser
First Author
Administrator
*****
Posts: 33,435



see users location on a map View Profile WWW Read user's biography. Give some DonationCredits to this forum member
« Reply #12 on: July 05, 2008, 07:29:21 PM »

skrommel for the love of god put this on your site and update your web page!
(and recompile your exes to solve the false positive antivirus alerts).

your fans demand it!!!
Logged
skrommel
Fastest code in the west
Developer
***
Posts: 882



View Profile WWW Give some DonationCredits to this forum member
« Reply #13 on: July 05, 2008, 07:35:10 PM »

 embarassed I'll get right on it, mouser!

Skrommel
Logged

Please stop by my site at  1 Hour Software by skrommel  for downloads and more info.
kartal
Supporting Member
**
Posts: 1,529


View Profile Give some DonationCredits to this forum member
« Reply #14 on: July 05, 2008, 07:36:07 PM »

Btw I have found this free alternative. Nice thing about this is your drawings scribbles stays on top of you application.

http://www.screenmarker.com/
Logged
skrommel
Fastest code in the west
Developer
***
Posts: 882



View Profile WWW Give some DonationCredits to this forum member
« Reply #15 on: July 08, 2008, 08:14:58 PM »

 smiley Just updated DesktopDrawer above. Works much better now.

Skrommel
Logged

Please stop by my site at  1 Hour Software by skrommel  for downloads and more info.
Pages: [1]   Go Up
  Reply  |  New Topic  |  Print  
 
Jump to:  
   Forum Home   Thread Marks Chat! Downloads Search Login Register  

DonationCoder.com | About Us
DonationCoder.com Forum | Powered by SMF
[ Page time: 0.052s | Server load: 0.34 ]